diff options
Diffstat (limited to 'meta/recipes-devtools/rust/rust_1.75.0.bb')
-rw-r--r-- | meta/recipes-devtools/rust/rust_1.75.0.bb | 365 |
1 files changed, 365 insertions, 0 deletions
diff --git a/meta/recipes-devtools/rust/rust_1.75.0.bb b/meta/recipes-devtools/rust/rust_1.75.0.bb new file mode 100644 index 0000000000..ee1ce9e050 --- /dev/null +++ b/meta/recipes-devtools/rust/rust_1.75.0.bb | |||
@@ -0,0 +1,365 @@ | |||
1 | SUMMARY = "Rust compiler and runtime libaries" | ||
2 | HOMEPAGE = "http://www.rust-lang.org" | ||
3 | SECTION = "devel" | ||
4 | LICENSE = "(MIT | Apache-2.0) & Unicode-TOU" | ||
5 | LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=c2cccf560306876da3913d79062a54b9" | ||
6 | |||
7 | inherit rust | ||
8 | inherit cargo_common | ||
9 | |||
10 | DEPENDS += "file-native python3-native" | ||
11 | DEPENDS:append:class-native = " rust-llvm-native" | ||
12 | DEPENDS:append:class-nativesdk = " nativesdk-rust-llvm" | ||
13 | |||
14 | DEPENDS += "rust-llvm (=${PV})" | ||
15 | |||
16 | RDEPENDS:${PN}:append:class-target = " gcc g++ binutils" | ||
17 | |||
18 | # Otherwise we'll depend on what we provide | ||
19 | INHIBIT_DEFAULT_RUST_DEPS:class-native = "1" | ||
20 | # We don't need to depend on gcc-native because yocto assumes it exists | ||
21 | PROVIDES:class-native = "virtual/${TARGET_PREFIX}rust" | ||
22 | |||
23 | S = "${RUSTSRC}" | ||
24 | |||
25 | # Use at your own risk, accepted values are stable, beta and nightly | ||
26 | RUST_CHANNEL ?= "stable" | ||
27 | PV .= "${@bb.utils.contains('RUST_CHANNEL', 'stable', '', '-${RUST_CHANNEL}', d)}" | ||
28 | |||
29 | export FORCE_CRATE_HASH="${BB_TASKHASH}" | ||
30 | |||
31 | RUST_ALTERNATE_EXE_PATH ?= "${STAGING_LIBDIR}/llvm-rust/bin/llvm-config" | ||
32 | RUST_ALTERNATE_EXE_PATH_NATIVE = "${STAGING_LIBDIR_NATIVE}/llvm-rust/bin/llvm-config" | ||
33 | |||
34 | # We don't want to use bitbakes vendoring because the rust sources do their | ||
35 | # own vendoring. | ||
36 | CARGO_DISABLE_BITBAKE_VENDORING = "1" | ||
37 | |||
38 | # We can't use RUST_BUILD_SYS here because that may be "musl" if | ||
39 | # TCLIBC="musl". Snapshots are always -unknown-linux-gnu | ||
40 | setup_cargo_environment () { | ||
41 | # The first step is to build bootstrap and some early stage tools, | ||
42 | # these are build for the same target as the snapshot, e.g. | ||
43 | # x86_64-unknown-linux-gnu. | ||
44 | # Later stages are build for the native target (i.e. target.x86_64-linux) | ||
45 | cargo_common_do_configure | ||
46 | } | ||
47 | |||
48 | inherit rust-target-config | ||
49 | |||
50 | do_rust_setup_snapshot () { | ||
51 | for installer in "${WORKDIR}/rust-snapshot-components/"*"/install.sh"; do | ||
52 | "${installer}" --prefix="${WORKDIR}/rust-snapshot" --disable-ldconfig | ||
53 | done | ||
54 | |||
55 | # Some versions of rust (e.g. 1.18.0) tries to find cargo in stage0/bin/cargo | ||
56 | # and fail without it there. | ||
57 | mkdir -p ${RUSTSRC}/build/${BUILD_SYS} | ||
58 | ln -sf ${WORKDIR}/rust-snapshot/ ${RUSTSRC}/build/${BUILD_SYS}/stage0 | ||
59 | |||
60 | # Need to use uninative's loader if enabled/present since the library paths | ||
61 | # are used internally by rust and result in symbol mismatches if we don't | ||
62 | if [ ! -z "${UNINATIVE_LOADER}" -a -e "${UNINATIVE_LOADER}" ]; then | ||
63 | for bin in cargo rustc rustdoc; do | ||
64 | patchelf-uninative ${WORKDIR}/rust-snapshot/bin/$bin --set-interpreter ${UNINATIVE_LOADER} | ||
65 | done | ||
66 | fi | ||
67 | } | ||
68 | addtask rust_setup_snapshot after do_unpack before do_configure | ||
69 | addtask do_test_compile after do_configure do_rust_gen_targets | ||
70 | do_rust_setup_snapshot[dirs] += "${WORKDIR}/rust-snapshot" | ||
71 | do_rust_setup_snapshot[vardepsexclude] += "UNINATIVE_LOADER" | ||
72 | |||
73 | python do_configure() { | ||
74 | import json | ||
75 | import configparser | ||
76 | |||
77 | # toml is rather similar to standard ini like format except it likes values | ||
78 | # that look more JSON like. So for our purposes simply escaping all values | ||
79 | # as JSON seem to work fine. | ||
80 | |||
81 | e = lambda s: json.dumps(s) | ||
82 | |||
83 | config = configparser.RawConfigParser() | ||
84 | |||
85 | # [target.ARCH-poky-linux] | ||
86 | host_section = "target.{}".format(d.getVar('RUST_HOST_SYS')) | ||
87 | config.add_section(host_section) | ||
88 | |||
89 | llvm_config_target = d.expand("${RUST_ALTERNATE_EXE_PATH}") | ||
90 | llvm_config_build = d.expand("${RUST_ALTERNATE_EXE_PATH_NATIVE}") | ||
91 | config.set(host_section, "llvm-config", e(llvm_config_target)) | ||
92 | |||
93 | config.set(host_section, "cxx", e(d.expand("${RUST_TARGET_CXX}"))) | ||
94 | config.set(host_section, "cc", e(d.expand("${RUST_TARGET_CC}"))) | ||
95 | config.set(host_section, "linker", e(d.expand("${RUST_TARGET_CCLD}"))) | ||
96 | if "musl" in host_section: | ||
97 | config.set(host_section, "musl-root", e(d.expand("${STAGING_DIR_HOST}${exec_prefix}"))) | ||
98 | |||
99 | # If we don't do this rust-native will compile it's own llvm for BUILD. | ||
100 | # [target.${BUILD_ARCH}-unknown-linux-gnu] | ||
101 | build_section = "target.{}".format(d.getVar('RUST_BUILD_SYS')) | ||
102 | if build_section != host_section: | ||
103 | config.add_section(build_section) | ||
104 | |||
105 | config.set(build_section, "llvm-config", e(llvm_config_build)) | ||
106 | |||
107 | config.set(build_section, "cxx", e(d.expand("${RUST_BUILD_CXX}"))) | ||
108 | config.set(build_section, "cc", e(d.expand("${RUST_BUILD_CC}"))) | ||
109 | config.set(build_section, "linker", e(d.expand("${RUST_BUILD_CCLD}"))) | ||
110 | |||
111 | target_section = "target.{}".format(d.getVar('RUST_TARGET_SYS')) | ||
112 | if target_section != host_section and target_section != build_section: | ||
113 | config.add_section(target_section) | ||
114 | |||
115 | config.set(target_section, "llvm-config", e(llvm_config_target)) | ||
116 | |||
117 | config.set(target_section, "cxx", e(d.expand("${RUST_TARGET_CXX}"))) | ||
118 | config.set(target_section, "cc", e(d.expand("${RUST_TARGET_CC}"))) | ||
119 | config.set(target_section, "linker", e(d.expand("${RUST_TARGET_CCLD}"))) | ||
120 | |||
121 | # [llvm] | ||
122 | config.add_section("llvm") | ||
123 | config.set("llvm", "static-libstdcpp", e(False)) | ||
124 | if "llvm" in (d.getVar('TC_CXX_RUNTIME') or ""): | ||
125 | config.set("llvm", "use-libcxx", e(True)) | ||
126 | |||
127 | # [rust] | ||
128 | config.add_section("rust") | ||
129 | config.set("rust", "rpath", e(True)) | ||
130 | config.set("rust", "remap-debuginfo", e(True)) | ||
131 | config.set("rust", "channel", e(d.expand("${RUST_CHANNEL}"))) | ||
132 | |||
133 | # Whether or not to optimize the compiler and standard library | ||
134 | config.set("rust", "optimize", e(True)) | ||
135 | |||
136 | # Emits extraneous output from tests to ensure that failures of the test | ||
137 | # harness are debuggable just from logfiles | ||
138 | config.set("rust", "verbose-tests", e(True)) | ||
139 | |||
140 | # [build] | ||
141 | config.add_section("build") | ||
142 | config.set("build", "submodules", e(False)) | ||
143 | config.set("build", "docs", e(False)) | ||
144 | config.set("build", "tools", ["rust-demangler",]) | ||
145 | |||
146 | rustc = d.expand("${WORKDIR}/rust-snapshot/bin/rustc") | ||
147 | config.set("build", "rustc", e(rustc)) | ||
148 | |||
149 | # Support for the profiler runtime to generate e.g. coverage report, | ||
150 | # PGO etc. | ||
151 | config.set("build", "profiler", e(False)) | ||
152 | |||
153 | cargo = d.expand("${WORKDIR}/rust-snapshot/bin/cargo") | ||
154 | config.set("build", "cargo", e(cargo)) | ||
155 | |||
156 | config.set("build", "vendor", e(True)) | ||
157 | |||
158 | config.set("build", "target", e([d.getVar("RUST_TARGET_SYS")])) | ||
159 | |||
160 | config.set("build", "host", e([d.getVar("RUST_HOST_SYS")])) | ||
161 | |||
162 | # We can't use BUILD_SYS since that is something the rust snapshot knows | ||
163 | # nothing about when trying to build some stage0 tools (like fabricate) | ||
164 | config.set("build", "build", e(d.getVar("RUST_BUILD_SYS"))) | ||
165 | |||
166 | # [install] | ||
167 | config.add_section("install") | ||
168 | # ./x.py install doesn't have any notion of "destdir" | ||
169 | # but we can prepend ${D} to all the directories instead | ||
170 | config.set("install", "prefix", e(d.getVar("D") + d.getVar("prefix"))) | ||
171 | config.set("install", "bindir", e(d.getVar("D") + d.getVar("bindir"))) | ||
172 | config.set("install", "libdir", e(d.getVar("D") + d.getVar("libdir"))) | ||
173 | config.set("install", "datadir", e(d.getVar("D") + d.getVar("datadir"))) | ||
174 | config.set("install", "mandir", e(d.getVar("D") + d.getVar("mandir"))) | ||
175 | config.set("install", "sysconfdir", e(d.getVar("D") + d.getVar("sysconfdir"))) | ||
176 | |||
177 | with open("config.toml", "w") as f: | ||
178 | f.write('change-id = 116881\n\n') | ||
179 | config.write(f) | ||
180 | |||
181 | # set up ${WORKDIR}/cargo_home | ||
182 | bb.build.exec_func("setup_cargo_environment", d) | ||
183 | } | ||
184 | |||
185 | rust_runx () { | ||
186 | echo "COMPILE ${PN}" "$@" | ||
187 | |||
188 | # CFLAGS, LDFLAGS, CXXFLAGS, CPPFLAGS are used by rust's build for a | ||
189 | # wide range of targets (not just TARGET). Yocto's settings for them will | ||
190 | # be inappropriate, avoid using. | ||
191 | unset CFLAGS | ||
192 | unset LDFLAGS | ||
193 | unset CXXFLAGS | ||
194 | unset CPPFLAGS | ||
195 | |||
196 | export RUSTFLAGS="${RUST_DEBUG_REMAP}" | ||
197 | |||
198 | # Copy the natively built llvm-config into the target so we can run it. Horrible, | ||
199 | # but works! | ||
200 | if [ ${RUST_ALTERNATE_EXE_PATH_NATIVE} != ${RUST_ALTERNATE_EXE_PATH} -a ! -f ${RUST_ALTERNATE_EXE_PATH} ]; then | ||
201 | mkdir -p `dirname ${RUST_ALTERNATE_EXE_PATH}` | ||
202 | cp ${RUST_ALTERNATE_EXE_PATH_NATIVE} ${RUST_ALTERNATE_EXE_PATH} | ||
203 | if [ -e ${STAGING_LIBDIR_NATIVE}/libc++.so.1 ]; then | ||
204 | chrpath -r \$ORIGIN/../../../../../`basename ${STAGING_DIR_NATIVE}`${libdir_native} ${RUST_ALTERNATE_EXE_PATH} | ||
205 | else | ||
206 | chrpath -d ${RUST_ALTERNATE_EXE_PATH} | ||
207 | fi | ||
208 | fi | ||
209 | |||
210 | oe_cargo_fix_env | ||
211 | |||
212 | python3 src/bootstrap/bootstrap.py ${@oe.utils.parallel_make_argument(d, '-j %d')} "$@" --verbose | ||
213 | } | ||
214 | rust_runx[vardepsexclude] += "PARALLEL_MAKE" | ||
215 | |||
216 | require rust-source.inc | ||
217 | require rust-snapshot.inc | ||
218 | |||
219 | INSANE_SKIP:${PN}:class-native = "already-stripped" | ||
220 | FILES:${PN} += "${libdir}/rustlib" | ||
221 | FILES:${PN} += "${libdir}/*.so" | ||
222 | FILES:${PN}-dev = "" | ||
223 | |||
224 | do_compile () { | ||
225 | } | ||
226 | |||
227 | do_test_compile[dirs] = "${B}" | ||
228 | do_test_compile () { | ||
229 | rust_runx build src/tools/remote-test-server --target "${RUST_TARGET_SYS}" | ||
230 | } | ||
231 | |||
232 | ALLOW_EMPTY:${PN} = "1" | ||
233 | |||
234 | PACKAGES =+ "${PN}-rustdoc ${PN}-tools-clippy ${PN}-tools-rustfmt" | ||
235 | FILES:${PN}-rustdoc = "${bindir}/rustdoc" | ||
236 | FILES:${PN}-tools-clippy = "${bindir}/cargo-clippy ${bindir}/clippy-driver" | ||
237 | FILES:${PN}-tools-rustfmt = "${bindir}/rustfmt" | ||
238 | RDEPENDS:${PN}-rustdoc = "${PN}" | ||
239 | RDEPENDS:${PN}-tools-clippy = "${PN}" | ||
240 | RDEPENDS:${PN}-tools-rustfmt = "${PN}" | ||
241 | |||
242 | SUMMARY:${PN}-tools-clippy = "A collection of lints to catch common mistakes and improve your Rust code" | ||
243 | SUMMARY:${PN}-tools-rustfmt = "A tool for formatting Rust code according to style guidelines" | ||
244 | |||
245 | do_install () { | ||
246 | rust_do_install | ||
247 | } | ||
248 | |||
249 | rust_do_install() { | ||
250 | rust_runx install | ||
251 | } | ||
252 | |||
253 | rust_do_install:class-nativesdk() { | ||
254 | export PSEUDO_UNLOAD=1 | ||
255 | rust_runx install | ||
256 | rust_runx install clippy | ||
257 | rust_runx install rustfmt | ||
258 | unset PSEUDO_UNLOAD | ||
259 | |||
260 | install -d ${D}${bindir} | ||
261 | for i in cargo-clippy clippy-driver rustfmt; do | ||
262 | cp build/${RUST_BUILD_SYS}/stage2-tools/${RUST_HOST_SYS}/release/$i ${D}${bindir} | ||
263 | chrpath -r "\$ORIGIN/../lib" ${D}${bindir}/$i | ||
264 | done | ||
265 | |||
266 | chown root:root ${D}/ -R | ||
267 | rm ${D}${libdir}/rustlib/uninstall.sh | ||
268 | rm ${D}${libdir}/rustlib/install.log | ||
269 | rm ${D}${libdir}/rustlib/manifest* | ||
270 | } | ||
271 | |||
272 | EXTRA_TOOLS ?= "cargo-clippy clippy-driver rustfmt" | ||
273 | rust_do_install:class-target() { | ||
274 | export PSEUDO_UNLOAD=1 | ||
275 | rust_runx install | ||
276 | rust_runx install clippy | ||
277 | rust_runx install rustfmt | ||
278 | unset PSEUDO_UNLOAD | ||
279 | |||
280 | install -d ${D}${bindir} | ||
281 | for i in ${EXTRA_TOOLS}; do | ||
282 | cp build/${RUST_BUILD_SYS}/stage2-tools/${RUST_HOST_SYS}/release/$i ${D}${bindir} | ||
283 | chrpath -r "\$ORIGIN/../lib" ${D}${bindir}/$i | ||
284 | done | ||
285 | |||
286 | install -d ${D}${libdir}/rustlib/${RUST_HOST_SYS} | ||
287 | install -m 0644 ${WORKDIR}/rust-targets/${RUST_HOST_SYS}.json ${D}${libdir}/rustlib/${RUST_HOST_SYS}/target.json | ||
288 | |||
289 | chown root:root ${D}/ -R | ||
290 | rm ${D}${libdir}/rustlib/uninstall.sh | ||
291 | rm ${D}${libdir}/rustlib/install.log | ||
292 | rm ${D}${libdir}/rustlib/manifest* | ||
293 | } | ||
294 | |||
295 | addtask do_update_snapshot after do_patch | ||
296 | do_update_snapshot[nostamp] = "1" | ||
297 | |||
298 | # Run with `bitbake -c update_snapshot rust` to update `rust-snapshot.inc` | ||
299 | # with the checksums for the rust snapshot associated with this rustc-src | ||
300 | # tarball. | ||
301 | python do_update_snapshot() { | ||
302 | import json | ||
303 | import re | ||
304 | import sys | ||
305 | |||
306 | from collections import defaultdict | ||
307 | |||
308 | with open(os.path.join(d.getVar("S"), "src", "stage0.json")) as f: | ||
309 | j = json.load(f) | ||
310 | |||
311 | config_dist_server = j['config']['dist_server'] | ||
312 | compiler_date = j['compiler']['date'] | ||
313 | compiler_version = j['compiler']['version'] | ||
314 | |||
315 | src_uri = defaultdict(list) | ||
316 | for k, v in j['checksums_sha256'].items(): | ||
317 | m = re.search(f"dist/{compiler_date}/(?P<component>.*)-{compiler_version}-(?P<arch>.*)-unknown-linux-gnu\\.tar\\.xz", k) | ||
318 | if m: | ||
319 | component = m.group('component') | ||
320 | arch = m.group('arch') | ||
321 | src_uri[arch].append(f"SRC_URI[{component}-snapshot-{arch}.sha256sum] = \"{v}\"") | ||
322 | |||
323 | snapshot = """\ | ||
324 | ## This is information on the rust-snapshot (binary) used to build our current release. | ||
325 | ## snapshot info is taken from rust/src/stage0.json | ||
326 | ## Rust is self-hosting and bootstraps itself with a pre-built previous version of itself. | ||
327 | ## The exact (previous) version that has been used is specified in the source tarball. | ||
328 | ## The version is replicated here. | ||
329 | |||
330 | SNAPSHOT_VERSION = "%s" | ||
331 | |||
332 | """ % compiler_version | ||
333 | |||
334 | for arch, components in src_uri.items(): | ||
335 | snapshot += "\n".join(components) + "\n\n" | ||
336 | |||
337 | snapshot += """\ | ||
338 | SRC_URI += " \\ | ||
339 | ${RUST_DIST_SERVER}/dist/${RUST_STD_SNAPSHOT}.tar.xz;name=rust-std-snapshot-${RUST_BUILD_ARCH};subdir=rust-snapshot-components \\ | ||
340 | ${RUST_DIST_SERVER}/dist/${RUSTC_SNAPSHOT}.tar.xz;name=rustc-snapshot-${RUST_BUILD_ARCH};subdir=rust-snapshot-components \\ | ||
341 | ${RUST_DIST_SERVER}/dist/${CARGO_SNAPSHOT}.tar.xz;name=cargo-snapshot-${RUST_BUILD_ARCH};subdir=rust-snapshot-components \\ | ||
342 | " | ||
343 | |||
344 | RUST_DIST_SERVER = "%s" | ||
345 | |||
346 | RUST_STD_SNAPSHOT = "rust-std-${SNAPSHOT_VERSION}-${RUST_BUILD_ARCH}-unknown-linux-gnu" | ||
347 | RUSTC_SNAPSHOT = "rustc-${SNAPSHOT_VERSION}-${RUST_BUILD_ARCH}-unknown-linux-gnu" | ||
348 | CARGO_SNAPSHOT = "cargo-${SNAPSHOT_VERSION}-${RUST_BUILD_ARCH}-unknown-linux-gnu" | ||
349 | """ % config_dist_server | ||
350 | |||
351 | with open(os.path.join(d.getVar("THISDIR"), "rust-snapshot.inc"), "w") as f: | ||
352 | f.write(snapshot) | ||
353 | } | ||
354 | |||
355 | RUSTLIB_DEP:class-nativesdk = "" | ||
356 | |||
357 | # musl builds include libunwind.a | ||
358 | INSANE_SKIP:${PN} = "staticdev" | ||
359 | |||
360 | BBCLASSEXTEND = "native nativesdk" | ||
361 | |||
362 | # Since 1.70.0 upgrade this fails to build with gold: | ||
363 | # http://errors.yoctoproject.org/Errors/Details/708196/ | ||
364 | # ld: error: version script assignment of to symbol __rust_alloc_error_handler_should_panic failed: symbol not defined | ||
365 | LDFLAGS:append = "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', ' -fuse-ld=bfd', '', d)}" | ||