summaryrefslogtreecommitdiffstats
path: root/meta/recipes-extended/lighttpd/lighttpd_1.4.31.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-extended/lighttpd/lighttpd_1.4.31.bb')
-rw-r--r--meta/recipes-extended/lighttpd/lighttpd_1.4.31.bb64
1 files changed, 64 insertions, 0 deletions
diff --git a/meta/recipes-extended/lighttpd/lighttpd_1.4.31.bb b/meta/recipes-extended/lighttpd/lighttpd_1.4.31.bb
new file mode 100644
index 0000000000..ea41d82267
--- /dev/null
+++ b/meta/recipes-extended/lighttpd/lighttpd_1.4.31.bb
@@ -0,0 +1,64 @@
1DESCRIPTION = "Lightweight high-performance web server"
2HOMEPAGE = "http://www.lighttpd.net/"
3BUGTRACKER = "http://redmine.lighttpd.net/projects/lighttpd/issues"
4
5LICENSE = "BSD"
6LIC_FILES_CHKSUM = "file://COPYING;md5=e4dac5c6ab169aa212feb5028853a579"
7
8
9SECTION = "net"
10DEPENDS = "zlib libpcre"
11RDEPENDS_${PN} += " \
12 lighttpd-module-access \
13 lighttpd-module-accesslog \
14 lighttpd-module-indexfile \
15 lighttpd-module-dirlisting \
16 lighttpd-module-staticfile \
17"
18
19PR = "r0"
20
21SRC_URI = "http://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${PV}.tar.bz2 \
22 file://index.html.lighttpd \
23 file://lighttpd.conf \
24 file://lighttpd \
25 file://lighttpd_fix_for_automake-1.12.patch \
26 "
27
28SRC_URI[md5sum] = "c718cc27658240d307b8a1d1c7c4bb54"
29SRC_URI[sha256sum] = "5209e7a25d3044cb21b34d6a2bb3a6f6c216ba903ea486a803d070582e5e26ac"
30
31EXTRA_OECONF = " \
32 --without-bzip2 \
33 --without-ldap \
34 --without-lua \
35 --without-memcache \
36 --with-pcre \
37 --without-webdav-props \
38 --without-webdav-locks \
39 --without-openssl \
40 --disable-static \
41"
42
43inherit autotools pkgconfig update-rc.d gettext
44
45INITSCRIPT_NAME = "lighttpd"
46INITSCRIPT_PARAMS = "defaults 70"
47
48do_install_append() {
49 install -d ${D}${sysconfdir}/init.d ${D}/www/logs ${D}/www/pages/dav ${D}/www/var
50 install -m 0755 ${WORKDIR}/lighttpd ${D}${sysconfdir}/init.d
51 install -m 0755 ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}
52 install -m 0644 ${WORKDIR}/index.html.lighttpd ${D}/www/pages/index.html
53}
54
55FILES_${PN} += "${sysconfdir} /www"
56
57CONFFILES_${PN} = "${sysconfdir}/lighttpd.conf"
58
59PACKAGES_DYNAMIC = "lighttpd-module-*"
60
61python populate_packages_prepend () {
62 lighttpd_libdir = d.expand('${libdir}')
63 do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='')
64}