initial commit for Enea Linux 4.0

Migrated from the internal git server on the daisy-enea branch

Signed-off-by: Adrian Dudau <adrian.dudau@enea.com>

3 files changed, 172 insertions, 0 deletions

diff --git a/meta/recipes-support/db/db/arm-thumb-mutex_db5.patch b/meta/recipes-support/db/db/arm-thumb-mutex_db5.patch
new file mode 100644
index 0000000000..40b13dee79
--- /dev/null
+++ b/meta/recipes-support/db/db/arm-thumb-mutex_db5.patch
@@ -0,0 +1,38 @@
+Upstream-Status: Inappropriate [embedded specific]
+
+--- db-5.1.19/src/dbinc/mutex_int.h.orig        2011-01-05 19:21:42.181805366 -0600
++++ db-5.1.19/src/dbinc/mutex_int.h     2011-01-05 19:24:53.141853117 -0600
+@@ -474,6 +474,25 @@
+ 
+ #ifdef LOAD_ACTUAL_MUTEX_CODE
+ /* gcc/arm: 0 is clear, 1 is set. */
++#if defined __thumb__
++#define        MUTEX_SET(tsl) ({                                               \
++       int __r, __p;                                                   \
++       __asm__ volatile(                                               \
++               ".align 2\n\t"                                          \
++               "bx     pc\n\t"                                         \
++               "nop\n\t"                                               \
++               ".arm\n\t"                                              \
++               "swpb   %0, %2, [%3]\n\t"                               \
++               "eor    %0, %0, #1\n\t"                                 \
++               "orr    %1, pc, #1\n\t"                                 \
++               "bx     %1\n\t"                                         \
++               ".force_thumb"                                          \
++           : "=&r" (__r), "=r" (__p)                                   \
++           : "r" (1), "r" (tsl)                                        \
++           );                                                          \
++       __r & 1;                                                        \
++})
++#else
+ #define        MUTEX_SET(tsl) ({                                               \
+        int __r;                                                        \
+        __asm__ volatile(                                               \
+@@ -484,6 +503,7 @@
+            );                                                          \
+        __r & 1;                                                        \
+ })
++#endif
+ 
+ #define        MUTEX_UNSET(tsl)        (*(volatile tsl_t *)(tsl) = 0)
+ #define        MUTEX_INIT(tsl)         (MUTEX_UNSET(tsl), 0)
diff --git a/meta/recipes-support/db/db/fix-parallel-build.patch b/meta/recipes-support/db/db/fix-parallel-build.patch
new file mode 100644
index 0000000000..2c7f1e186b
--- /dev/null
+++ b/meta/recipes-support/db/db/fix-parallel-build.patch
@@ -0,0 +1,19 @@
+With higher paralelism it sometimes fails with:
+libtool: link: `util_log.lo' is not a valid libtool object
+make: *** [db_replicate] Error 1
+
+Upstream-Status: Pending
+
+Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
+
+--- dist.orig/Makefile.in       2012-05-11 19:57:48.000000000 +0200
++++ dist/Makefile.in    2013-10-31 18:17:11.875532522 +0100
+@@ -1034,7 +1034,7 @@
+            db_recover@o@ util_sig@o@ $(DEF_LIB) $(LIBS)
+        $(POSTLINK) $@
+ 
+-db_replicate: db_replicate@o@ util_sig@o@ $(DEF_LIB)
++db_replicate: db_replicate@o@ util_log@o@ util_sig@o@ $(DEF_LIB)
+        $(CCLINK) -o $@ $(LDFLAGS) \
+            db_replicate@o@ util_log@o@ util_sig@o@ $(DEF_LIB) $(LIBS)
+        $(POSTLINK) $@
diff --git a/meta/recipes-support/db/db_5.3.21.bb b/meta/recipes-support/db/db_5.3.21.bb
new file mode 100644
index 0000000000..caf6890261
--- /dev/null
+++ b/meta/recipes-support/db/db_5.3.21.bb
@@ -0,0 +1,115 @@
+# Version 5 of the Berkeley DB from Sleepycat
+#
+# At present this package only installs the DB code
+# itself (shared libraries, .a in the dev package),
+# documentation and headers.
+#
+# The headers have the same names as those as v3
+# of the DB, only one version can be used *for dev*
+# at once - DB3 and DB5 can both be installed on the
+# same system at the same time if really necessary.
+SECTION = "libs"
+SUMMARY = "Berkeley Database v5"
+HOMEPAGE = "http://www.oracle.com/technology/products/berkeley-db/db/index.html"
+LICENSE = "Sleepycat"
+VIRTUAL_NAME ?= "virtual/db"
+RCONFLICTS_${PN} = "db3"
+
+SRC_URI = "http://download.oracle.com/berkeley-db/db-${PV}.tar.gz"
+SRC_URI += "file://arm-thumb-mutex_db5.patch;patchdir=.. \
+            file://fix-parallel-build.patch \
+           "
+
+SRC_URI[md5sum] = "3fda0b004acdaa6fa350bfc41a3b95ca"
+SRC_URI[sha256sum] = "ddd92a930317df92021054c03992392db9ea5cddba43bef8920d392a82114fb8"
+
+LIC_FILES_CHKSUM = "file://../LICENSE;md5=32aefa5a8e7318be1f657432cbe2e768"
+
+inherit autotools
+
+# Put virtual/db in any appropriate provider of a
+# relational database, use it as a dependency in
+# place of a specific db and use:
+#
+# PREFERRED_PROVIDER_virtual/db
+#
+# to select the correct db in the build (distro) .conf
+PROVIDES += "${VIRTUAL_NAME}"
+
+# bitbake isn't quite clever enough to deal with sleepycat,
+# the distribution sits in the expected directory, but all
+# the builds must occur from a sub-directory.  The following
+# persuades bitbake to go to the right place
+S = "${WORKDIR}/db-${PV}/dist"
+B = "${WORKDIR}/db-${PV}/build_unix"
+
+# The executables go in a separate package - typically there
+# is no need to install these unless doing real database
+# management on the system.
+inherit lib_package
+
+PACKAGES =+ "${PN}-cxx"
+FILES_${PN}-cxx = "${libdir}/*cxx*so"
+
+
+# The dev package has the .so link (as in db3) and the .a's -
+# it is therefore incompatible (cannot be installed at the
+# same time) as the db3 package
+# sort out the .so since they do version prior to the .so
+SOLIBS = "-5*.so"
+FILES_SOLIBSDEV = "${libdir}/libdb.so ${libdir}/libdb_cxx.so"
+
+#configuration - set in local.conf to override
+# All the --disable-* options replace --enable-smallbuild, which breaks a bunch of stuff (eg. postfix)
+DB5_CONFIG ?= "--enable-o_direct --disable-cryptography --disable-queue --disable-replication --disable-verify --disable-compat185 --disable-sql"
+
+EXTRA_OECONF = "${DB5_CONFIG} --enable-shared --enable-cxx --with-sysroot"
+
+# Override the MUTEX setting here, the POSIX library is
+# the default - "POSIX/pthreads/library".
+# Don't ignore the nice SWP instruction on the ARM:
+# These enable the ARM assembler mutex code, this won't
+# work with thumb compilation...
+ARM_MUTEX = "--with-mutex=ARM/gcc-assembly"
+MUTEX = ""
+MUTEX_arm = "${ARM_MUTEX}"
+MUTEX_armeb = "${ARM_MUTEX}"
+EXTRA_OECONF += "${MUTEX}"
+
+# Cancel the site stuff - it's set for db3 and destroys the
+# configure.
+CONFIG_SITE = ""
+do_configure() {
+        gnu-configize --force ${S}
+        export STRIP="true"
+        oe_runconf
+}
+
+do_compile_prepend() {
+        sed -i -e 's|hardcode_into_libs=yes|hardcode_into_libs=no|' \
+                ${B}/libtool
+}
+
+do_install_append() {
+        mkdir -p ${D}/${includedir}/db51
+        mv ${D}/${includedir}/db.h ${D}/${includedir}/db51/.
+        mv ${D}/${includedir}/db_cxx.h ${D}/${includedir}/db51/.
+        ln -s db51/db.h ${D}/${includedir}/db.h
+        ln -s db51/db_cxx.h ${D}/${includedir}/db_cxx.h
+
+        # The docs end up in /usr/docs - not right.
+        if test -d "${D}/${prefix}/docs"
+        then
+                mkdir -p "${D}/${datadir}"
+                test ! -d "${D}/${docdir}" || rm -rf "${D}/${docdir}"
+                mv "${D}/${prefix}/docs" "${D}/${docdir}"
+        fi
+
+        chown -R root:root ${D}
+}
+
+INSANE_SKIP_${PN} = "dev-so"
+INSANE_SKIP_${PN}-cxx = "dev-so"
+
+BBCLASSEXTEND = "native nativesdk"
+