summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/clang/libcxx_git.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/clang/libcxx_git.bb')
-rw-r--r--meta/recipes-devtools/clang/libcxx_git.bb124
1 files changed, 124 insertions, 0 deletions
diff --git a/meta/recipes-devtools/clang/libcxx_git.bb b/meta/recipes-devtools/clang/libcxx_git.bb
new file mode 100644
index 0000000000..d355fc3a0f
--- /dev/null
+++ b/meta/recipes-devtools/clang/libcxx_git.bb
@@ -0,0 +1,124 @@
1# Copyright (C) 2015 Khem Raj <raj.khem@gmail.com>
2# Released under the MIT license (see COPYING.MIT for the terms)
3
4SUMMARY = "libc++ is a new implementation of the C++ standard library, targeting C++11 and above"
5HOMEPAGE = "http://libcxx.llvm.org/"
6SECTION = "base"
7
8require common-clang.inc
9require common-source.inc
10
11inherit cmake python3native
12
13BPN = "libcxx"
14
15PACKAGECONFIG ??= "compiler-rt exceptions ${@bb.utils.contains("TC_CXX_RUNTIME", "llvm", "unwind unwind-shared", "", d)}"
16PACKAGECONFIG:append:armv5 = " no-atomics"
17PACKAGECONFIG:remove:class-native = "compiler-rt"
18PACKAGECONFIG[unwind] = "-DLIBCXXABI_USE_LLVM_UNWINDER=ON -DLIBCXXABI_ENABLE_STATIC_UNWINDER=ON,-DLIBCXXABI_USE_LLVM_UNWINDER=OFF,,"
19PACKAGECONFIG[exceptions] = "-DLIBCXXABI_ENABLE_EXCEPTIONS=ON -DLIBCXX_ENABLE_EXCEPTIONS=ON,-DLIBCXXABI_ENABLE_EXCEPTIONS=OFF -DLIBCXX_ENABLE_EXCEPTIONS=OFF -DCMAKE_REQUIRED_FLAGS='-fno-exceptions',"
20PACKAGECONFIG[no-atomics] = "-D_LIBCXXABI_HAS_ATOMIC_BUILTINS=OFF -DCMAKE_SHARED_LINKER_FLAGS='-latomic',,"
21PACKAGECONFIG[compiler-rt] = "-DLIBCXX_USE_COMPILER_RT=ON -DLIBCXXABI_USE_COMPILER_RT=ON -DLIBUNWIND_USE_COMPILER_RT=ON,,compiler-rt"
22PACKAGECONFIG[unwind-shared] = "-DLIBUNWIND_ENABLE_SHARED=ON,-DLIBUNWIND_ENABLE_SHARED=OFF,,"
23
24DEPENDS += "ninja-native"
25DEPENDS:append:class-target = " virtual/cross-c++ clang-cross-${TARGET_ARCH} virtual/${MLPREFIX}libc virtual/${MLPREFIX}compilerlibs"
26DEPENDS:append:class-nativesdk = " virtual/cross-c++ clang-crosssdk-${SDK_SYS} nativesdk-compiler-rt"
27DEPENDS:append:class-native = " clang-native compiler-rt-native"
28DEPENDS:remove:class-native = "libcxx-native"
29
30COMPILER_RT ?= "${@bb.utils.contains("PACKAGECONFIG", "compiler-rt", "-rtlib=compiler-rt", "-rtlib=libgcc", d)}"
31UNWINDLIB ?= "${@bb.utils.contains("PACKAGECONFIG", "unwind", "-unwindlib=none", "-unwindlib=libgcc", d)}"
32LIBCPLUSPLUS ?= "-stdlib=libstdc++"
33# Trick clang.bbclass into not creating circular dependencies
34UNWINDLIB:class-nativesdk = "-unwindlib=libgcc"
35LIBCPLUSPLUS:class-nativesdk = "-stdlib=libstdc++"
36UNWINDLIB:class-native = "-unwindlib=libgcc"
37LIBCPLUSPLUS:class-native = "-stdlib=libstdc++"
38
39LDFLAGS:append = " ${UNWINDLIB}"
40
41INHIBIT_DEFAULT_DEPS = "1"
42
43LIC_FILES_CHKSUM = "file://libcxx/LICENSE.TXT;md5=55d89dd7eec8d3b4204b680e27da3953 \
44 file://libcxxabi/LICENSE.TXT;md5=7b9334635b542c56868400a46b272b1e \
45 file://libunwind/LICENSE.TXT;md5=f66970035d12f196030658b11725e1a1 \
46"
47
48OECMAKE_TARGET_COMPILE = "${@bb.utils.contains("TC_CXX_RUNTIME", "llvm", "unwind", "", d)} cxxabi cxx"
49OECMAKE_TARGET_INSTALL = "${@bb.utils.contains("TC_CXX_RUNTIME", "llvm", "install-unwind", "", d)} install-cxxabi install-cxx"
50
51CC = "${CCACHE}${HOST_PREFIX}clang ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
52CXX = "${CCACHE}${HOST_PREFIX}clang++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
53BUILD_CC = "${CCACHE}clang ${BUILD_CC_ARCH}"
54BUILD_CXX = "${CCACHE}clang++ ${BUILD_CC_ARCH}"
55LDFLAGS += "${COMPILER_RT} ${UNWINDLIB} ${LIBCPLUSPLUS}"
56CXXFLAGS += "${LIBCPLUSPLUS}"
57
58TOOLCHAIN = "clang"
59TOOLCHAIN_NATIVE = "clang"
60
61OECMAKE_SOURCEPATH = "${S}/llvm"
62EXTRA_OECMAKE += "\
63 -DCMAKE_BUILD_TYPE=RelWithDebInfo \
64 -DLLVM_ENABLE_PER_TARGET_RUNTIME_DIR=OFF \
65 -DCMAKE_CROSSCOMPILING=ON \
66 -DLLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN=ON \
67 -DLLVM_ENABLE_RTTI=ON \
68 -DLIBUNWIND_ENABLE_CROSS_UNWINDING=ON \
69 -DLIBCXX_ENABLE_STATIC_ABI_LIBRARY=ON \
70 -DLIBCXXABI_INCLUDE_TESTS=OFF \
71 -DLIBCXXABI_ENABLE_SHARED=ON \
72 -DLIBCXXABI_LIBCXX_INCLUDES=${S}/libcxx/include \
73 -DLIBCXX_CXX_ABI=libcxxabi \
74 -DLIBCXX_CXX_ABI_INCLUDE_PATHS=${S}/libcxxabi/include \
75 -DLIBCXX_CXX_ABI_LIBRARY_PATH=${B}/lib${LLVM_LIBDIR_SUFFIX} \
76 -S ${S}/runtimes \
77 -DLLVM_ENABLE_RUNTIMES='libcxx;libcxxabi;libunwind' \
78 -DLLVM_RUNTIME_TARGETS=${HOST_ARCH} \
79 -DLLVM_LIBDIR_SUFFIX=${LLVM_LIBDIR_SUFFIX} \
80 -DLLVM_APPEND_VC_REV=OFF \
81 -DCMAKE_BUILD_WITH_INSTALL_RPATH=ON \
82"
83
84EXTRA_OECMAKE:append:class-target = " \
85 -DCMAKE_AR=${STAGING_BINDIR_TOOLCHAIN}/${AR} \
86 -DCMAKE_NM=${STAGING_BINDIR_TOOLCHAIN}/${NM} \
87 -DCMAKE_RANLIB=${STAGING_BINDIR_TOOLCHAIN}/${RANLIB} \
88 -DLLVM_HOST_TRIPLE=${TARGET_SYS} \
89 -DCMAKE_POSITION_INDEPENDENT_CODE=ON \
90"
91
92EXTRA_OECMAKE:append:class-nativesdk = " \
93 -DCMAKE_AR=${STAGING_BINDIR_TOOLCHAIN}/${AR} \
94 -DCMAKE_NM=${STAGING_BINDIR_TOOLCHAIN}/${NM} \
95 -DCMAKE_RANLIB=${STAGING_BINDIR_TOOLCHAIN}/${RANLIB} \
96 -DLLVM_DEFAULT_TARGET_TRIPLE=${HOST_SYS} \
97"
98
99EXTRA_OECMAKE:append:libc-musl = " -DLIBCXX_HAS_MUSL_LIBC=ON "
100
101CXXFLAGS:append:armv5 = " -mfpu=vfp2"
102
103ALLOW_EMPTY:${PN} = "1"
104
105PROVIDES:append:runtime-llvm = " libunwind"
106
107do_install:append() {
108 if ${@bb.utils.contains("TC_CXX_RUNTIME", "llvm", "true", "false", d)}
109 then
110 for f in libunwind.h __libunwind_config.h unwind.h unwind_itanium.h unwind_arm_ehabi.h
111 do
112 install -Dm 0644 ${S}/libunwind/include/$f ${D}${includedir}/$f
113 done
114 install -d ${D}${libdir}/pkgconfig
115 sed -e 's,@LIBDIR@,${libdir},g;s,@VERSION@,${PV},g' ${S}/libunwind/libunwind.pc.in > ${D}${libdir}/pkgconfig/libunwind.pc
116 fi
117}
118
119PACKAGES:append:runtime-llvm = " libunwind"
120FILES:libunwind:runtime-llvm = "${libdir}/libunwind.so.*"
121# Package library module manifest path
122FILES:${PN}-dev += "${datadir}/libc++/v1/ ${libdir}/libc++.modules.json"
123
124BBCLASSEXTEND = "native nativesdk"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2025-07-05 01:05:22 +0000