summaryrefslogtreecommitdiffstats
path: root/meta/recipes-connectivity/bluez5/bluez5.inc
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-connectivity/bluez5/bluez5.inc')
-rw-r--r--meta/recipes-connectivity/bluez5/bluez5.inc79
1 files changed, 79 insertions, 0 deletions
diff --git a/meta/recipes-connectivity/bluez5/bluez5.inc b/meta/recipes-connectivity/bluez5/bluez5.inc
new file mode 100644
index 0000000..b385a91
--- /dev/null
+++ b/meta/recipes-connectivity/bluez5/bluez5.inc
@@ -0,0 +1,79 @@
1SUMMARY = "Linux Bluetooth Stack Userland V5"
2DESCRIPTION = "Linux Bluetooth stack V5 userland components. These include a system configurations, daemons, tools and system libraries."
3HOMEPAGE = "http://www.bluez.org"
4SECTION = "libs"
5LICENSE = "GPLv2+ & LGPLv2.1+"
6LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
7 file://COPYING.LIB;md5=fb504b67c50331fc78734fed90fb0e09 \
8 file://src/main.c;beginline=1;endline=24;md5=9bc54b93cd7e17bf03f52513f39f926e"
9DEPENDS = "udev libusb dbus-glib glib-2.0 libcheck readline"
10PROVIDES += "bluez-hcidump"
11RPROVIDES_${PN} += "bluez-hcidump"
12
13RCONFLICTS_${PN} = "bluez4"
14
15PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)} obex-profiles"
16PACKAGECONFIG[obex-profiles] = "--enable-obex,--disable-obex,libical"
17
18SRC_URI = "\
19 ${KERNELORG_MIRROR}/linux/bluetooth/bluez-${PV}.tar.xz \
20 file://bluetooth.conf \
21"
22S = "${WORKDIR}/bluez-${PV}"
23
24inherit autotools-brokensep pkgconfig systemd
25
26EXTRA_OECONF = "\
27 --enable-tools \
28 --disable-cups \
29 --enable-test \
30 --enable-datafiles \
31 ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--with-systemdunitdir=${systemd_unitdir}/system/', '--disable-systemd', d)} \
32 --enable-library \
33"
34
35do_install_append() {
36 install -d ${D}${sysconfdir}/bluetooth/
37 if [ -f ${S}/profiles/audio/audio.conf ]; then
38 install -m 0644 ${S}/profiles/audio/audio.conf ${D}/${sysconfdir}/bluetooth/
39 fi
40 if [ -f ${S}/profiles/network/network.conf ]; then
41 install -m 0644 ${S}/profiles/network/network.conf ${D}/${sysconfdir}/bluetooth/
42 fi
43 if [ -f ${S}/profiles/input/input.conf ]; then
44 install -m 0644 ${S}/profiles/input/input.conf ${D}/${sysconfdir}/bluetooth/
45 fi
46 # at_console doesn't really work with the current state of OE, so punch some more holes so people can actually use BT
47 install -m 0644 ${WORKDIR}/bluetooth.conf ${D}/${sysconfdir}/dbus-1/system.d/
48}
49
50ALLOW_EMPTY_libasound-module-bluez = "1"
51PACKAGES =+ "libasound-module-bluez ${PN}-testtools ${PN}-obex"
52
53FILES_libasound-module-bluez = "${libdir}/alsa-lib/lib*.so ${datadir}/alsa"
54FILES_${PN} += "${libdir}/bluetooth/plugins ${libdir}/bluetooth/plugins/*.so ${base_libdir}/udev/ ${nonarch_base_libdir}/udev/ ${systemd_unitdir}/ ${datadir}/dbus-1"
55FILES_${PN}-dev += "\
56 ${libdir}/bluetooth/plugins/*.la \
57 ${libdir}/alsa-lib/*.la \
58"
59
60FILES_${PN}-obex = "${libdir}/bluez5/bluetooth/obexd \
61 ${exec_prefix}/lib/systemd/user/obex.service \
62 ${datadir}/dbus-1/services/org.bluez.obex.service \
63 "
64SYSTEMD_SERVICE_${PN}-obex = "obex.service"
65
66FILES_${PN}-testtools = "${libdir}/bluez/test/*"
67
68FILES_${PN}-dbg += "\
69 ${libdir}/${BPN}/bluetooth/.debug \
70 ${libdir}/bluetooth/plugins/.debug \
71 ${libdir}/*/.debug \
72 */udev/.debug \
73 "
74
75RDEPENDS_${PN}-testtools += "python python-dbus python-pygobject"
76
77SYSTEMD_SERVICE_${PN} = "bluetooth.service"
78
79EXCLUDE_FROM_WORLD = "1"