summaryrefslogtreecommitdiffstats
path: root/meta/classes/qemuboot.bbclass
diff options
context:
space:
mode:
Diffstat (limited to 'meta/classes/qemuboot.bbclass')
-rw-r--r--meta/classes/qemuboot.bbclass148
1 files changed, 0 insertions, 148 deletions
diff --git a/meta/classes/qemuboot.bbclass b/meta/classes/qemuboot.bbclass
deleted file mode 100644
index 4b7532b304..0000000000
--- a/meta/classes/qemuboot.bbclass
+++ /dev/null
@@ -1,148 +0,0 @@
1# Help runqemu boot target board, "QB" means Qemu Boot, the following
2# vars can be set in conf files, such as <bsp.conf> to make it can be
3# boot by runqemu:
4#
5# QB_SYSTEM_NAME: qemu name, e.g., "qemu-system-i386"
6#
7# QB_OPT_APPEND: options to append to qemu, e.g., "-device usb-mouse"
8#
9# QB_DEFAULT_KERNEL: default kernel to boot, e.g., "bzImage"
10#
11# QB_DEFAULT_FSTYPE: default FSTYPE to boot, e.g., "ext4"
12#
13# QB_MEM: memory, e.g., "-m 512"
14#
15# QB_MACHINE: qemu machine, e.g., "-machine virt"
16#
17# QB_CPU: qemu cpu, e.g., "-cpu qemu32"
18#
19# QB_CPU_KVM: the similar to QB_CPU, but used when kvm, e.g., '-cpu kvm64',
20# set it when support kvm.
21#
22# QB_KERNEL_CMDLINE_APPEND: options to append to kernel's -append
23# option, e.g., "console=ttyS0 console=tty"
24#
25# QB_DTB: qemu dtb name
26#
27# QB_AUDIO_DRV: qemu audio driver, e.g., "alsa", set it when support audio
28#
29# QB_AUDIO_OPT: qemu audio option, e.g., "-soundhw ac97,es1370", used
30# when QB_AUDIO_DRV is set.
31#
32# QB_RNG: Pass-through for host random number generator, it can speedup boot
33# in system mode, where system is experiencing entropy starvation
34#
35# QB_KERNEL_ROOT: kernel's root, e.g., /dev/vda
36#
37# QB_NETWORK_DEVICE: network device, e.g., "-device virtio-net-pci,netdev=net0,mac=@MAC@",
38# it needs work with QB_TAP_OPT and QB_SLIRP_OPT.
39# Note, runqemu will replace @MAC@ with a predefined mac, you can set
40# a custom one, but that may cause conflicts when multiple qemus are
41# running on the same host.
42# Note: If more than one interface of type -device virtio-net-device gets added,
43# QB_NETWORK_DEVICE_prepend might be used, since Qemu enumerates the eth*
44# devices in reverse order to -device arguments.
45#
46# QB_TAP_OPT: network option for 'tap' mode, e.g.,
47# "-netdev tap,id=net0,ifname=@TAP@,script=no,downscript=no"
48# Note, runqemu will replace "@TAP@" with the one which is used, such as tap0, tap1 ...
49#
50# QB_SLIRP_OPT: network option for SLIRP mode, e.g., -netdev user,id=net0"
51#
52# QB_CMDLINE_IP_SLIRP: If QB_NETWORK_DEVICE adds more than one network interface to qemu, usually the
53# ip= kernel comand line argument needs to be changed accordingly. Details are documented
54# in the kernel docuemntation https://www.kernel.org/doc/Documentation/filesystems/nfs/nfsroot.txt
55# Example to configure only the first interface: "ip=eth0:dhcp"
56# QB_CMDLINE_IP_TAP: This parameter is similar to the QB_CMDLINE_IP_SLIRP parameter. Since the tap interface requires
57# static IP configuration @CLIENT@ and @GATEWAY@ place holders are replaced by the IP and the gateway
58# address of the qemu guest by runqemu.
59# Example: "ip=192.168.7.@CLIENT@::192.168.7.@GATEWAY@:255.255.255.0::eth0"
60#
61# QB_ROOTFS_OPT: used as rootfs, e.g.,
62# "-drive id=disk0,file=@ROOTFS@,if=none,format=raw -device virtio-blk-device,drive=disk0"
63# Note, runqemu will replace "@ROOTFS@" with the one which is used, such as core-image-minimal-qemuarm64.ext4.
64#
65# QB_SERIAL_OPT: serial port, e.g., "-serial mon:stdio"
66#
67# QB_TCPSERIAL_OPT: tcp serial port option, e.g.,
68# " -device virtio-serial-device -chardev socket,id=virtcon,port=@PORT@,host=127.0.0.1 -device virtconsole,chardev=virtcon"
69# Note, runqemu will replace "@PORT@" with the port number which is used.
70#
71# QB_ROOTFS_EXTRA_OPT: extra options to be appended to the rootfs device in case there is none specified by QB_ROOTFS_OPT.
72# Can be used to automatically determine the image from the other variables
73# but define things link 'bootindex' when booting from EFI or 'readonly' when using squashfs
74# without the need to specify a dedicated qemu configuration
75# Usage:
76# IMAGE_CLASSES += "qemuboot"
77# See "runqemu help" for more info
78
79QB_MEM ?= "-m 256"
80QB_SERIAL_OPT ?= "-serial mon:stdio -serial null"
81QB_DEFAULT_KERNEL ?= "${KERNEL_IMAGETYPE}"
82QB_DEFAULT_FSTYPE ?= "ext4"
83QB_RNG ?= "-object rng-random,filename=/dev/urandom,id=rng0 -device virtio-rng-pci,rng=rng0"
84QB_OPT_APPEND ?= ""
85QB_NETWORK_DEVICE ?= "-device virtio-net-pci,netdev=net0,mac=@MAC@"
86QB_CMDLINE_IP_SLIRP ?= "ip=dhcp"
87QB_CMDLINE_IP_TAP ?= "ip=192.168.7.@CLIENT@::192.168.7.@GATEWAY@:255.255.255.0"
88QB_ROOTFS_EXTRA_OPT ?= ""
89
90# This should be kept align with ROOT_VM
91QB_DRIVE_TYPE ?= "/dev/sd"
92
93inherit image-artifact-names
94
95# Create qemuboot.conf
96addtask do_write_qemuboot_conf after do_rootfs before do_image
97
98def qemuboot_vars(d):
99 build_vars = ['MACHINE', 'TUNE_ARCH', 'DEPLOY_DIR_IMAGE',
100 'KERNEL_IMAGETYPE', 'IMAGE_NAME', 'IMAGE_LINK_NAME',
101 'STAGING_DIR_NATIVE', 'STAGING_BINDIR_NATIVE',
102 'STAGING_DIR_HOST']
103 return build_vars + [k for k in d.keys() if k.startswith('QB_')]
104
105do_write_qemuboot_conf[vardeps] += "${@' '.join(qemuboot_vars(d))}"
106do_write_qemuboot_conf[vardepsexclude] += "TOPDIR"
107python do_write_qemuboot_conf() {
108 import configparser
109
110 qemuboot = "%s/%s.qemuboot.conf" % (d.getVar('IMGDEPLOYDIR'), d.getVar('IMAGE_NAME'))
111 qemuboot_link = "%s/%s.qemuboot.conf" % (d.getVar('IMGDEPLOYDIR'), d.getVar('IMAGE_LINK_NAME'))
112 finalpath = d.getVar("DEPLOY_DIR_IMAGE")
113 topdir = d.getVar('TOPDIR')
114 cf = configparser.ConfigParser()
115 cf.add_section('config_bsp')
116 for k in sorted(qemuboot_vars(d)):
117 # qemu-helper-native sysroot is not removed by rm_work and
118 # contains all tools required by runqemu
119 if k == 'STAGING_BINDIR_NATIVE':
120 val = os.path.join(d.getVar('BASE_WORKDIR'), d.getVar('BUILD_SYS'),
121 'qemu-helper-native/1.0-r1/recipe-sysroot-native/usr/bin/')
122 else:
123 val = d.getVar(k)
124 # we only want to write out relative paths so that we can relocate images
125 # and still run them
126 if val.startswith(topdir):
127 val = os.path.relpath(val, finalpath)
128 cf.set('config_bsp', k, '%s' % val)
129
130 # QB_DEFAULT_KERNEL's value of KERNEL_IMAGETYPE is the name of a symlink
131 # to the kernel file, which hinders relocatability of the qb conf.
132 # Read the link and replace it with the full filename of the target.
133 kernel_link = os.path.join(d.getVar('DEPLOY_DIR_IMAGE'), d.getVar('QB_DEFAULT_KERNEL'))
134 kernel = os.path.realpath(kernel_link)
135 # we only want to write out relative paths so that we can relocate images
136 # and still run them
137 kernel = os.path.relpath(kernel, finalpath)
138 cf.set('config_bsp', 'QB_DEFAULT_KERNEL', kernel)
139
140 bb.utils.mkdirhier(os.path.dirname(qemuboot))
141 with open(qemuboot, 'w') as f:
142 cf.write(f)
143
144 if qemuboot_link != qemuboot:
145 if os.path.lexists(qemuboot_link):
146 os.remove(qemuboot_link)
147 os.symlink(os.path.basename(qemuboot), qemuboot_link)
148}
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-04-25 01:59:08 +0000