summaryrefslogtreecommitdiffstats
path: root/meta/recipes-extended/grep/grep_3.11.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-extended/grep/grep_3.11.bb')
-rw-r--r--meta/recipes-extended/grep/grep_3.11.bb46
1 files changed, 46 insertions, 0 deletions
diff --git a/meta/recipes-extended/grep/grep_3.11.bb b/meta/recipes-extended/grep/grep_3.11.bb
new file mode 100644
index 0000000000..cb3105de04
--- /dev/null
+++ b/meta/recipes-extended/grep/grep_3.11.bb
@@ -0,0 +1,46 @@
1SUMMARY = "GNU grep utility"
2HOMEPAGE = "http://savannah.gnu.org/projects/grep/"
3DESCRIPTION = "Grep searches one or more input files for lines containing a match to a specified pattern. By default, grep prints the matching lines."
4BUGTRACKER = "http://savannah.gnu.org/bugs/?group=grep"
5SECTION = "console/utils"
6LICENSE = "GPL-3.0-only"
7LIC_FILES_CHKSUM = "file://COPYING;md5=1ebbd3e34237af26da5dc08a4e440464"
8
9SRC_URI = "${GNU_MIRROR}/grep/grep-${PV}.tar.xz"
10
11SRC_URI[sha256sum] = "1db2aedde89d0dea42b16d9528f894c8d15dae4e190b59aecc78f5a951276eab"
12
13inherit autotools gettext texinfo pkgconfig
14
15# Fix "Argument list too long" error when len(TMPDIR) = 410
16acpaths = "-I ./m4"
17
18do_configure:prepend () {
19 sed -i -e '1s,#!@SHELL@,#!/bin/sh,' ${S}/src/egrep.sh
20 rm -f ${S}/m4/init.m4
21}
22
23do_install () {
24 autotools_do_install
25 if [ "${base_bindir}" != "${bindir}" ]; then
26 install -d ${D}${base_bindir}
27 mv ${D}${bindir}/grep ${D}${base_bindir}/grep
28 mv ${D}${bindir}/egrep ${D}${base_bindir}/egrep
29 mv ${D}${bindir}/fgrep ${D}${base_bindir}/fgrep
30 rmdir ${D}${bindir}/
31 fi
32}
33
34inherit update-alternatives
35
36PACKAGECONFIG ??= "pcre"
37PACKAGECONFIG[pcre] = "--enable-perl-regexp,--disable-perl-regexp,libpcre2"
38
39ALTERNATIVE_PRIORITY = "100"
40
41ALTERNATIVE:${PN} = "grep egrep fgrep"
42ALTERNATIVE_LINK_NAME[grep] = "${base_bindir}/grep"
43ALTERNATIVE_LINK_NAME[egrep] = "${base_bindir}/egrep"
44ALTERNATIVE_LINK_NAME[fgrep] = "${base_bindir}/fgrep"
45
46BBCLASSEXTEND = "nativesdk"