diff options
Diffstat (limited to 'meta/recipes-devtools/valgrind/valgrind_3.16.0.bb')
-rw-r--r-- | meta/recipes-devtools/valgrind/valgrind_3.16.0.bb | 227 |
1 files changed, 227 insertions, 0 deletions
diff --git a/meta/recipes-devtools/valgrind/valgrind_3.16.0.bb b/meta/recipes-devtools/valgrind/valgrind_3.16.0.bb new file mode 100644 index 0000000000..5402f39a5b --- /dev/null +++ b/meta/recipes-devtools/valgrind/valgrind_3.16.0.bb | |||
@@ -0,0 +1,227 @@ | |||
1 | SUMMARY = "Valgrind memory debugger and instrumentation framework" | ||
2 | HOMEPAGE = "http://valgrind.org/" | ||
3 | BUGTRACKER = "http://valgrind.org/support/bug_reports.html" | ||
4 | LICENSE = "GPLv2 & GPLv2+ & BSD" | ||
5 | LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \ | ||
6 | file://include/pub_tool_basics.h;beginline=6;endline=29;md5=41c410e8d3f305aee7aaa666b2e4f366 \ | ||
7 | file://include/valgrind.h;beginline=1;endline=56;md5=ad3b317f3286b6b704575d9efe6ca5df \ | ||
8 | file://COPYING.DOCS;md5=24ea4c7092233849b4394699333b5c56" | ||
9 | |||
10 | DEPENDS = " \ | ||
11 | ${@bb.utils.contains('DISTRO_FEATURES', 'ptest', 'boost', '', d)} \ | ||
12 | " | ||
13 | |||
14 | SRC_URI = "https://sourceware.org/pub/valgrind/valgrind-${PV}.tar.bz2 \ | ||
15 | file://fixed-perl-path.patch \ | ||
16 | file://Added-support-for-PPC-instructions-mfatbu-mfatbl.patch \ | ||
17 | file://run-ptest \ | ||
18 | file://remove-for-aarch64 \ | ||
19 | file://0004-Fix-out-of-tree-builds.patch \ | ||
20 | file://0005-Modify-vg_test-wrapper-to-support-PTEST-formats.patch \ | ||
21 | file://0001-Remove-tests-that-fail-to-build-on-some-PPC32-config.patch \ | ||
22 | file://use-appropriate-march-mcpu-mfpu-for-ARM-test-apps.patch \ | ||
23 | file://avoid-neon-for-targets-which-don-t-support-it.patch \ | ||
24 | file://valgrind-make-ld-XXX.so-strlen-intercept-optional.patch \ | ||
25 | file://0001-makefiles-Drop-setting-mcpu-to-cortex-a8-on-arm-arch.patch \ | ||
26 | file://0001-str_tester.c-Limit-rawmemchr-test-to-glibc.patch \ | ||
27 | file://0001-sigqueue-Rename-_sifields-to-__si_fields-on-musl.patch \ | ||
28 | file://0002-context-APIs-are-not-available-on-musl.patch \ | ||
29 | file://0003-correct-include-directive-path-for-config.h.patch \ | ||
30 | file://0005-tc20_verifywrap.c-Fake-__GLIBC_PREREQ-with-musl.patch \ | ||
31 | file://0001-memcheck-arm64-Define-__THROW-if-not-already-defined.patch \ | ||
32 | file://0002-memcheck-x86-Define-__THROW-if-not-defined.patch \ | ||
33 | file://0003-tests-seg_override-Replace-__modify_ldt-with-syscall.patch \ | ||
34 | file://0001-fix-opcode-not-supported-on-mips32-linux.patch \ | ||
35 | file://0001-Guard-against-__GLIBC_PREREQ-for-musl-libc.patch \ | ||
36 | file://0001-Make-local-functions-static-to-avoid-assembler-error.patch \ | ||
37 | file://0001-Return-a-valid-exit_code-from-vg_regtest.patch \ | ||
38 | file://0001-valgrind-filter_xml_frames-do-not-filter-usr.patch \ | ||
39 | file://0001-adjust-path-filter-for-2-memcheck-tests.patch \ | ||
40 | file://s390x_vec_op_t.patch \ | ||
41 | file://0001-none-tests-fdleak_cmsg.stderr.exp-adjust-tmp-paths.patch \ | ||
42 | file://0001-memcheck-tests-Fix-timerfd-syscall-test.patch \ | ||
43 | " | ||
44 | SRC_URI[md5sum] = "495b30af5e5ed62ebb9bb777ee19b27f" | ||
45 | SRC_URI[sha256sum] = "582d5127ba56dfeaab4c6ced92a742b2921148e28a5d55055aedd8f75f1cf633" | ||
46 | UPSTREAM_CHECK_REGEX = "valgrind-(?P<pver>\d+(\.\d+)+)\.tar" | ||
47 | |||
48 | COMPATIBLE_HOST = '(i.86|x86_64|arm|aarch64|mips|powerpc|powerpc64).*-linux' | ||
49 | |||
50 | # valgrind supports armv7 and above | ||
51 | COMPATIBLE_HOST_armv4 = 'null' | ||
52 | COMPATIBLE_HOST_armv5 = 'null' | ||
53 | COMPATIBLE_HOST_armv6 = 'null' | ||
54 | |||
55 | # X32 isn't supported by valgrind at this time | ||
56 | COMPATIBLE_HOST_linux-gnux32 = 'null' | ||
57 | COMPATIBLE_HOST_linux-muslx32 = 'null' | ||
58 | |||
59 | # Disable for some MIPS variants | ||
60 | COMPATIBLE_HOST_mipsarchr6 = 'null' | ||
61 | COMPATIBLE_HOST_linux-gnun32 = 'null' | ||
62 | |||
63 | # Disable for powerpc64 with musl | ||
64 | COMPATIBLE_HOST_libc-musl_powerpc64 = 'null' | ||
65 | |||
66 | # brokenseip is unfortunately required by ptests to pass | ||
67 | inherit autotools-brokensep ptest multilib_header | ||
68 | |||
69 | EXTRA_OECONF = "--enable-tls --without-mpicc" | ||
70 | EXTRA_OECONF += "${@['--enable-only32bit','--enable-only64bit'][d.getVar('SITEINFO_BITS') != '32']}" | ||
71 | |||
72 | # valgrind checks host_cpu "armv7*)", so we need to over-ride the autotools.bbclass default --host option | ||
73 | EXTRA_OECONF_append_arm = " --host=armv7${HOST_VENDOR}-${HOST_OS}" | ||
74 | |||
75 | EXTRA_OEMAKE = "-w" | ||
76 | |||
77 | CACHED_CONFIGUREVARS += "ac_cv_path_PERL='/usr/bin/env perl'" | ||
78 | |||
79 | # valgrind likes to control its own optimisation flags. It generally defaults | ||
80 | # to -O2 but uses -O0 for some specific test apps etc. Passing our own flags | ||
81 | # (via CFLAGS) means we interfere with that. Only pass DEBUG_FLAGS to it | ||
82 | # which fixes build path issue in DWARF. | ||
83 | SELECTED_OPTIMIZATION = "${DEBUG_FLAGS}" | ||
84 | |||
85 | do_configure_prepend () { | ||
86 | rm -rf ${S}/config.h | ||
87 | sed -i -e 's:$(abs_top_builddir):$(pkglibdir)/ptest:g' ${S}/none/tests/Makefile.am | ||
88 | sed -i -e 's:$(top_builddir):$(pkglibdir)/ptest:g' ${S}/memcheck/tests/Makefile.am | ||
89 | } | ||
90 | |||
91 | do_install_append () { | ||
92 | install -m 644 ${B}/default.supp ${D}/${libdir}/valgrind/ | ||
93 | oe_multilib_header valgrind/config.h | ||
94 | } | ||
95 | |||
96 | VALGRINDARCH ?= "${TARGET_ARCH}" | ||
97 | VALGRINDARCH_aarch64 = "arm64" | ||
98 | VALGRINDARCH_x86-64 = "amd64" | ||
99 | VALGRINDARCH_x86 = "x86" | ||
100 | VALGRINDARCH_mips = "mips32" | ||
101 | VALGRINDARCH_mipsel = "mips32" | ||
102 | VALGRINDARCH_mips64el = "mips64" | ||
103 | VALGRINDARCH_powerpc = "ppc" | ||
104 | VALGRINDARCH_powerpc64 = "ppc64" | ||
105 | VALGRINDARCH_powerpc64el = "ppc64le" | ||
106 | |||
107 | INHIBIT_PACKAGE_STRIP_FILES = "${PKGD}${libdir}/valgrind/vgpreload_memcheck-${VALGRINDARCH}-linux.so" | ||
108 | |||
109 | RDEPENDS_${PN} += "perl" | ||
110 | |||
111 | # valgrind needs debug information for ld.so at runtime in order to | ||
112 | # redirect functions like strlen. | ||
113 | RRECOMMENDS_${PN} += "${TCLIBC}-dbg" | ||
114 | |||
115 | RDEPENDS_${PN}-ptest += " bash coreutils file \ | ||
116 | gdb libgomp \ | ||
117 | perl \ | ||
118 | perl-module-getopt-long perl-module-file-basename perl-module-file-glob \ | ||
119 | procps sed ${PN}-dbg ${PN}-src" | ||
120 | RDEPENDS_${PN}-ptest_append_libc-glibc = " glibc-utils" | ||
121 | |||
122 | # One of the tests contains a bogus interpreter path on purpose. | ||
123 | # Skip file dependency check | ||
124 | SKIP_FILEDEPS_${PN}-ptest = '1' | ||
125 | INSANE_SKIP_${PN}-ptest = "debug-deps" | ||
126 | |||
127 | do_compile_ptest() { | ||
128 | oe_runmake check | ||
129 | } | ||
130 | |||
131 | do_install_ptest() { | ||
132 | chmod +x ${B}/tests/vg_regtest | ||
133 | |||
134 | # The test application binaries are not automatically installed. | ||
135 | # Grab them from the build directory. | ||
136 | # | ||
137 | # The regression tests require scripts and data files that are not | ||
138 | # copied to the build directory. They must be copied from the | ||
139 | # source directory. | ||
140 | saved_dir=$PWD | ||
141 | for parent_dir in ${S} ${B} ; do | ||
142 | cd $parent_dir | ||
143 | |||
144 | subdirs=" \ | ||
145 | .in_place \ | ||
146 | cachegrind/tests \ | ||
147 | callgrind/tests \ | ||
148 | dhat/tests \ | ||
149 | drd/tests \ | ||
150 | gdbserver_tests \ | ||
151 | helgrind/tests \ | ||
152 | lackey/tests \ | ||
153 | massif/tests \ | ||
154 | memcheck/tests \ | ||
155 | none/tests \ | ||
156 | tests \ | ||
157 | exp-bbv/tests \ | ||
158 | exp-dhat/tests \ | ||
159 | exp-sgcheck/tests \ | ||
160 | " | ||
161 | # Get the vg test scripts, filters, and expected files | ||
162 | for dir in $subdirs ; do | ||
163 | find $dir | cpio -pvdu ${D}${PTEST_PATH} | ||
164 | done | ||
165 | cd $saved_dir | ||
166 | done | ||
167 | |||
168 | # The scripts reference config.h so add it to the top ptest dir. | ||
169 | cp ${B}/config.h ${D}${PTEST_PATH} | ||
170 | install -D ${WORKDIR}/remove-for-aarch64 ${D}${PTEST_PATH} | ||
171 | |||
172 | # Add an executable need by none/tests/bigcode | ||
173 | mkdir ${D}${PTEST_PATH}/perf | ||
174 | cp ${B}/perf/bigcode ${D}${PTEST_PATH}/perf | ||
175 | |||
176 | # Add an executable needed by memcheck/tests/vcpu_bz2 | ||
177 | cp ${B}/perf/bz2 ${D}${PTEST_PATH}/perf | ||
178 | |||
179 | # Make the ptest dir look like the top level valgrind src dir | ||
180 | # This is checked by the gdbserver_tests/make_local_links script | ||
181 | mkdir ${D}${PTEST_PATH}/coregrind | ||
182 | cp ${B}/coregrind/vgdb ${D}${PTEST_PATH}/coregrind | ||
183 | |||
184 | # Add an executable needed by massif tests | ||
185 | cp ${B}/massif/ms_print ${D}${PTEST_PATH}/massif/ms_print | ||
186 | |||
187 | find ${D}${PTEST_PATH} \ | ||
188 | \( \ | ||
189 | -name "Makefile*" \ | ||
190 | -o -name "*.o" \ | ||
191 | \) \ | ||
192 | -exec rm {} \; | ||
193 | |||
194 | # These files need to be newer so touch them. | ||
195 | touch ${D}${PTEST_PATH}/cachegrind/tests/a.c -r ${D}${PTEST_PATH}/cachegrind/tests/cgout-test | ||
196 | |||
197 | # find *_annotate in ${bindir} for yocto build | ||
198 | sed -i s:\.\./\.\./cachegrind/cg_annotate:${bindir}/cg_annotate: ${D}${PTEST_PATH}/cachegrind/tests/ann1.vgtest | ||
199 | sed -i s:\.\./\.\./cachegrind/cg_annotate:${bindir}/cg_annotate: ${D}${PTEST_PATH}/cachegrind/tests/ann2.vgtest | ||
200 | |||
201 | sed -i s:\.\./\.\./callgrind/callgrind_annotate:${bindir}/callgrind_annotate: ${D}${PTEST_PATH}/callgrind/tests/ann1.vgtest | ||
202 | sed -i s:\.\./\.\./callgrind/callgrind_annotate:${bindir}/callgrind_annotate: ${D}${PTEST_PATH}/callgrind/tests/ann2.vgtest | ||
203 | |||
204 | # handle multilib | ||
205 | sed -i s:@libdir@:${libdir}:g ${D}${PTEST_PATH}/run-ptest | ||
206 | sed -i s:@bindir@:${bindir}:g ${D}${PTEST_PATH}/run-ptest | ||
207 | |||
208 | # This test fails on the host as well, using both 3.15 and git master (as of Jan 24 2020) | ||
209 | # https://bugs.kde.org/show_bug.cgi?id=402833 | ||
210 | rm ${D}${PTEST_PATH}/memcheck/tests/overlap.vgtest | ||
211 | |||
212 | # As the binary isn't stripped or debug-splitted, the source file isn't fetched | ||
213 | # via dwarfsrcfiles either, so it needs to be installed manually. | ||
214 | mkdir -p ${D}/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR}/${BP}/none/tests/ | ||
215 | install ${S}/none/tests/tls.c ${D}/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR}/${BP}/none/tests/ | ||
216 | } | ||
217 | |||
218 | # avoid stripping some generated binaries otherwise some of the tests will fail | ||
219 | # run-strip-reloc.sh, run-strip-strmerge.sh and so on will fail | ||
220 | INHIBIT_PACKAGE_STRIP_FILES = "\ | ||
221 | ${PKGD}${PTEST_PATH}/none/tests/tls \ | ||
222 | ${PKGD}${PTEST_PATH}/none/tests/tls.so \ | ||
223 | ${PKGD}${PTEST_PATH}/none/tests/tls2.so \ | ||
224 | ${PKGD}${PTEST_PATH}/helgrind/tests/tc09_bad_unlock \ | ||
225 | ${PKGD}${PTEST_PATH}/memcheck/tests/manuel1 \ | ||
226 | ${PKGD}${PTEST_PATH}/drd/tests/pth_detached3 \ | ||
227 | " | ||