summaryrefslogtreecommitdiffstats
path: root/meta-skeleton/recipes-skeleton/useradd/useradd-example.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta-skeleton/recipes-skeleton/useradd/useradd-example.bb')
-rw-r--r--meta-skeleton/recipes-skeleton/useradd/useradd-example.bb76
1 files changed, 76 insertions, 0 deletions
diff --git a/meta-skeleton/recipes-skeleton/useradd/useradd-example.bb b/meta-skeleton/recipes-skeleton/useradd/useradd-example.bb
new file mode 100644
index 0000000..d3c02d5
--- /dev/null
+++ b/meta-skeleton/recipes-skeleton/useradd/useradd-example.bb
@@ -0,0 +1,76 @@
1SUMMARY = "Example recipe for using inherit useradd"
2DESCRIPTION = "This recipe serves as an example for using features from useradd.bbclass"
3SECTION = "examples"
4PR = "r1"
5LICENSE = "MIT"
6LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=4d92cd373abda3937c2bc47fbc49d690 \
7 file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
8
9SRC_URI = "file://file1 \
10 file://file2 \
11 file://file3 \
12 file://file4"
13
14S = "${WORKDIR}"
15
16PACKAGES =+ "${PN}-user3"
17
18inherit useradd
19
20# You must set USERADD_PACKAGES when you inherit useradd. This
21# lists which output packages will include the user/group
22# creation code.
23USERADD_PACKAGES = "${PN} ${PN}-user3"
24
25# You must also set USERADD_PARAM and/or GROUPADD_PARAM when
26# you inherit useradd.
27
28# USERADD_PARAM specifies command line options to pass to the
29# useradd command. Multiple users can be created by separating
30# the commands with a semicolon. Here we'll create two users,
31# user1 and user2:
32USERADD_PARAM_${PN} = "-u 1200 -d /home/user1 -r -s /bin/bash user1; -u 1201 -d /home/user2 -r -s /bin/bash user2"
33
34# user3 will be managed in the useradd-example-user3 pacakge:
35# As an example, we use the -P option to set clear text password for user3
36USERADD_PARAM_${PN}-user3 = "-u 1202 -d /home/user3 -r -s /bin/bash -P 'user3' user3"
37
38# GROUPADD_PARAM works the same way, which you set to the options
39# you'd normally pass to the groupadd command. This will create
40# groups group1 and group2:
41GROUPADD_PARAM_${PN} = "-g 880 group1; -g 890 group2"
42
43# Likewise, we'll manage group3 in the useradd-example-user3 package:
44GROUPADD_PARAM_${PN}-user3 = "-g 900 group3"
45
46do_install () {
47 install -d -m 755 ${D}${datadir}/user1
48 install -d -m 755 ${D}${datadir}/user2
49 install -d -m 755 ${D}${datadir}/user3
50
51 install -p -m 644 file1 ${D}${datadir}/user1/
52 install -p -m 644 file2 ${D}${datadir}/user1/
53
54 install -p -m 644 file2 ${D}${datadir}/user2/
55 install -p -m 644 file3 ${D}${datadir}/user2/
56
57 install -p -m 644 file3 ${D}${datadir}/user3/
58 install -p -m 644 file4 ${D}${datadir}/user3/
59
60 # The new users and groups are created before the do_install
61 # step, so you are now free to make use of them:
62 chown -R user1 ${D}${datadir}/user1
63 chown -R user2 ${D}${datadir}/user2
64 chown -R user3 ${D}${datadir}/user3
65
66 chgrp -R group1 ${D}${datadir}/user1
67 chgrp -R group2 ${D}${datadir}/user2
68 chgrp -R group3 ${D}${datadir}/user3
69}
70
71FILES_${PN} = "${datadir}/user1/* ${datadir}/user2/*"
72FILES_${PN}-user3 = "${datadir}/user3/*"
73
74# Prevents do_package failures with:
75# debugsources.list: No such file or directory:
76INHIBIT_PACKAGE_DEBUG_SPLIT = "1"