1 files changed, 73 insertions, 0 deletions

diff --git a/meta/recipes-extended/cronie/cronie_1.4.11.bb b/meta/recipes-extended/cronie/cronie_1.4.11.bb
new file mode 100644
index 0000000000..5b124482a3
--- /dev/null
+++ b/meta/recipes-extended/cronie/cronie_1.4.11.bb
@@ -0,0 +1,73 @@
+SUMMARY = "Cron daemon for executing programs at set times"
+DESCRIPTION = "Cronie contains the standard UNIX daemon crond that runs \
+specified programs at scheduled times and related tools. It is based on the \
+original cron and has security and configuration enhancements like the \
+ability to use pam and SELinux."
+HOMEPAGE = "https://fedorahosted.org/cronie/"
+BUGTRACKER = "mmaslano@redhat.com"
+
+# Internet Systems Consortium License
+LICENSE = "ISC & BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=963ea0772a2adbdcd607a9b2ec320c11 \
+                    file://src/cron.c;endline=20;md5=b425c334265026177128353a142633b4 \
+                    file://src/popen.c;beginline=3;endline=31;md5=edd50742d8def712e9472dba353668a9"
+
+SECTION = "utils"
+
+DEPENDS += "${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
+RDEPENDS_${PN} = "${@base_contains('DISTRO_FEATURES', 'pam', '${PAM_DEPS}', '', d)}"
+PAM_DEPS = "libpam libpam-runtime pam-plugin-access pam-plugin-loginuid"
+
+SRC_URI = "https://fedorahosted.org/releases/c/r/cronie/cronie-${PV}.tar.gz \
+           file://crond.init \
+           file://crontab \
+           ${@base_contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)}"
+
+PAM_SRC_URI = "file://crond_pam_config.patch"
+
+
+SRC_URI[md5sum] = "2ba645cf54de17f138ef70312843862f"
+SRC_URI[sha256sum] = "fd08084cedddbb42499f80ddb7f2158195c3555c2ff40ee11d4ece2f9864d7be"
+
+inherit autotools update-rc.d useradd
+
+EXTRA_OECONF += "\
+                ${@base_contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)}"
+
+INITSCRIPT_NAME = "crond"
+INITSCRIPT_PARAMS = "start 90 2 3 4 5 . stop 60 0 1 6 ."
+
+USERADD_PACKAGES = "${PN}"
+GROUPADD_PARAM_${PN} = "--system crontab"
+
+do_install_append () {
+        install -d ${D}${sysconfdir}/sysconfig/
+        install -d ${D}${sysconfdir}/init.d/
+        install -m 0644 ${S}/crond.sysconfig ${D}${sysconfdir}/sysconfig/crond
+        install -m 0755 ${WORKDIR}/crond.init ${D}${sysconfdir}/init.d/crond
+
+        # below are necessary for a complete cron environment
+        install -d ${D}${localstatedir}/spool/cron
+        install -m 0755 ${WORKDIR}/crontab ${D}${sysconfdir}/
+        mkdir -p ${D}${sysconfdir}/cron.d
+        mkdir -p ${D}${sysconfdir}/cron.hourly
+        mkdir -p ${D}${sysconfdir}/cron.daily
+        mkdir -p ${D}${sysconfdir}/cron.weekly
+        mkdir -p ${D}${sysconfdir}/cron.monthly
+        touch ${D}${sysconfdir}/cron.deny
+        
+        # below setting is necessary to allow normal user using crontab
+
+        # setgid for crontab binary
+        chown root:crontab ${D}${bindir}/crontab
+        chmod 2755 ${D}${bindir}/crontab
+
+        # allow 'crontab' group write to /var/spool/cron
+        chown root:crontab ${D}${localstatedir}/spool/cron
+        chmod 770 ${D}${localstatedir}/spool/cron
+
+        chmod 600 ${D}${sysconfdir}/crontab
+}
+
+FILES_${PN} += "${sysconfdir}/cron*"
+