libgpg-error: Upgrade 1.18 -> 1.19

The patch pkgconfig.patch has not being integrated into upstream
repository, so rebasing it. Another change occurred inside the recipe,
the TUPLE's name changed for i586/i686 target architectures.

(From OE-Core rev: c263dc742c0c4729be51dad8eefc0b2699b071d9)

Signed-off-by: Leonardo Sandoval <leonardo.sandoval.gonzalez@linux.intel.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/meta/recipes-support/libgpg-error/libgpg-error_1.19.bb b/meta/recipes-support/libgpg-error/libgpg-error_1.19.bb
new file mode 100644
index 0000000000..39dbbcf337
--- /dev/null
+++ b/meta/recipes-support/libgpg-error/libgpg-error_1.19.bb
@@ -0,0 +1,51 @@
+SUMMARY = "Small library that defines common error values for all GnuPG components"
+HOMEPAGE = "http://www.gnupg.org/related_software/libgpg-error/"
+BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
+
+LICENSE = "GPLv2+ & LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
+                    file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1 \
+                    file://src/gpg-error.h.in;endline=23;md5=8b204918f0ca707136394d8bb20c7ebc \
+                    file://src/init.c;endline=20;md5=8f5a9b59634f4aebcd0ec9d3ebd53bfe"
+
+
+SECTION = "libs"
+
+SRC_URI = "ftp://ftp.gnupg.org/gcrypt/libgpg-error/libgpg-error-${PV}.tar.bz2 \
+           file://pkgconfig.patch"
+SRC_URI[md5sum] = "c04c16245b92829281f43b5bef7d16da"
+SRC_URI[sha256sum] = "53120e1333d5c5d28d87ff2854e9e98719c8e214152f17ad5291704d25c4978b"
+
+BINCONFIG = "${bindir}/gpg-error-config"
+
+inherit autotools binconfig-disabled pkgconfig gettext
+CPPFLAGS += "-P"
+do_compile_prepend() {
+        TARGET_FILE=linux-gnu
+        if [ ${TARGET_OS} != "linux" ]; then
+                TARGET_FILE=${TARGET_OS}
+        fi
+
+        case ${TARGET_ARCH} in
+          aarch64_be) TUPLE=aarch64-unknown-linux-gnu ;;
+          arm)        TUPLE=arm-unknown-linux-gnueabi ;;
+          armeb)      TUPLE=arm-unknown-linux-gnueabi ;;
+          i586|i686)  TUPLE=i686-pc-linux-gnu ;;
+          mips64el)   TUPLE=mipsel-unknown-linux-gnu ;;
+          mips64)     TUPLE=mips-unknown-linux-gnu ;;
+          x86_64)     TUPLE=x86_64-pc-linux-gnu ;;
+          *)          TUPLE=${TARGET_ARCH}-unknown-linux-gnu ;; 
+        esac
+
+        cp ${S}/src/syscfg/lock-obj-pub.$TUPLE.h \
+          ${S}/src/syscfg/lock-obj-pub.$TARGET_FILE.h
+}
+
+do_install_append() {
+        # we don't have common lisp in OE
+        rm -rf "${D}${datadir}/common-lisp/"
+}
+
+FILES_${PN}-dev += "${bindir}/gpg-error"
+
+BBCLASSEXTEND = "native"