diff options
Diffstat (limited to 'meta/recipes-connectivity/nfs-utils/nfs-utils_2.4.2.bb')
-rw-r--r-- | meta/recipes-connectivity/nfs-utils/nfs-utils_2.4.2.bb | 149 |
1 files changed, 149 insertions, 0 deletions
diff --git a/meta/recipes-connectivity/nfs-utils/nfs-utils_2.4.2.bb b/meta/recipes-connectivity/nfs-utils/nfs-utils_2.4.2.bb new file mode 100644 index 0000000000..df3070bd8b --- /dev/null +++ b/meta/recipes-connectivity/nfs-utils/nfs-utils_2.4.2.bb | |||
@@ -0,0 +1,149 @@ | |||
1 | SUMMARY = "userspace utilities for kernel nfs" | ||
2 | DESCRIPTION = "The nfs-utils package provides a daemon for the kernel \ | ||
3 | NFS server and related tools." | ||
4 | HOMEPAGE = "http://nfs.sourceforge.net/" | ||
5 | SECTION = "console/network" | ||
6 | |||
7 | LICENSE = "MIT & GPLv2+ & BSD" | ||
8 | LIC_FILES_CHKSUM = "file://COPYING;md5=95f3a93a5c3c7888de623b46ea085a84" | ||
9 | |||
10 | # util-linux for libblkid | ||
11 | DEPENDS = "libcap libevent util-linux sqlite3 libtirpc" | ||
12 | RDEPENDS_${PN} = "${PN}-client" | ||
13 | RRECOMMENDS_${PN} = "kernel-module-nfsd" | ||
14 | |||
15 | inherit useradd | ||
16 | |||
17 | USERADD_PACKAGES = "${PN}-client" | ||
18 | USERADD_PARAM_${PN}-client = "--system --home-dir /var/lib/nfs \ | ||
19 | --shell /bin/false --user-group rpcuser" | ||
20 | |||
21 | SRC_URI = "${KERNELORG_MIRROR}/linux/utils/nfs-utils/${PV}/nfs-utils-${PV}.tar.xz \ | ||
22 | file://nfsserver \ | ||
23 | file://nfscommon \ | ||
24 | file://nfs-utils.conf \ | ||
25 | file://nfs-server.service \ | ||
26 | file://nfs-mountd.service \ | ||
27 | file://nfs-statd.service \ | ||
28 | file://proc-fs-nfsd.mount \ | ||
29 | file://nfs-utils-debianize-start-statd.patch \ | ||
30 | file://bugfix-adjust-statd-service-name.patch \ | ||
31 | file://0001-cacheio-use-intmax_t-for-formatted-IO.patch \ | ||
32 | file://0001-Makefile.am-fix-undefined-function-for-libnsm.a.patch \ | ||
33 | file://0001-Don-t-build-tools-with-CC_FOR_BUILD.patch \ | ||
34 | " | ||
35 | SRC_URI_append_libc-glibc = " file://0001-configure.ac-Do-not-fatalize-Wmissing-prototypes.patch" | ||
36 | |||
37 | SRC_URI[md5sum] = "d427c6b3014e9a04e8498f0598b1c1b9" | ||
38 | SRC_URI[sha256sum] = "4464737a03d5f73ded2ffefe19d5543ed7b1d6c541985d8acaafdc8025aa1038" | ||
39 | |||
40 | # Only kernel-module-nfsd is required here (but can be built-in) - the nfsd module will | ||
41 | # pull in the remainder of the dependencies. | ||
42 | |||
43 | INITSCRIPT_PACKAGES = "${PN} ${PN}-client" | ||
44 | INITSCRIPT_NAME = "nfsserver" | ||
45 | INITSCRIPT_PARAMS = "defaults" | ||
46 | INITSCRIPT_NAME_${PN}-client = "nfscommon" | ||
47 | INITSCRIPT_PARAMS_${PN}-client = "defaults 19 21" | ||
48 | |||
49 | inherit autotools-brokensep update-rc.d systemd pkgconfig | ||
50 | |||
51 | SYSTEMD_PACKAGES = "${PN} ${PN}-client" | ||
52 | SYSTEMD_SERVICE_${PN} = "nfs-server.service nfs-mountd.service" | ||
53 | SYSTEMD_SERVICE_${PN}-client = "nfs-statd.service" | ||
54 | |||
55 | # --enable-uuid is need for cross-compiling | ||
56 | EXTRA_OECONF = "--with-statduser=rpcuser \ | ||
57 | --enable-mountconfig \ | ||
58 | --enable-libmount-mount \ | ||
59 | --enable-uuid \ | ||
60 | --disable-gss \ | ||
61 | --disable-nfsdcltrack \ | ||
62 | --with-statdpath=/var/lib/nfs/statd \ | ||
63 | " | ||
64 | |||
65 | CFLAGS += "-Wno-error=format-overflow" | ||
66 | |||
67 | PACKAGECONFIG ??= "tcp-wrappers \ | ||
68 | ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} \ | ||
69 | " | ||
70 | PACKAGECONFIG_remove_libc-musl = "tcp-wrappers" | ||
71 | PACKAGECONFIG[tcp-wrappers] = "--with-tcp-wrappers,--without-tcp-wrappers,tcp-wrappers" | ||
72 | PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6," | ||
73 | # libdevmapper is available in meta-oe | ||
74 | PACKAGECONFIG[nfsv41] = "--enable-nfsv41,--disable-nfsv41,libdevmapper" | ||
75 | # keyutils is available in meta-security | ||
76 | PACKAGECONFIG[nfsv4] = "--enable-nfsv4,--disable-nfsv4,keyutils" | ||
77 | |||
78 | PACKAGES =+ "${PN}-client ${PN}-mount ${PN}-stats" | ||
79 | |||
80 | CONFFILES_${PN}-client += "${localstatedir}/lib/nfs/etab \ | ||
81 | ${localstatedir}/lib/nfs/rmtab \ | ||
82 | ${localstatedir}/lib/nfs/xtab \ | ||
83 | ${localstatedir}/lib/nfs/statd/state \ | ||
84 | ${sysconfdir}/nfsmount.conf" | ||
85 | |||
86 | FILES_${PN}-client = "${sbindir}/*statd \ | ||
87 | ${sbindir}/rpc.idmapd ${sbindir}/sm-notify \ | ||
88 | ${sbindir}/showmount ${sbindir}/nfsstat \ | ||
89 | ${localstatedir}/lib/nfs \ | ||
90 | ${sysconfdir}/nfs-utils.conf \ | ||
91 | ${sysconfdir}/nfsmount.conf \ | ||
92 | ${sysconfdir}/init.d/nfscommon \ | ||
93 | ${systemd_unitdir}/system/nfs-statd.service" | ||
94 | RDEPENDS_${PN}-client = "${PN}-mount rpcbind" | ||
95 | |||
96 | FILES_${PN}-mount = "${base_sbindir}/*mount.nfs*" | ||
97 | |||
98 | FILES_${PN}-stats = "${sbindir}/mountstats ${sbindir}/nfsiostat" | ||
99 | RDEPENDS_${PN}-stats = "python3-core" | ||
100 | |||
101 | FILES_${PN} += "${systemd_unitdir}" | ||
102 | |||
103 | do_configure_prepend() { | ||
104 | sed -i -e 's,sbindir = /sbin,sbindir = ${base_sbindir},g' \ | ||
105 | ${S}/utils/mount/Makefile.am | ||
106 | } | ||
107 | |||
108 | # Make clean needed because the package comes with | ||
109 | # precompiled 64-bit objects that break the build | ||
110 | do_compile_prepend() { | ||
111 | make clean | ||
112 | } | ||
113 | |||
114 | # Works on systemd only | ||
115 | HIGH_RLIMIT_NOFILE ??= "4096" | ||
116 | |||
117 | do_install_append () { | ||
118 | install -d ${D}${sysconfdir}/init.d | ||
119 | install -m 0755 ${WORKDIR}/nfsserver ${D}${sysconfdir}/init.d/nfsserver | ||
120 | install -m 0755 ${WORKDIR}/nfscommon ${D}${sysconfdir}/init.d/nfscommon | ||
121 | |||
122 | install -m 0755 ${WORKDIR}/nfs-utils.conf ${D}${sysconfdir} | ||
123 | install -m 0755 ${S}/utils/mount/nfsmount.conf ${D}${sysconfdir} | ||
124 | |||
125 | install -d ${D}${systemd_unitdir}/system | ||
126 | install -m 0644 ${WORKDIR}/nfs-server.service ${D}${systemd_unitdir}/system/ | ||
127 | install -m 0644 ${WORKDIR}/nfs-mountd.service ${D}${systemd_unitdir}/system/ | ||
128 | install -m 0644 ${WORKDIR}/nfs-statd.service ${D}${systemd_unitdir}/system/ | ||
129 | sed -i -e 's,@SBINDIR@,${sbindir},g' \ | ||
130 | -e 's,@SYSCONFDIR@,${sysconfdir},g' \ | ||
131 | -e 's,@HIGH_RLIMIT_NOFILE@,${HIGH_RLIMIT_NOFILE},g' \ | ||
132 | ${D}${systemd_unitdir}/system/*.service | ||
133 | if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then | ||
134 | install -m 0644 ${WORKDIR}/proc-fs-nfsd.mount ${D}${systemd_unitdir}/system/ | ||
135 | install -d ${D}${systemd_unitdir}/system/sysinit.target.wants/ | ||
136 | ln -sf ../proc-fs-nfsd.mount ${D}${systemd_unitdir}/system/sysinit.target.wants/proc-fs-nfsd.mount | ||
137 | fi | ||
138 | |||
139 | # kernel code as of 3.8 hard-codes this path as a default | ||
140 | install -d ${D}/var/lib/nfs/v4recovery | ||
141 | |||
142 | # chown the directories and files | ||
143 | chown -R rpcuser:rpcuser ${D}${localstatedir}/lib/nfs/statd | ||
144 | chmod 0644 ${D}${localstatedir}/lib/nfs/statd/state | ||
145 | |||
146 | # Make python tools use python 3 | ||
147 | sed -i -e '1s,#!.*python.*,#!${bindir}/python3,' ${D}${sbindir}/mountstats ${D}${sbindir}/nfsiostat | ||
148 | |||
149 | } | ||