diff options
author | Alexander Kanavin <alex.kanavin@gmail.com> | 2022-08-19 09:27:02 +0200 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2022-08-21 22:51:42 +0100 |
commit | fdf3e306635d785342aa50bb19d20c52576620c6 (patch) | |
tree | 387c928726f5a968cbc7d78adf94601670990eb6 /meta/recipes-support/gpgme/gpgme_1.18.0.bb | |
parent | a2ac81ebf13f5122dfa1aec16c05fb5069fed015 (diff) | |
download | poky-fdf3e306635d785342aa50bb19d20c52576620c6.tar.gz |
gpgme: upgrade 1.17.1 -> 1.18.0
(From OE-Core rev: b82b51a10e7348ea77999219a13b29cacd50b4f2)
Signed-off-by: Alexander Kanavin <alex@linutronix.de>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-support/gpgme/gpgme_1.18.0.bb')
-rw-r--r-- | meta/recipes-support/gpgme/gpgme_1.18.0.bb | 87 |
1 files changed, 87 insertions, 0 deletions
diff --git a/meta/recipes-support/gpgme/gpgme_1.18.0.bb b/meta/recipes-support/gpgme/gpgme_1.18.0.bb new file mode 100644 index 0000000000..ca9c6cab14 --- /dev/null +++ b/meta/recipes-support/gpgme/gpgme_1.18.0.bb | |||
@@ -0,0 +1,87 @@ | |||
1 | SUMMARY = "High-level GnuPG encryption/signing API" | ||
2 | DESCRIPTION = "GnuPG Made Easy (GPGME) is a library designed to make access to GnuPG easier for applications. It provides a High-Level Crypto API for encryption, decryption, signing, signature verification and key management" | ||
3 | HOMEPAGE = "http://www.gnupg.org/gpgme.html" | ||
4 | BUGTRACKER = "https://bugs.g10code.com/gnupg/index" | ||
5 | |||
6 | LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later" | ||
7 | LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \ | ||
8 | file://COPYING.LESSER;md5=bbb461211a33b134d42ed5ee802b37ff \ | ||
9 | file://src/gpgme.h.in;endline=23;md5=2f0bf06d1c7dcb28532a9d0f94a7ca1d \ | ||
10 | file://src/engine.h;endline=22;md5=4b6d8ba313d9b564cc4d4cfb1640af9d" | ||
11 | |||
12 | UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html" | ||
13 | SRC_URI = "${GNUPG_MIRROR}/gpgme/${BP}.tar.bz2 \ | ||
14 | file://0001-Revert-build-Make-gpgme.m4-use-gpgrt-config-with-.pc.patch \ | ||
15 | file://0001-pkgconfig.patch \ | ||
16 | file://0002-gpgme-lang-python-gpg-error-config-should-not-be-use.patch \ | ||
17 | file://0003-Correctly-install-python-modules.patch \ | ||
18 | file://0004-python-import.patch \ | ||
19 | file://0005-gpgme-config-skip-all-lib-or-usr-lib-directories-in-.patch \ | ||
20 | file://0006-fix-build-path-issue.patch \ | ||
21 | file://0007-python-Add-variables-to-tests.patch \ | ||
22 | file://0008-do-not-auto-check-var-PYTHON.patch \ | ||
23 | file://0001-use-closefrom-on-linux-and-glibc-2.34.patch \ | ||
24 | " | ||
25 | |||
26 | SRC_URI[sha256sum] = "361d4eae47ce925dba0ea569af40e7b52c645c4ae2e65e5621bf1b6cdd8b0e9e" | ||
27 | |||
28 | DEPENDS = "libgpg-error libassuan" | ||
29 | RDEPENDS:${PN}-cpp += "libstdc++" | ||
30 | |||
31 | RDEPENDS:python2-gpg += "python-unixadmin" | ||
32 | RDEPENDS:python3-gpg += "python3-unixadmin" | ||
33 | |||
34 | BINCONFIG = "${bindir}/gpgme-config" | ||
35 | |||
36 | # Note select python2 or python3, but you can't select both at the same time | ||
37 | PACKAGECONFIG ??= "python3" | ||
38 | PACKAGECONFIG[python2] = ",,python swig-native," | ||
39 | PACKAGECONFIG[python3] = ",,python3 swig-native," | ||
40 | |||
41 | # Default in configure.ac: "cl cpp python qt" | ||
42 | # Supported: "cl cpp python python2 python3 qt" | ||
43 | # python says 'search and find python2 or python3' | ||
44 | |||
45 | # Building the C++ bindings for native requires a C++ compiler with C++11 | ||
46 | # support. Since these bindings are currently not needed, we can disable them. | ||
47 | DEFAULT_LANGUAGES = "" | ||
48 | DEFAULT_LANGUAGES:class-target = "cpp" | ||
49 | LANGUAGES ?= "${DEFAULT_LANGUAGES} python" | ||
50 | |||
51 | PYTHON_INHERIT = "${@bb.utils.contains('PACKAGECONFIG', 'python2', 'pythonnative', '', d)}" | ||
52 | PYTHON_INHERIT .= "${@bb.utils.contains('PACKAGECONFIG', 'python3', 'python3native python3targetconfig', '', d)}" | ||
53 | |||
54 | EXTRA_OECONF += '--enable-languages="${LANGUAGES}" \ | ||
55 | --disable-gpgconf-test \ | ||
56 | --disable-gpg-test \ | ||
57 | --disable-gpgsm-test \ | ||
58 | --disable-g13-test \ | ||
59 | --disable-lang-python-test \ | ||
60 | ' | ||
61 | |||
62 | inherit autotools texinfo binconfig-disabled pkgconfig setuptools3-base ${PYTHON_INHERIT} multilib_header | ||
63 | |||
64 | export PKG_CONFIG='pkg-config' | ||
65 | |||
66 | BBCLASSEXTEND = "native nativesdk" | ||
67 | |||
68 | PACKAGES =+ "${PN}-cpp" | ||
69 | PACKAGES =. "${@bb.utils.contains('PACKAGECONFIG', 'python2', 'python2-gpg ', '', d)}" | ||
70 | PACKAGES =. "${@bb.utils.contains('PACKAGECONFIG', 'python3', 'python3-gpg ', '', d)}" | ||
71 | |||
72 | FILES:${PN}-cpp = "${libdir}/libgpgmepp.so.*" | ||
73 | FILES:python2-gpg = "${PYTHON_SITEPACKAGES_DIR}/*" | ||
74 | FILES:python3-gpg = "${PYTHON_SITEPACKAGES_DIR}/*" | ||
75 | FILES:${PN}-dev += "${datadir}/common-lisp/source/gpgme/*" | ||
76 | |||
77 | CFLAGS:append:libc-musl = " -D__error_t_defined " | ||
78 | do_configure:prepend () { | ||
79 | # Else these could be used in preference to those in aclocal-copy | ||
80 | rm -f ${S}/m4/gpg-error.m4 | ||
81 | rm -f ${S}/m4/libassuan.m4 | ||
82 | rm -f ${S}/m4/python.m4 | ||
83 | } | ||
84 | |||
85 | do_install:append() { | ||
86 | oe_multilib_header gpgme.h | ||
87 | } | ||