summaryrefslogtreecommitdiffstats
path: root/meta/recipes-connectivity/ppp/ppp_2.4.6.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-connectivity/ppp/ppp_2.4.6.bb')
-rw-r--r--meta/recipes-connectivity/ppp/ppp_2.4.6.bb93
1 files changed, 93 insertions, 0 deletions
diff --git a/meta/recipes-connectivity/ppp/ppp_2.4.6.bb b/meta/recipes-connectivity/ppp/ppp_2.4.6.bb
new file mode 100644
index 0000000..b6b4048
--- /dev/null
+++ b/meta/recipes-connectivity/ppp/ppp_2.4.6.bb
@@ -0,0 +1,93 @@
1SUMMARY = "Point-to-Point Protocol (PPP) support"
2DESCRIPTION = "ppp (Paul's PPP Package) is an open source package which implements \
3the Point-to-Point Protocol (PPP) on Linux and Solaris systems."
4SECTION = "console/network"
5HOMEPAGE = "http://samba.org/ppp/"
6BUGTRACKER = "http://ppp.samba.org/cgi-bin/ppp-bugs"
7DEPENDS = "libpcap"
8LICENSE = "BSD & GPLv2+ & LGPLv2+ & PD"
9LIC_FILES_CHKSUM = "file://pppd/ccp.c;beginline=1;endline=29;md5=e2c43fe6e81ff77d87dc9c290a424dea \
10 file://pppd/plugins/passprompt.c;beginline=1;endline=10;md5=3bcbcdbf0e369c9a3e0b8c8275b065d8 \
11 file://pppd/tdb.c;beginline=1;endline=27;md5=4ca3a9991b011038d085d6675ae7c4e6 \
12 file://chat/chat.c;beginline=1;endline=15;md5=0d374b8545ee5c62d7aff1acbd38add2"
13
14SRC_URI = "http://ppp.samba.org/ftp/ppp/ppp-${PV}.tar.gz \
15 file://makefile.patch \
16 file://cifdefroute.patch \
17 file://pppd-resolv-varrun.patch \
18 file://makefile-remove-hard-usr-reference.patch \
19 file://pon \
20 file://poff \
21 file://init \
22 file://ip-up \
23 file://ip-down \
24 file://08setupdns \
25 file://92removedns \
26 file://copts.patch \
27 file://pap \
28 file://ppp_on_boot \
29 file://provider \
30 file://0001-ppp-Fix-compilation-errors-in-Makefile.patch \
31 file://ppp@.service \
32 file://fix-CVE-2015-3310.patch \
33"
34
35SRC_URI[md5sum] = "3434d2cc9327167a0723aaaa8670083b"
36SRC_URI[sha256sum] = "1b33181a03962c8a092c055fb9980e9722728a8d98a4bb7ec7acda17c1b1b49d"
37
38inherit autotools-brokensep systemd
39
40TARGET_CC_ARCH += " ${LDFLAGS}"
41EXTRA_OEMAKE = "STRIPPROG=${STRIP} MANDIR=${D}${datadir}/man/man8 INCDIR=${D}${includedir} LIBDIR=${D}${libdir}/pppd/${PV} BINDIR=${D}${sbindir}"
42EXTRA_OECONF = "--disable-strip"
43
44# Package Makefile computes CFLAGS, referencing COPTS.
45# Typically hard-coded to '-O2 -g' in the Makefile's.
46#
47EXTRA_OEMAKE += ' COPTS="${CFLAGS}"'
48
49do_install_append () {
50 make install-etcppp ETCDIR=${D}/${sysconfdir}/ppp
51 mkdir -p ${D}${bindir}/ ${D}${sysconfdir}/init.d
52 mkdir -p ${D}${sysconfdir}/ppp/ip-up.d/
53 mkdir -p ${D}${sysconfdir}/ppp/ip-down.d/
54 install -m 0755 ${WORKDIR}/pon ${D}${bindir}/pon
55 install -m 0755 ${WORKDIR}/poff ${D}${bindir}/poff
56 install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/ppp
57 install -m 0755 ${WORKDIR}/ip-up ${D}${sysconfdir}/ppp/
58 install -m 0755 ${WORKDIR}/ip-down ${D}${sysconfdir}/ppp/
59 install -m 0755 ${WORKDIR}/08setupdns ${D}${sysconfdir}/ppp/ip-up.d/
60 install -m 0755 ${WORKDIR}/92removedns ${D}${sysconfdir}/ppp/ip-down.d/
61 mkdir -p ${D}${sysconfdir}/chatscripts
62 mkdir -p ${D}${sysconfdir}/ppp/peers
63 install -m 0755 ${WORKDIR}/pap ${D}${sysconfdir}/chatscripts
64 install -m 0755 ${WORKDIR}/ppp_on_boot ${D}${sysconfdir}/ppp/ppp_on_boot
65 install -m 0755 ${WORKDIR}/provider ${D}${sysconfdir}/ppp/peers/provider
66 install -d ${D}${systemd_unitdir}/system
67 install -m 0644 ${WORKDIR}/ppp@.service ${D}${systemd_unitdir}/system
68 sed -i -e 's,@SBINDIR@,${sbindir},g' \
69 ${D}${systemd_unitdir}/system/ppp@.service
70 rm -rf ${D}/${mandir}/man8/man8
71 chmod u+s ${D}${sbindir}/pppd
72}
73
74CONFFILES_${PN} = "${sysconfdir}/ppp/pap-secrets ${sysconfdir}/ppp/chap-secrets ${sysconfdir}/ppp/options"
75PACKAGES =+ "${PN}-oa ${PN}-oe ${PN}-radius ${PN}-winbind ${PN}-minconn ${PN}-password ${PN}-l2tp ${PN}-tools"
76FILES_${PN} = "${sysconfdir} ${bindir} ${sbindir}/chat ${sbindir}/pppd ${systemd_unitdir}/system/ppp@.service"
77FILES_${PN}-dbg += "${libdir}/pppd/${PV}/.debug"
78FILES_${PN}-oa = "${libdir}/pppd/${PV}/pppoatm.so"
79FILES_${PN}-oe = "${sbindir}/pppoe-discovery ${libdir}/pppd/${PV}/rp-pppoe.so"
80FILES_${PN}-radius = "${libdir}/pppd/${PV}/radius.so ${libdir}/pppd/${PV}/radattr.so ${libdir}/pppd/${PV}/radrealms.so"
81FILES_${PN}-winbind = "${libdir}/pppd/${PV}/winbind.so"
82FILES_${PN}-minconn = "${libdir}/pppd/${PV}/minconn.so"
83FILES_${PN}-password = "${libdir}/pppd/${PV}/pass*.so"
84FILES_${PN}-l2tp = "${libdir}/pppd/${PV}/*l2tp.so"
85FILES_${PN}-tools = "${sbindir}/pppstats ${sbindir}/pppdump"
86SUMMARY_${PN}-oa = "Plugin for PPP for PPP-over-ATM support"
87SUMMARY_${PN}-oe = "Plugin for PPP for PPP-over-Ethernet support"
88SUMMARY_${PN}-radius = "Plugin for PPP for RADIUS support"
89SUMMARY_${PN}-winbind = "Plugin for PPP to authenticate against Samba or Windows"
90SUMMARY_${PN}-minconn = "Plugin for PPP to set a delay before the idle timeout applies"
91SUMMARY_${PN}-password = "Plugin for PPP to get passwords via a pipe"
92SUMMARY_${PN}-l2tp = "Plugin for PPP for l2tp support"
93SUMMARY_${PN}-tools = "Additional tools for the PPP package"