diff options
author | Saul Wold <sgw@linux.intel.com> | 2015-02-02 10:09:40 -0800 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2015-02-08 08:00:25 +0000 |
commit | 5a4e20a73f1aac2d94900ab84e9a33b93ead904c (patch) | |
tree | fefdc7ae708ea0f8fbaa9d5b66e52779da6e1d0a /meta/recipes-support/ca-certificates/ca-certificates_20141019.bb | |
parent | 308a7ea7802bdc5946270a6f1c8f8ec0c78b1ac9 (diff) | |
download | poky-5a4e20a73f1aac2d94900ab84e9a33b93ead904c.tar.gz |
ca-certificates: Upgrade to 20141019 (git based)
Rebase default-sysroot patch
Remove backported Mozilla certdata patch
License has not changed, just wording.
(From OE-Core rev: 33222af134c465791ed84eccd61bbc2b69ad81f1)
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-support/ca-certificates/ca-certificates_20141019.bb')
-rw-r--r-- | meta/recipes-support/ca-certificates/ca-certificates_20141019.bb | 75 |
1 files changed, 75 insertions, 0 deletions
diff --git a/meta/recipes-support/ca-certificates/ca-certificates_20141019.bb b/meta/recipes-support/ca-certificates/ca-certificates_20141019.bb new file mode 100644 index 0000000000..e5a482138f --- /dev/null +++ b/meta/recipes-support/ca-certificates/ca-certificates_20141019.bb | |||
@@ -0,0 +1,75 @@ | |||
1 | SUMMARY = "Common CA certificates" | ||
2 | DESCRIPTION = "This package includes PEM files of CA certificates to allow \ | ||
3 | SSL-based applications to check for the authenticity of SSL connections. \ | ||
4 | This derived from Debian's CA Certificates." | ||
5 | HOMEPAGE = "http://packages.debian.org/sid/ca-certificates" | ||
6 | SECTION = "misc" | ||
7 | LICENSE = "GPL-2.0+ & MPL-2.0" | ||
8 | LIC_FILES_CHKSUM = "file://debian/copyright;md5=48d2baf97986999e776b43c8dd9e0c5a" | ||
9 | |||
10 | # This is needed to ensure we can run the postinst at image creation time | ||
11 | DEPENDS = "ca-certificates-native" | ||
12 | DEPENDS_class-native = "" | ||
13 | |||
14 | # tag: debian/20140325 + 2 | ||
15 | SRCREV = "2b8a047c78aadbecd90bf8e49ccf68898a211610" | ||
16 | |||
17 | SRC_URI = "git://anonscm.debian.org/collab-maint/ca-certificates.git \ | ||
18 | file://0001-update-ca-certificates-remove-c-rehash.patch \ | ||
19 | file://0002-update-ca-certificates-use-SYSROOT.patch \ | ||
20 | file://default-sysroot.patch \ | ||
21 | file://sbindir.patch" | ||
22 | |||
23 | S = "${WORKDIR}/git" | ||
24 | |||
25 | inherit allarch | ||
26 | |||
27 | EXTRA_OEMAKE = "\ | ||
28 | 'CERTSDIR=${datadir}/ca-certificates' \ | ||
29 | 'SBINDIR=${sbindir}' \ | ||
30 | " | ||
31 | |||
32 | do_install () { | ||
33 | install -d ${D}${datadir}/ca-certificates \ | ||
34 | ${D}${sysconfdir}/ssl/certs \ | ||
35 | ${D}${sysconfdir}/ca-certificates/update.d | ||
36 | oe_runmake 'DESTDIR=${D}' install | ||
37 | |||
38 | install -d ${D}${mandir}/man8 | ||
39 | install -m 0644 sbin/update-ca-certificates.8 ${D}${mandir}/man8/ | ||
40 | |||
41 | install -d ${D}${sysconfdir} | ||
42 | { | ||
43 | echo "# Lines starting with # will be ignored" | ||
44 | echo "# Lines starting with ! will remove certificate on next update" | ||
45 | echo "#" | ||
46 | find ${D}${datadir}/ca-certificates -type f -name '*.crt' | \ | ||
47 | sed 's,^${D}${datadir}/ca-certificates/,,' | ||
48 | } >${D}${sysconfdir}/ca-certificates.conf | ||
49 | } | ||
50 | |||
51 | do_install_append_class-target () { | ||
52 | sed -i -e 's,/etc/,${sysconfdir}/,' \ | ||
53 | -e 's,/usr/share/,${datadir}/,' \ | ||
54 | -e 's,/usr/local,${prefix}/local,' \ | ||
55 | ${D}${sbindir}/update-ca-certificates \ | ||
56 | ${D}${mandir}/man8/update-ca-certificates.8 | ||
57 | } | ||
58 | |||
59 | pkg_postinst_${PN} () { | ||
60 | SYSROOT="$D" update-ca-certificates | ||
61 | } | ||
62 | |||
63 | CONFFILES_${PN} += "${sysconfdir}/ca-certificates.conf" | ||
64 | |||
65 | # Postinsts don't seem to be run for nativesdk packages when populating SDKs. | ||
66 | CONFFILES_${PN}_append_class-nativesdk = " ${sysconfdir}/ssl/certs/ca-certificates.crt" | ||
67 | do_install_append_class-nativesdk () { | ||
68 | SYSROOT="${D}${SDKPATHNATIVE}" update-ca-certificates | ||
69 | } | ||
70 | |||
71 | do_install_append_class-native () { | ||
72 | SYSROOT="${D}${base_prefix}" ${D}${sbindir}/update-ca-certificates | ||
73 | } | ||
74 | |||
75 | BBCLASSEXTEND += "native nativesdk" | ||