diff options
Diffstat (limited to 'meta/recipes-devtools/python/python3_3.12.6.bb')
-rw-r--r-- | meta/recipes-devtools/python/python3_3.12.6.bb | 476 |
1 files changed, 476 insertions, 0 deletions
diff --git a/meta/recipes-devtools/python/python3_3.12.6.bb b/meta/recipes-devtools/python/python3_3.12.6.bb new file mode 100644 index 0000000000..858124d104 --- /dev/null +++ b/meta/recipes-devtools/python/python3_3.12.6.bb | |||
@@ -0,0 +1,476 @@ | |||
1 | SUMMARY = "The Python Programming Language" | ||
2 | HOMEPAGE = "http://www.python.org" | ||
3 | DESCRIPTION = "Python is a programming language that lets you work more quickly and integrate your systems more effectively." | ||
4 | LICENSE = "PSF-2.0" | ||
5 | SECTION = "devel/python" | ||
6 | |||
7 | LIC_FILES_CHKSUM = "file://LICENSE;md5=fcf6b249c2641540219a727f35d8d2c2" | ||
8 | |||
9 | SRC_URI = "http://www.python.org/ftp/python/${PV}/Python-${PV}.tar.xz \ | ||
10 | file://run-ptest \ | ||
11 | file://create_manifest3.py \ | ||
12 | file://get_module_deps3.py \ | ||
13 | file://python3-manifest.json \ | ||
14 | file://check_build_completeness.py \ | ||
15 | file://reformat_sysconfig.py \ | ||
16 | file://cgi_py.patch \ | ||
17 | file://0001-Makefile.pre-use-qemu-wrapper-when-gathering-profile.patch \ | ||
18 | file://0001-python3-use-cc_basename-to-replace-CC-for-checking-c.patch \ | ||
19 | file://crosspythonpath.patch \ | ||
20 | file://0001-test_locale.py-correct-the-test-output-format.patch \ | ||
21 | file://0020-configure.ac-setup.py-do-not-add-a-curses-include-pa.patch \ | ||
22 | file://0001-Skip-failing-tests-due-to-load-variability-on-YP-AB.patch \ | ||
23 | file://0001-test_ctypes.test_find-skip-without-tools-sdk.patch \ | ||
24 | file://makerace.patch \ | ||
25 | file://0001-sysconfig.py-use-platlibdir-also-for-purelib.patch \ | ||
26 | file://0001-Lib-pty.py-handle-stdin-I-O-errors-same-way-as-maste.patch \ | ||
27 | file://deterministic_imports.patch \ | ||
28 | file://0001-Avoid-shebang-overflow-on-python-config.py.patch \ | ||
29 | file://0001-Update-test_sysconfig-for-posix_user-purelib.patch \ | ||
30 | file://0001-skip-no_stdout_fileno-test-due-to-load-variability.patch \ | ||
31 | file://0001-test_storlines-skip-due-to-load-variability.patch \ | ||
32 | file://0001-test_shutdown-skip-problematic-test.patch \ | ||
33 | file://0001-gh-107811-tarfile-treat-overflow-in-UID-GID-as-failu.patch \ | ||
34 | file://0001-test_deadlock-skip-problematic-test.patch \ | ||
35 | file://0001-test_active_children-skip-problematic-test.patch \ | ||
36 | file://0001-test_readline-skip-limited-history-test.patch \ | ||
37 | " | ||
38 | |||
39 | SRC_URI:append:class-native = " \ | ||
40 | file://0001-Lib-sysconfig.py-use-prefix-value-from-build-configu.patch \ | ||
41 | " | ||
42 | |||
43 | SRC_URI[sha256sum] = "1999658298cf2fb837dffed8ff3c033ef0c98ef20cf73c5d5f66bed5ab89697c" | ||
44 | |||
45 | # exclude pre-releases for both python 2.x and 3.x | ||
46 | UPSTREAM_CHECK_REGEX = "[Pp]ython-(?P<pver>\d+(\.\d+)+).tar" | ||
47 | |||
48 | CVE_PRODUCT = "python cpython" | ||
49 | |||
50 | CVE_STATUS[CVE-2007-4559] = "disputed: Upstream consider this expected behaviour" | ||
51 | CVE_STATUS[CVE-2019-18348] = "not-applicable-config: This is not exploitable when glibc has CVE-2016-10739 fixed" | ||
52 | CVE_STATUS[CVE-2020-15523] = "not-applicable-platform: Issue only applies on Windows" | ||
53 | CVE_STATUS[CVE-2022-26488] = "not-applicable-platform: Issue only applies on Windows" | ||
54 | # The module will be removed in the future and flaws documented. | ||
55 | CVE_STATUS[CVE-2015-20107] = "upstream-wontfix: The mailcap module is insecure by design, so this can't be fixed in a meaningful way" | ||
56 | CVE_STATUS[CVE-2023-36632] = "disputed: Not an issue, in fact expected behaviour" | ||
57 | |||
58 | PYTHON_MAJMIN = "3.12" | ||
59 | |||
60 | S = "${WORKDIR}/Python-${PV}" | ||
61 | |||
62 | BBCLASSEXTEND = "native nativesdk" | ||
63 | |||
64 | inherit autotools pkgconfig qemu ptest multilib_header update-alternatives | ||
65 | |||
66 | MULTILIB_SUFFIX = "${@d.getVar('base_libdir',1).split('/')[-1]}" | ||
67 | |||
68 | ALTERNATIVE:${PN}-dev = "python3-config" | ||
69 | ALTERNATIVE_LINK_NAME[python3-config] = "${bindir}/python${PYTHON_MAJMIN}-config" | ||
70 | ALTERNATIVE_TARGET[python3-config] = "${bindir}/python${PYTHON_MAJMIN}-config-${MULTILIB_SUFFIX}" | ||
71 | |||
72 | |||
73 | DEPENDS = "bzip2-replacement-native expat libffi bzip2 openssl sqlite3 zlib virtual/libintl xz virtual/crypt util-linux-libuuid libtirpc libnsl2 autoconf-archive-native ncurses" | ||
74 | DEPENDS:append:class-target = " python3-native" | ||
75 | DEPENDS:append:class-nativesdk = " python3-native" | ||
76 | |||
77 | EXTRA_OECONF = " --without-ensurepip --enable-shared --with-platlibdir=${baselib} --with-system-expat" | ||
78 | EXTRA_OECONF:append:class-native = " --bindir=${bindir}/${PN}" | ||
79 | EXTRA_OECONF:append:class-target = " --with-build-python=nativepython3" | ||
80 | EXTRA_OECONF:append:class-nativesdk = " --with-build-python=nativepython3" | ||
81 | |||
82 | export CROSSPYTHONPATH="${STAGING_LIBDIR_NATIVE}/python${PYTHON_MAJMIN}/lib-dynload/" | ||
83 | |||
84 | EXTRANATIVEPATH += "python3-native" | ||
85 | |||
86 | # LTO will be enabled via packageconfig depending upong distro features | ||
87 | LTO:class-target = "" | ||
88 | |||
89 | CACHED_CONFIGUREVARS = " \ | ||
90 | ac_cv_file__dev_ptmx=yes \ | ||
91 | ac_cv_file__dev_ptc=no \ | ||
92 | ac_cv_working_tzset=yes \ | ||
93 | " | ||
94 | # set thread stack size to 2MB on musl for interpreter and stdlib C extensions | ||
95 | # so it does not run into stack limits due to musl's small thread stack | ||
96 | # This is only needed to build interpreter and not the subsequent modules | ||
97 | # Thats why CFLAGS_NODIST is modified instead of CFLAGS | ||
98 | CACHED_CONFIGUREVARS:append:libc-musl = "\ | ||
99 | CFLAGS_NODIST='${CFLAGS} -DTHREAD_STACK_SIZE=0x200000' \ | ||
100 | " | ||
101 | |||
102 | # PGO currently causes builds to not be reproducible so disable by default, see YOCTO #13407 | ||
103 | PACKAGECONFIG ??= "editline gdbm ${@bb.utils.filter('DISTRO_FEATURES', 'lto', d)}" | ||
104 | PACKAGECONFIG[readline] = "--with-readline=readline,,readline,,,editline" | ||
105 | PACKAGECONFIG[editline] = "--with-readline=editline,,libedit,,,readline" | ||
106 | # Use profile guided optimisation by running PyBench inside qemu-user | ||
107 | PACKAGECONFIG[pgo] = "--enable-optimizations,,qemu-native" | ||
108 | PACKAGECONFIG[tk] = ",,tk" | ||
109 | PACKAGECONFIG[tcl] = ",,tcl" | ||
110 | PACKAGECONFIG[gdbm] = ",,gdbm" | ||
111 | PACKAGECONFIG[lto] = "--with-lto,--without-lto" | ||
112 | PACKAGECONFIG[staticlibpython] = "--with-static-libpython,--without-static-libpython" | ||
113 | |||
114 | do_configure:prepend () { | ||
115 | mkdir -p ${B}/Modules | ||
116 | cat > ${B}/Modules/Setup.local << EOF | ||
117 | *disabled* | ||
118 | ${@bb.utils.contains('PACKAGECONFIG', 'gdbm', '', '_gdbm _dbm', d)} | ||
119 | ${@bb.utils.contains_any('PACKAGECONFIG', 'readline editline', '', 'readline', d)} | ||
120 | ${@bb.utils.contains('PACKAGECONFIG', 'tk', '', '_tkinter', d)} | ||
121 | EOF | ||
122 | } | ||
123 | |||
124 | CPPFLAGS += "-I${STAGING_INCDIR}/ncursesw -I${STAGING_INCDIR}/uuid" | ||
125 | |||
126 | # COMPILEALL_OPTS= ensures that .pyc are not compiled in parallel | ||
127 | # This was found to lock up builds, break reproducibility, and produce strange file ownership | ||
128 | # races. | ||
129 | # | ||
130 | # The upstream commit introducing the change was: | ||
131 | # https://github.com/python/cpython/commit/1a2dd82f56bd813aacc570e172cefe55a8a41504 | ||
132 | # | ||
133 | # The build lock up issue is reported here: | ||
134 | # https://bugs.python.org/issue45945 | ||
135 | # | ||
136 | # The repro failures are documented here: | ||
137 | # https://autobuilder.yocto.io/pub/repro-fail/oe-reproducible-20211130-yr_o1a8d/packages/diff-html/ | ||
138 | |||
139 | EXTRA_OEMAKE = '\ | ||
140 | STAGING_LIBDIR=${STAGING_LIBDIR} \ | ||
141 | STAGING_INCDIR=${STAGING_INCDIR} \ | ||
142 | LIB=${baselib} \ | ||
143 | COMPILEALL_OPTS= \ | ||
144 | ' | ||
145 | |||
146 | # Generate a Profile Guided Optimisation wrapper script that uses qemu-user for | ||
147 | # all cross builds. | ||
148 | write_pgo_wrapper:class-native = ":" | ||
149 | write_pgo_wrapper() { | ||
150 | if ${@bb.utils.contains('PACKAGECONFIG', 'pgo', 'true', 'false', d)}; then | ||
151 | cat >pgo-wrapper <<EOF | ||
152 | #!/bin/sh | ||
153 | cd ${B} | ||
154 | ${@qemu_wrapper_cmdline(d, '${STAGING_DIR_TARGET}', ['${B}', '${STAGING_DIR_TARGET}/${base_libdir}'])} "\$@" | ||
155 | EOF | ||
156 | chmod +x pgo-wrapper | ||
157 | fi | ||
158 | } | ||
159 | |||
160 | do_compile:prepend() { | ||
161 | write_pgo_wrapper | ||
162 | } | ||
163 | |||
164 | do_install:prepend() { | ||
165 | ${UNPACKDIR}/check_build_completeness.py ${T}/log.do_compile | ||
166 | } | ||
167 | |||
168 | do_install:append:class-target() { | ||
169 | oe_multilib_header python${PYTHON_MAJMIN}/pyconfig.h | ||
170 | } | ||
171 | |||
172 | do_install:append:class-native() { | ||
173 | # Make sure we use /usr/bin/env python | ||
174 | for PYTHSCRIPT in `grep -rIl ${bindir}/${PN}/python ${D}${bindir}/${PN}`; do | ||
175 | sed -i -e '1s|^#!.*|#!/usr/bin/env python3|' $PYTHSCRIPT | ||
176 | done | ||
177 | # Add a symlink to the native Python so that scripts can just invoke | ||
178 | # "nativepython" and get the right one without needing absolute paths | ||
179 | # (these often end up too long for the #! parser in the kernel as the | ||
180 | # buffer is 128 bytes long). | ||
181 | ln -s python3-native/python3 ${D}${bindir}/nativepython3 | ||
182 | |||
183 | # Remove the opt-1.pyc and opt-2.pyc files. There are over 3,000 of them | ||
184 | # and the overhead in each recipe-sysroot-native isn't worth it, particularly | ||
185 | # when they're only used for python called with -O or -OO. | ||
186 | #find ${D} -name *opt-*.pyc -delete | ||
187 | # Remove all pyc files. There are a ton of them and it is probably faster to let | ||
188 | # python create the ones it wants at runtime rather than manage in the sstate | ||
189 | # tarballs and sysroot creation. | ||
190 | find ${D} -name *.pyc -delete | ||
191 | |||
192 | # Nothing should be looking into ${B} for python3-native | ||
193 | sed -i -e 's:${B}:/build/path/unavailable/:g' \ | ||
194 | ${D}/${libdir}/python${PYTHON_MAJMIN}/config-${PYTHON_MAJMIN}${PYTHON_ABI}*/Makefile | ||
195 | |||
196 | # disable the lookup in user's site-packages globally | ||
197 | sed -i 's#ENABLE_USER_SITE = None#ENABLE_USER_SITE = False#' ${D}${libdir}/python${PYTHON_MAJMIN}/site.py | ||
198 | |||
199 | # python3-config needs to be in /usr/bin and not in a subdir of it to work properly | ||
200 | mv ${D}/${bindir}/${PN}/python*config ${D}/${bindir}/ | ||
201 | } | ||
202 | |||
203 | do_install:append() { | ||
204 | for c in ${D}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py; do | ||
205 | python3 ${UNPACKDIR}/reformat_sysconfig.py $c | ||
206 | done | ||
207 | rm -f ${D}${libdir}/python${PYTHON_MAJMIN}/__pycache__/_sysconfigdata*.cpython* | ||
208 | |||
209 | mkdir -p ${D}${libdir}/python-sysconfigdata | ||
210 | sysconfigfile=`find ${D} -name _sysconfig*.py` | ||
211 | sed -i \ | ||
212 | -e "s,^ 'LIBDIR'.*, 'LIBDIR': '${STAGING_LIBDIR}'\,,g" \ | ||
213 | -e "s,^ 'INCLUDEDIR'.*, 'INCLUDEDIR': '${STAGING_INCDIR}'\,,g" \ | ||
214 | -e "s,^ 'CONFINCLUDEDIR'.*, 'CONFINCLUDEDIR': '${STAGING_INCDIR}'\,,g" \ | ||
215 | -e "s,^ 'INCLUDEPY'.*, 'INCLUDEPY': '${STAGING_INCDIR}/python${PYTHON_MAJMIN}'\,,g" \ | ||
216 | -e "s,^ 'CONFINCLUDEPY'.*, 'CONFINCLUDEPY': '${STAGING_INCDIR}/python${PYTHON_MAJMIN}'\,,g" \ | ||
217 | -e "s,${B},/build/path/unavailable/,g" \ | ||
218 | $sysconfigfile | ||
219 | cp $sysconfigfile ${D}${libdir}/python-sysconfigdata/_sysconfigdata.py | ||
220 | |||
221 | |||
222 | # Unfortunately the following pyc files are non-deterministc due to 'frozenset' | ||
223 | # being written without strict ordering, even with PYTHONHASHSEED = 0 | ||
224 | # Upstream is discussing ways to solve the issue properly, until then let's | ||
225 | # just not install the problematic files. | ||
226 | # More info: http://benno.id.au/blog/2013/01/15/python-determinism | ||
227 | rm -f ${D}${libdir}/python${PYTHON_MAJMIN}/test/__pycache__/test_range.cpython* | ||
228 | rm -f ${D}${libdir}/python${PYTHON_MAJMIN}/test/__pycache__/test_xml_etree.cpython* | ||
229 | |||
230 | # Similar to the above, we're getting reproducibility issues with | ||
231 | # /usr/lib/python3.10/__pycache__/traceback.cpython-310.pyc | ||
232 | # so remove it too | ||
233 | rm -f ${D}${libdir}/python${PYTHON_MAJMIN}/__pycache__/traceback.cpython* | ||
234 | |||
235 | # Remove the opt-1.pyc and opt-2.pyc files. They effectively waste space on embedded | ||
236 | # style targets as they're only used when python is called with the -O or -OO options | ||
237 | # which is rare. | ||
238 | find ${D} -name *opt-*.pyc -delete | ||
239 | } | ||
240 | |||
241 | do_install:append:class-nativesdk () { | ||
242 | # Make sure we use /usr/bin/env python | ||
243 | for PYTHSCRIPT in `grep -rIl ${bindir}/python ${D}${bindir}`; do | ||
244 | sed -i -e '1s|^#!.*|#!/usr/bin/env python3|' $PYTHSCRIPT | ||
245 | done | ||
246 | create_wrapper ${D}${bindir}/python${PYTHON_MAJMIN} TERMINFO_DIRS='${sysconfdir}/terminfo:/etc/terminfo:/usr/share/terminfo:/usr/share/misc/terminfo:/lib/terminfo' PYTHONNOUSERSITE='1' | ||
247 | } | ||
248 | |||
249 | do_install_ptest:append:class-target:libc-musl () { | ||
250 | sed -i -e 's|SKIPPED_TESTS=|SKIPPED_TESTS="-x test__locale -x test_c_locale_coercion -x test_locale -x test_os test_re -x test__xxsubinterpreters -x test_threading"|' ${D}${PTEST_PATH}/run-ptest | ||
251 | } | ||
252 | |||
253 | SYSROOT_PREPROCESS_FUNCS:append:class-target = " provide_target_config_script" | ||
254 | SYSROOT_PREPROCESS_FUNCS:append:class-nativesdk = " provide_target_config_script" | ||
255 | |||
256 | # This is installed into /usr/python-target-config/ and not /usr/bin | ||
257 | # because adding target sysroot's /usr/bin/ to PATH has unwanted side effects | ||
258 | # in components erroneously picking up other target executables from it | ||
259 | provide_target_config_script() { | ||
260 | install -d ${SYSROOT_DESTDIR}${prefix}/python-target-config/ | ||
261 | install ${D}/${bindir}/python3-config ${SYSROOT_DESTDIR}/${prefix}/python-target-config/ | ||
262 | install ${D}/${bindir}/python${PYTHON_MAJMIN}-config ${SYSROOT_DESTDIR}/${prefix}/python-target-config/ | ||
263 | } | ||
264 | SYSROOT_DIRS += "${prefix}/python-target-config/" | ||
265 | |||
266 | SSTATE_SCAN_FILES += "Makefile _sysconfigdata.py" | ||
267 | SSTATE_HASHEQUIV_FILEMAP = " \ | ||
268 | populate_sysroot:*/lib*/python3*/_sysconfigdata*.py:${TMPDIR} \ | ||
269 | populate_sysroot:*/lib*/python3*/_sysconfigdata*.py:${COREBASE} \ | ||
270 | populate_sysroot:*/lib*/python3*/config-*/Makefile:${TMPDIR} \ | ||
271 | populate_sysroot:*/lib*/python3*/config-*/Makefile:${COREBASE} \ | ||
272 | populate_sysroot:*/lib*/python-sysconfigdata/_sysconfigdata.py:${TMPDIR} \ | ||
273 | populate_sysroot:*/lib*/python-sysconfigdata/_sysconfigdata.py:${COREBASE} \ | ||
274 | " | ||
275 | PACKAGE_PREPROCESS_FUNCS += "py_package_preprocess" | ||
276 | |||
277 | py_package_preprocess () { | ||
278 | # Remove references to buildmachine paths in target Makefile and _sysconfigdata | ||
279 | sed -i -e 's:--sysroot=${STAGING_DIR_TARGET}::g' -e s:'--with-libtool-sysroot=${STAGING_DIR_TARGET}'::g \ | ||
280 | -e 's|${DEBUG_PREFIX_MAP}||g' \ | ||
281 | -e 's:${HOSTTOOLS_DIR}/::g' \ | ||
282 | -e 's:${RECIPE_SYSROOT_NATIVE}::g' \ | ||
283 | -e 's:${RECIPE_SYSROOT}::g' \ | ||
284 | -e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \ | ||
285 | ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/config-${PYTHON_MAJMIN}${PYTHON_ABI}*/Makefile \ | ||
286 | ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py \ | ||
287 | ${PKGD}/${bindir}/python${PYTHON_MAJMIN}-config | ||
288 | |||
289 | # Reformat _sysconfigdata after modifying it so that it remains | ||
290 | # reproducible | ||
291 | for c in ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py; do | ||
292 | python3 ${UNPACKDIR}/reformat_sysconfig.py $c | ||
293 | done | ||
294 | |||
295 | # Recompile _sysconfigdata after modifying it | ||
296 | cd ${PKGD} | ||
297 | sysconfigfile=`find . -name _sysconfigdata_*.py` | ||
298 | ${STAGING_BINDIR_NATIVE}/python3-native/python3 \ | ||
299 | -c "from py_compile import compile; compile('$sysconfigfile')" | ||
300 | ${STAGING_BINDIR_NATIVE}/python3-native/python3 \ | ||
301 | -c "from py_compile import compile; compile('$sysconfigfile', optimize=1)" | ||
302 | ${STAGING_BINDIR_NATIVE}/python3-native/python3 \ | ||
303 | -c "from py_compile import compile; compile('$sysconfigfile', optimize=2)" | ||
304 | cd - | ||
305 | |||
306 | mv ${PKGD}/${bindir}/python${PYTHON_MAJMIN}-config ${PKGD}/${bindir}/python${PYTHON_MAJMIN}-config-${MULTILIB_SUFFIX} | ||
307 | |||
308 | #Remove the unneeded copy of target sysconfig data | ||
309 | rm -rf ${PKGD}/${libdir}/python-sysconfigdata | ||
310 | } | ||
311 | |||
312 | # We want bytecode precompiled .py files (.pyc's) by default | ||
313 | # but the user may set it on their own conf | ||
314 | INCLUDE_PYCS ?= "1" | ||
315 | |||
316 | python(){ | ||
317 | import collections, json | ||
318 | |||
319 | filename = os.path.join(d.getVar('THISDIR'), 'python3', 'python3-manifest.json') | ||
320 | # This python changes the datastore based on the contents of a file, so mark | ||
321 | # that dependency. | ||
322 | bb.parse.mark_dependency(d, filename) | ||
323 | |||
324 | with open(filename) as manifest_file: | ||
325 | manifest_str = manifest_file.read() | ||
326 | json_start = manifest_str.find('# EOC') + 6 | ||
327 | manifest_file.seek(json_start) | ||
328 | manifest_str = manifest_file.read() | ||
329 | python_manifest = json.loads(manifest_str, object_pairs_hook=collections.OrderedDict) | ||
330 | |||
331 | # First set RPROVIDES for -native case | ||
332 | # Hardcoded since it cant be python3-native-foo, should be python3-foo-native | ||
333 | pn = 'python3' | ||
334 | rprovides = (d.getVar('RPROVIDES') or "").split() | ||
335 | |||
336 | # ${PN}-misc-native is not in the manifest | ||
337 | rprovides.append(pn + '-misc-native') | ||
338 | |||
339 | for key in python_manifest: | ||
340 | pypackage = pn + '-' + key + '-native' | ||
341 | if pypackage not in rprovides: | ||
342 | rprovides.append(pypackage) | ||
343 | |||
344 | d.setVar('RPROVIDES:class-native', ' '.join(rprovides)) | ||
345 | |||
346 | # Then work on the target | ||
347 | include_pycs = d.getVar('INCLUDE_PYCS') | ||
348 | |||
349 | packages = d.getVar('PACKAGES').split() | ||
350 | pn = d.getVar('PN') | ||
351 | |||
352 | newpackages=[] | ||
353 | for key in python_manifest: | ||
354 | pypackage = pn + '-' + key | ||
355 | |||
356 | if pypackage not in packages: | ||
357 | # We need to prepend, otherwise python-misc gets everything | ||
358 | # so we use a new variable | ||
359 | newpackages.append(pypackage) | ||
360 | |||
361 | # "Build" python's manifest FILES, RDEPENDS and SUMMARY | ||
362 | d.setVar('FILES:' + pypackage, '') | ||
363 | for value in python_manifest[key]['files']: | ||
364 | d.appendVar('FILES:' + pypackage, ' ' + value) | ||
365 | |||
366 | # Add cached files | ||
367 | if include_pycs == '1': | ||
368 | for value in python_manifest[key]['cached']: | ||
369 | d.appendVar('FILES:' + pypackage, ' ' + value) | ||
370 | |||
371 | for value in python_manifest[key]['rdepends']: | ||
372 | # Make it work with or without $PN | ||
373 | if '${PN}' in value: | ||
374 | value=value.split('-', 1)[1] | ||
375 | d.appendVar('RDEPENDS:' + pypackage, ' ' + pn + '-' + value) | ||
376 | |||
377 | for value in python_manifest[key].get('rrecommends', ()): | ||
378 | if '${PN}' in value: | ||
379 | value=value.split('-', 1)[1] | ||
380 | d.appendVar('RRECOMMENDS:' + pypackage, ' ' + pn + '-' + value) | ||
381 | |||
382 | d.setVar('SUMMARY:' + pypackage, python_manifest[key]['summary']) | ||
383 | |||
384 | # Prepending so to avoid python-misc getting everything | ||
385 | packages = newpackages + packages | ||
386 | d.setVar('PACKAGES', ' '.join(packages)) | ||
387 | d.setVar('ALLOW_EMPTY:${PN}-modules', '1') | ||
388 | d.setVar('ALLOW_EMPTY:${PN}-pkgutil', '1') | ||
389 | |||
390 | if "pgo" in d.getVar("PACKAGECONFIG").split() and not bb.utils.contains('MACHINE_FEATURES', 'qemu-usermode', True, False, d): | ||
391 | bb.fatal("pgo cannot be enabled as there is no qemu-usermode support for this architecture/machine") | ||
392 | } | ||
393 | |||
394 | # Files needed to create a new manifest | ||
395 | |||
396 | do_create_manifest() { | ||
397 | # This task should be run with every new release of Python. | ||
398 | # We must ensure that PACKAGECONFIG enables everything when creating | ||
399 | # a new manifest, this is to base our new manifest on a complete | ||
400 | # native python build, containing all dependencies, otherwise the task | ||
401 | # wont be able to find the required files. | ||
402 | # e.g. BerkeleyDB is an optional build dependency so it may or may not | ||
403 | # be present, we must ensure it is. | ||
404 | |||
405 | cp ${UNPACKDIR}/create_manifest3.py ${WORKDIR} | ||
406 | cd ${WORKDIR} | ||
407 | # This needs to be executed by python-native and NOT by HOST's python | ||
408 | nativepython3 create_manifest3.py ${PYTHON_MAJMIN} | ||
409 | cp python3-manifest.json.new ${THISDIR}/python3/python3-manifest.json | ||
410 | } | ||
411 | |||
412 | # bitbake python -c create_manifest | ||
413 | # Make sure we have native python ready when we create a new manifest | ||
414 | addtask do_create_manifest after do_patch do_prepare_recipe_sysroot | ||
415 | |||
416 | # manual dependency additions | ||
417 | RRECOMMENDS:${PN}-core:append:class-nativesdk = " nativesdk-python3-modules" | ||
418 | RRECOMMENDS:${PN}-crypt:append:class-target = " ${MLPREFIX}openssl ${MLPREFIX}ca-certificates" | ||
419 | RRECOMMENDS:${PN}-crypt:append:class-nativesdk = " ${MLPREFIX}openssl ${MLPREFIX}ca-certificates" | ||
420 | |||
421 | # For historical reasons PN is empty and provided by python3-modules | ||
422 | FILES:${PN} = "" | ||
423 | RPROVIDES:${PN}-modules = "${PN}" | ||
424 | |||
425 | FILES:${PN}-pydoc += "${bindir}/pydoc${PYTHON_MAJMIN} ${bindir}/pydoc3" | ||
426 | FILES:${PN}-idle += "${bindir}/idle3 ${bindir}/idle${PYTHON_MAJMIN}" | ||
427 | |||
428 | # provide python-pyvenv from python3-venv | ||
429 | RPROVIDES:${PN}-venv += "${MLPREFIX}python3-pyvenv" | ||
430 | |||
431 | # package libpython3 | ||
432 | PACKAGES =+ "libpython3 libpython3-staticdev" | ||
433 | FILES:libpython3 = "${libdir}/libpython*.so.*" | ||
434 | FILES:libpython3-staticdev += "${libdir}/python${PYTHON_MAJMIN}/config-${PYTHON_MAJMIN}-*/libpython${PYTHON_MAJMIN}.a" | ||
435 | INSANE_SKIP:${PN}-dev += "dev-elf" | ||
436 | INSANE_SKIP:${PN}-ptest = "dev-deps" | ||
437 | |||
438 | # catch all the rest (unsorted) | ||
439 | PACKAGES += "${PN}-misc" | ||
440 | RDEPENDS:${PN}-misc += "\ | ||
441 | ${PN}-audio \ | ||
442 | ${PN}-codecs \ | ||
443 | ${PN}-core \ | ||
444 | ${PN}-email \ | ||
445 | ${PN}-numbers \ | ||
446 | ${PN}-pickle \ | ||
447 | ${PN}-pydoc \ | ||
448 | " | ||
449 | RDEPENDS:${PN}-modules:append:class-target = " ${MLPREFIX}python3-misc" | ||
450 | RDEPENDS:${PN}-modules:append:class-nativesdk = " ${MLPREFIX}python3-misc" | ||
451 | RDEPENDS:${PN}-modules:append:class-target = " ${@bb.utils.contains('PACKAGECONFIG', 'gdbm', '${MLPREFIX}python3-gdbm', '', d)}" | ||
452 | FILES:${PN}-misc = "${libdir}/python${PYTHON_MAJMIN} ${libdir}/python${PYTHON_MAJMIN}/lib-dynload" | ||
453 | |||
454 | # catch manpage | ||
455 | PACKAGES += "${PN}-man" | ||
456 | FILES:${PN}-man = "${datadir}/man" | ||
457 | |||
458 | # See https://bugs.python.org/issue18748 and https://bugs.python.org/issue37395 | ||
459 | RDEPENDS:libpython3:append:libc-glibc = " libgcc" | ||
460 | RDEPENDS:${PN}-ctypes:append:libc-glibc = " ${MLPREFIX}ldconfig" | ||
461 | RDEPENDS:${PN}-ptest = "${PN}-modules ${PN}-tests ${PN}-dev ${PN}-cgitb ${PN}-zipapp unzip bzip2 libgcc tzdata coreutils sed gcc g++ binutils \ | ||
462 | locale-base-fr-fr locale-base-en-us locale-base-de-de" | ||
463 | RDEPENDS:${PN}-ptest:append:libc-glibc = " locale-base-tr-tr" | ||
464 | RDEPENDS:${PN}-tkinter += "${@bb.utils.contains('PACKAGECONFIG', 'tk', '${MLPREFIX}tk ${MLPREFIX}tk-lib', '', d)}" | ||
465 | RDEPENDS:${PN}-idle += "${@bb.utils.contains('PACKAGECONFIG', 'tk', '${PN}-tkinter ${MLPREFIX}tcl', '', d)}" | ||
466 | DEV_PKG_DEPENDENCY = "" | ||
467 | RDEPENDS:${PN}-pydoc += "${PN}-io" | ||
468 | |||
469 | RDEPENDS:${PN}-tests:append:class-target = " ${MLPREFIX}bash" | ||
470 | RDEPENDS:${PN}-tests:append:class-nativesdk = " ${MLPREFIX}bash" | ||
471 | |||
472 | # Python's tests contain large numbers of files we don't need in the recipe sysroots | ||
473 | SYSROOT_PREPROCESS_FUNCS += " py3_sysroot_cleanup" | ||
474 | py3_sysroot_cleanup () { | ||
475 | rm -rf ${SYSROOT_DESTDIR}${libdir}/python${PYTHON_MAJMIN}/test | ||
476 | } | ||