summaryrefslogtreecommitdiffstats
path: root/meta/classes/gsettings.bbclass
diff options
context:
space:
mode:
Diffstat (limited to 'meta/classes/gsettings.bbclass')
-rw-r--r--meta/classes/gsettings.bbclass37
1 files changed, 37 insertions, 0 deletions
diff --git a/meta/classes/gsettings.bbclass b/meta/classes/gsettings.bbclass
new file mode 100644
index 0000000..dec5abc
--- /dev/null
+++ b/meta/classes/gsettings.bbclass
@@ -0,0 +1,37 @@
1# A bbclass to handle installed GSettings (glib) schemas, updated the compiled
2# form on package install and remove.
3#
4# The compiled schemas are platform-agnostic, so we can depend on
5# glib-2.0-native for the native tool and run the postinst script when the
6# rootfs builds to save a little time on first boot.
7
8# TODO use a trigger so that this runs once per package operation run
9
10DEPENDS += "glib-2.0-native"
11
12RDEPENDS_${PN} += "glib-2.0-utils"
13
14FILES_${PN} += "${datadir}/glib-2.0/schemas"
15
16gsettings_postinstrm () {
17 glib-compile-schemas $D${datadir}/glib-2.0/schemas
18}
19
20python populate_packages_append () {
21 pkg = d.getVar('PN', True)
22 bb.note("adding gsettings postinst scripts to %s" % pkg)
23
24 postinst = d.getVar('pkg_postinst_%s' % pkg, True) or d.getVar('pkg_postinst', True)
25 if not postinst:
26 postinst = '#!/bin/sh\n'
27 postinst += d.getVar('gsettings_postinstrm', True)
28 d.setVar('pkg_postinst_%s' % pkg, postinst)
29
30 bb.note("adding gsettings postrm scripts to %s" % pkg)
31
32 postrm = d.getVar('pkg_postrm_%s' % pkg, True) or d.getVar('pkg_postrm', True)
33 if not postrm:
34 postrm = '#!/bin/sh\n'
35 postrm += d.getVar('gsettings_postinstrm', True)
36 d.setVar('pkg_postrm_%s' % pkg, postrm)
37}