summaryrefslogtreecommitdiffstats
path: root/meta/recipes-connectivity/nfs-utils/nfs-utils_1.2.9.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-connectivity/nfs-utils/nfs-utils_1.2.9.bb')
-rw-r--r--meta/recipes-connectivity/nfs-utils/nfs-utils_1.2.9.bb110
1 files changed, 110 insertions, 0 deletions
diff --git a/meta/recipes-connectivity/nfs-utils/nfs-utils_1.2.9.bb b/meta/recipes-connectivity/nfs-utils/nfs-utils_1.2.9.bb
new file mode 100644
index 0000000..da37160
--- /dev/null
+++ b/meta/recipes-connectivity/nfs-utils/nfs-utils_1.2.9.bb
@@ -0,0 +1,110 @@
1SUMMARY = "userspace utilities for kernel nfs"
2DESCRIPTION = "The nfs-utils package provides a daemon for the kernel \
3NFS server and related tools."
4HOMEPAGE = "http://nfs.sourceforge.net/"
5SECTION = "console/network"
6
7LICENSE = "MIT & GPLv2+ & BSD"
8LIC_FILES_CHKSUM = "file://COPYING;md5=95f3a93a5c3c7888de623b46ea085a84"
9
10# util-linux for libblkid
11DEPENDS = "libcap libnfsidmap libevent util-linux sqlite3"
12RDEPENDS_${PN}-client = "rpcbind bash"
13RDEPENDS_${PN} = "${PN}-client bash"
14RRECOMMENDS_${PN} = "kernel-module-nfsd"
15
16inherit useradd
17
18USERADD_PACKAGES = "${PN}-client"
19USERADD_PARAM_${PN}-client = "--system --home-dir /var/lib/nfs \
20 --shell /bin/false --user-group rpcuser"
21
22SRC_URI = "${KERNELORG_MIRROR}/linux/utils/nfs-utils/${PV}/nfs-utils-${PV}.tar.bz2 \
23 file://0001-configure-Allow-to-explicitly-disable-nfsidmap.patch \
24 file://nfs-utils-1.0.6-uclibc.patch \
25 file://nfs-utils-1.2.3-sm-notify-res_init.patch \
26 file://nfsserver \
27 file://nfscommon \
28 file://nfs-utils.conf \
29 file://nfs-server.service \
30 file://nfs-mountd.service \
31 file://nfs-statd.service "
32
33SRC_URI[md5sum] = "18869d16db3f49c053f8c68eba3fe2e0"
34SRC_URI[sha256sum] = "90b76d5692a520b74273e607a4fd69df4cc35f65e242e22e2bc61b58759722f3"
35
36PARALLEL_MAKE = ""
37
38# Only kernel-module-nfsd is required here (but can be built-in) - the nfsd module will
39# pull in the remainder of the dependencies.
40
41INITSCRIPT_PACKAGES = "${PN} ${PN}-client"
42INITSCRIPT_NAME = "nfsserver"
43INITSCRIPT_PARAMS = "defaults"
44INITSCRIPT_NAME_${PN}-client = "nfscommon"
45INITSCRIPT_PARAMS_${PN}-client = "defaults 19 21"
46
47inherit autotools-brokensep update-rc.d systemd
48
49SYSTEMD_SERVICE_${PN} = "nfs-server.service nfs-mountd.service"
50SYSTEMD_SERVICE_${PN}-client = "nfs-statd.service"
51SYSTEMD_AUTO_ENABLE = "disable"
52
53# --enable-uuid is need for cross-compiling
54EXTRA_OECONF = "--with-statduser=nobody \
55 --enable-mountconfig \
56 --enable-libmount-mount \
57 --disable-nfsv41 \
58 --enable-uuid \
59 --disable-gss \
60 --disable-tirpc \
61 --disable-nfsdcltrack \
62 --with-statdpath=/var/lib/nfs/statd \
63 "
64
65PACKAGECONFIG ??= "tcp-wrappers"
66PACKAGECONFIG[tcp-wrappers] = "--with-tcp-wrappers,--without-tcp-wrappers,tcp-wrappers"
67PACKAGECONFIG[nfsidmap] = "--enable-nfsidmap,--disable-nfsidmap,keyutils"
68
69INHIBIT_AUTO_STAGE = "1"
70
71PACKAGES =+ "${PN}-client ${PN}-stats"
72FILES_${PN}-client = "${base_sbindir}/*mount.nfs* ${sbindir}/*statd \
73 ${sbindir}/rpc.idmapd ${sbindir}/sm-notify \
74 ${sbindir}/showmount ${sbindir}/nfsstat \
75 ${localstatedir}/lib/nfs \
76 ${sysconfdir}/nfs-utils.conf \
77 ${sysconfdir}/init.d/nfscommon \
78 ${systemd_unitdir}/system/nfs-statd.service"
79FILES_${PN}-stats = "${sbindir}/mountstats ${sbindir}/nfsiostat"
80RDEPENDS_${PN}-stats = "python"
81
82# Make clean needed because the package comes with
83# precompiled 64-bit objects that break the build
84do_compile_prepend() {
85 make clean
86}
87
88do_install_append () {
89 install -d ${D}${sysconfdir}/init.d
90 install -d ${D}${localstatedir}/lib/nfs/statd
91 install -m 0755 ${WORKDIR}/nfsserver ${D}${sysconfdir}/init.d/nfsserver
92 install -m 0755 ${WORKDIR}/nfscommon ${D}${sysconfdir}/init.d/nfscommon
93
94 install -m 0755 ${WORKDIR}/nfs-utils.conf ${D}${sysconfdir}
95 install -d ${D}${systemd_unitdir}/system
96 install -m 0644 ${WORKDIR}/nfs-server.service ${D}${systemd_unitdir}/system/
97 install -m 0644 ${WORKDIR}/nfs-mountd.service ${D}${systemd_unitdir}/system/
98 install -m 0644 ${WORKDIR}/nfs-statd.service ${D}${systemd_unitdir}/system/
99 sed -i -e 's,@SBINDIR@,${sbindir},g' \
100 -e 's,@SYSCONFDIR@,${sysconfdir},g' \
101 ${D}${systemd_unitdir}/system/*.service
102
103 # kernel code as of 3.8 hard-codes this path as a default
104 install -d ${D}/var/lib/nfs/v4recovery
105
106 # the following are built by CC_FOR_BUILD
107 rm -f ${D}${sbindir}/rpcdebug
108 rm -f ${D}${sbindir}/rpcgen
109 rm -f ${D}${sbindir}/locktest
110}