1 files changed, 37 insertions, 16 deletions

diff --git a/meta/recipes-extended/bash/bash.inc b/meta/recipes-extended/bash/bash.inc
index db326660ea..e541161c75 100644
--- a/meta/recipes-extended/bash/bash.inc
+++ b/meta/recipes-extended/bash/bash.inc
@@ -1,5 +1,6 @@
 SUMMARY = "An sh-compatible command language interpreter"
 HOMEPAGE = "http://tiswww.case.edu/php/chet/bash/bashtop.html"
+DESCRIPTION = "Bash is the GNU Project's Bourne Again SHell, a complete implementation of the IEEE POSIX and Open Group shell specification with interactive command line editing, job control on architectures that support it, csh-like features such as history substitution and brace expansion, and a slew of other features."
 SECTION = "base/shell"
 
 DEPENDS = "ncurses bison-native virtual/libiconv"
@@ -21,18 +22,18 @@ CFLAGS += "-DHEREDOC_PIPESIZE=65536"
 # causes a lot of garbage in non-interactive shells
 CFLAGS += "-DBRACKETED_PASTE_DEFAULT=0"
 
-ALTERNATIVE_${PN} = "bash sh"
+ALTERNATIVE:${PN} = "bash sh"
 ALTERNATIVE_LINK_NAME[bash] = "${base_bindir}/bash"
 ALTERNATIVE_TARGET[bash] = "${base_bindir}/bash"
 ALTERNATIVE_LINK_NAME[sh] = "${base_bindir}/sh"
 ALTERNATIVE_TARGET[sh] = "${base_bindir}/bash.${BPN}"
 ALTERNATIVE_PRIORITY = "100"
 
-RDEPENDS_${PN} += "base-files"
-RDEPENDS_${PN}_class-nativesdk = ""
-RDEPENDS_${PN}-ptest += "make coreutils perl sed shadow util-linux-setpriv"
+RDEPENDS:${PN} += "base-files"
+RDEPENDS:${PN}:class-nativesdk = ""
+RDEPENDS:${PN}-ptest += "make coreutils perl sed shadow util-linux-setpriv"
 
-RDEPENDS_${PN}-ptest_append_libc-glibc = " \
+RDEPENDS:${PN}-ptest:append:libc-glibc = " \
         glibc-gconv-big5hkscs \
         glibc-gconv-iso8859-1 \
         glibc-utils \
@@ -45,13 +46,13 @@ RDEPENDS_${PN}-ptest_append_libc-glibc = " \
 
 CACHED_CONFIGUREVARS += "headersdir=${includedir}/${PN}"
 
-do_configure_prepend () {
+do_configure:prepend () {
     if [ ! -e ${S}/acinclude.m4 ]; then
        cat ${S}/aclocal.m4 > ${S}/acinclude.m4
     fi
 }
 
-do_compile_prepend() {
+do_compile:prepend() {
     # Remove any leftover .build files. This ensures that bash always has the
     # same version number and keeps builds reproducible
     rm -f ${B}/.build
@@ -61,14 +62,20 @@ do_compile_ptest () {
         oe_runmake buildtest
 }
 
-do_install_append () {
+do_install:prepend () {
+        # Ensure determinism as this counter increases for each make call
+        rm -f ${B}/.build
+}
+
+do_install:append () {
         # Move /usr/bin/bash to /bin/bash, if need
         if [ "${base_bindir}" != "${bindir}" ]; then
                 mkdir -p ${D}${base_bindir}
                 mv ${D}${bindir}/bash ${D}${base_bindir}
         fi
 }
-do_install_append_class-target () {
+
+fix_absolute_paths () {
         # Clean buildhost references in bashbug
         sed -i -e "s,--sysroot=${STAGING_DIR_TARGET},,g" \
                 -e "s,-I${WORKDIR}/\S* ,,g" \
@@ -87,12 +94,24 @@ do_install_append_class-target () {
                 ${D}${libdir}/bash/Makefile.inc
 }
 
+do_install:append:class-target () {
+        fix_absolute_paths
+}
+
+do_install:append:class-nativesdk () {
+        fix_absolute_paths
+}
+
 do_install_ptest () {
         make INSTALL_TEST_DIR=${D}${PTEST_PATH}/tests install-test
         cp ${B}/Makefile ${D}${PTEST_PATH}
+        cp ${B}/config.h ${D}${PTEST_PATH}
+        cp ${B}/version.h ${D}${PTEST_PATH}
+        cp ${S}/y.tab.[ch] ${D}${PTEST_PATH}
         install -D ${WORKDIR}/run-bash-ptests ${D}${PTEST_PATH}/run-bash-ptests
         sed -i -e 's/^Makefile/_Makefile/' -e "s,--sysroot=${STAGING_DIR_TARGET},,g" \
             -e 's|${DEBUG_PREFIX_MAP}||g' \
+            -e 's|${BUILD_LDFLAGS}||g' \
             -e "s,${S},,g" -e "s,${B},,g" -e "s,${STAGING_DIR_NATIVE},,g" \
             -e 's:${HOSTTOOLS_DIR}/::g' \
             -e 's:${UNINATIVE_LOADER}:${base_bindir}/false:g' \
@@ -103,20 +122,22 @@ do_install_ptest () {
 # hash
 do_install_ptest[vardepsexclude] += "UNINATIVE_LOADER"
 
-pkg_postinst_${PN} () {
+pkg_postinst:${PN} () {
         grep -q "^${base_bindir}/bash$" $D${sysconfdir}/shells || echo ${base_bindir}/bash >> $D${sysconfdir}/shells
 }
 
-pkg_postrm_${PN} () {
+pkg_postrm:${PN} () {
         printf "$(grep -v "^${base_bindir}/bash$" $D${sysconfdir}/shells)\n" > $D${sysconfdir}/shells
 }
 
 PACKAGES += "${PN}-bashbug"
-FILES_${PN} = "${bindir}/bash ${base_bindir}/bash.bash"
-FILES_${PN}-bashbug = "${bindir}/bashbug"
+FILES:${PN} = "${bindir}/bash ${base_bindir}/bash.bash"
+FILES:${PN}-bashbug = "${bindir}/bashbug"
 
 PACKAGE_BEFORE_PN += "${PN}-loadable"
-RDEPENDS_${PN}-loadable += "${PN}"
-FILES_${PN}-loadable += "${libdir}/bash/*"
+RDEPENDS:${PN}-loadable += "${PN}"
+FILES:${PN}-loadable += "${libdir}/bash/*"
 
-RPROVIDES_${PN} += "${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', '/bin/sh /bin/bash', '', d)}"
+# Limit the RPROVIDES here to class target so that if usrmerge is enabled for nativesdk, it does not
+# include host system paths in /bin/
+RPROVIDES:${PN}:append:class-target = " ${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', '/bin/sh /bin/bash', '', d)}"