diff options
author | Alexander Kanavin <alex.kanavin@gmail.com> | 2019-10-11 13:47:44 +0200 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2019-10-15 14:16:10 +0100 |
commit | f2629e86566c69850dad1e8633019e42045c34bf (patch) | |
tree | 8512d7177985784789e2454da84ab8e0bbc30246 /meta/recipes-sato/webkit/webkitgtk_2.26.1.bb | |
parent | 9c9e65740304d4b1d1d73a11ef276f4c2efae7ee (diff) | |
download | poky-f2629e86566c69850dad1e8633019e42045c34bf.tar.gz |
webkitgtk: update 2.24.4 -> 2.26.1
Drop patches:
- 0001-WebKitMacros-Append-to-I-and-not-to-isystem.patch - this
has been a pain to rebase for a while as upstream keeps shifting and
changing the code that needs to be modified. If the issue the patch
is addressing is still relevant, please work with upstream to fix it
at the source
- 0001-gstreamer-add-a-missing-format-string.patch, narrowing.patch
are integrated upstream
- detect-gstreamer-gl.patch is adjusting something that is better done
from the yocto package configuration
Add an option to disable an enabled-by-default sandbox that requires
a component that oe-core does not have.
(From OE-Core rev: d9e3ff36af9e06c1bc94c7a4c37ae87afceea5ca)
Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-sato/webkit/webkitgtk_2.26.1.bb')
-rw-r--r-- | meta/recipes-sato/webkit/webkitgtk_2.26.1.bb | 127 |
1 files changed, 127 insertions, 0 deletions
diff --git a/meta/recipes-sato/webkit/webkitgtk_2.26.1.bb b/meta/recipes-sato/webkit/webkitgtk_2.26.1.bb new file mode 100644 index 0000000000..77e51e7d29 --- /dev/null +++ b/meta/recipes-sato/webkit/webkitgtk_2.26.1.bb | |||
@@ -0,0 +1,127 @@ | |||
1 | SUMMARY = "WebKit web rendering engine for the GTK+ platform" | ||
2 | HOMEPAGE = "http://www.webkitgtk.org/" | ||
3 | BUGTRACKER = "http://bugs.webkit.org/" | ||
4 | |||
5 | LICENSE = "BSD & LGPLv2+" | ||
6 | LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \ | ||
7 | file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \ | ||
8 | file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \ | ||
9 | file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \ | ||
10 | " | ||
11 | |||
12 | SRC_URI = "http://www.webkitgtk.org/releases/${BPN}-${PV}.tar.xz \ | ||
13 | file://0001-FindGObjectIntrospection.cmake-prefix-variables-obta.patch \ | ||
14 | file://0001-When-building-introspection-files-add-CMAKE_C_FLAGS-.patch \ | ||
15 | file://0001-OptionsGTK.cmake-drop-the-hardcoded-introspection-gt.patch \ | ||
16 | file://0001-Fix-racy-parallel-build-of-WebKit2-4.0.gir.patch \ | ||
17 | file://0001-Tweak-gtkdoc-settings-so-that-gtkdoc-generation-work.patch \ | ||
18 | file://x32_support.patch \ | ||
19 | file://cross-compile.patch \ | ||
20 | file://0001-Fix-build-with-musl.patch \ | ||
21 | file://include_array.patch \ | ||
22 | " | ||
23 | |||
24 | SRC_URI[md5sum] = "08145bd6c1587230f135921c142bc150" | ||
25 | SRC_URI[sha256sum] = "6b4b21801d2b1008422a1075dbd6fb4ae8b5127503faf657cf9671289d9cd155" | ||
26 | |||
27 | inherit cmake pkgconfig gobject-introspection perlnative distro_features_check upstream-version-is-even gtk-doc | ||
28 | |||
29 | REQUIRED_DISTRO_FEATURES = "x11 opengl" | ||
30 | |||
31 | CVE_PRODUCT = "webkitgtk webkitgtk\+" | ||
32 | |||
33 | DEPENDS = "zlib libsoup-2.4 curl libxml2 cairo libxslt libxt libidn libgcrypt \ | ||
34 | gtk+3 gstreamer1.0 gstreamer1.0-plugins-base flex-native gperf-native sqlite3 \ | ||
35 | pango icu bison-native gawk intltool-native libwebp \ | ||
36 | atk udev harfbuzz jpeg libpng pulseaudio librsvg libtheora libvorbis libxcomposite libxtst \ | ||
37 | ruby-native libnotify gstreamer1.0-plugins-bad \ | ||
38 | gettext-native glib-2.0 glib-2.0-native libtasn1 \ | ||
39 | " | ||
40 | |||
41 | PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', 'wayland' ,d)} \ | ||
42 | ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'webgl opengl', '' ,d)} \ | ||
43 | enchant \ | ||
44 | libsecret \ | ||
45 | " | ||
46 | |||
47 | PACKAGECONFIG[wayland] = "-DENABLE_WAYLAND_TARGET=ON,-DENABLE_WAYLAND_TARGET=OFF,wayland" | ||
48 | PACKAGECONFIG[x11] = "-DENABLE_X11_TARGET=ON,-DENABLE_X11_TARGET=OFF,virtual/libx11" | ||
49 | PACKAGECONFIG[geoclue] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue" | ||
50 | PACKAGECONFIG[enchant] = "-DENABLE_SPELLCHECK=ON,-DENABLE_SPELLCHECK=OFF,enchant" | ||
51 | PACKAGECONFIG[gtk2] = "-DENABLE_PLUGIN_PROCESS_GTK2=ON,-DENABLE_PLUGIN_PROCESS_GTK2=OFF,gtk+" | ||
52 | PACKAGECONFIG[gles2] = "-DENABLE_GLES2=ON,-DENABLE_GLES2=OFF,virtual/libgles2" | ||
53 | PACKAGECONFIG[webgl] = "-DENABLE_WEBGL=ON,-DENABLE_WEBGL=OFF,virtual/libgl" | ||
54 | PACKAGECONFIG[opengl] = "-DENABLE_OPENGL=ON,-DENABLE_OPENGL=OFF,virtual/libgl" | ||
55 | PACKAGECONFIG[libsecret] = "-DUSE_LIBSECRET=ON,-DUSE_LIBSECRET=OFF,libsecret" | ||
56 | PACKAGECONFIG[libhyphen] = "-DUSE_LIBHYPHEN=ON,-DUSE_LIBHYPHEN=OFF,libhyphen" | ||
57 | # Source is at https://github.com/google/woff2 | ||
58 | PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2" | ||
59 | PACKAGECONFIG[openjpeg] = "-DUSE_OPENJPEG=ON,-DUSE_OPENJPEG=OFF,openjpeg" | ||
60 | |||
61 | EXTRA_OECMAKE = " \ | ||
62 | -DPORT=GTK \ | ||
63 | -DCMAKE_BUILD_TYPE=Release \ | ||
64 | ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON', '-DENABLE_INTROSPECTION=OFF', d)} \ | ||
65 | ${@bb.utils.contains('GTKDOC_ENABLED', 'True', '-DENABLE_GTKDOC=ON', '-DENABLE_GTKDOC=OFF', d)} \ | ||
66 | -DENABLE_MINIBROWSER=ON \ | ||
67 | -DPYTHON_EXECUTABLE=`which python3` \ | ||
68 | -DENABLE_BUBBLEWRAP_SANDBOX=OFF \ | ||
69 | " | ||
70 | |||
71 | # Javascript JIT is not supported on ARC | ||
72 | EXTRA_OECMAKE_append_arc = " -DENABLE_JIT=OFF " | ||
73 | # By default 25-bit "medium" calls are used on ARC | ||
74 | # which is not enough for binaries larger than 32 MiB | ||
75 | CFLAGS_append_arc = " -mlong-calls" | ||
76 | CXXFLAGS_append_arc = " -mlong-calls" | ||
77 | |||
78 | # Javascript JIT is not supported on powerpc | ||
79 | EXTRA_OECMAKE_append_powerpc = " -DENABLE_JIT=OFF " | ||
80 | EXTRA_OECMAKE_append_powerpc64 = " -DENABLE_JIT=OFF " | ||
81 | |||
82 | # ARM JIT code does not build on ARMv4/5/6 anymore | ||
83 | EXTRA_OECMAKE_append_armv5 = " -DENABLE_JIT=OFF " | ||
84 | EXTRA_OECMAKE_append_armv6 = " -DENABLE_JIT=OFF " | ||
85 | EXTRA_OECMAKE_append_armv4 = " -DENABLE_JIT=OFF " | ||
86 | |||
87 | EXTRA_OECMAKE_append_mipsarchn32 = " -DUSE_LD_GOLD=OFF " | ||
88 | EXTRA_OECMAKE_append_powerpc = " -DUSE_LD_GOLD=OFF " | ||
89 | |||
90 | # JIT not supported on MIPS either | ||
91 | EXTRA_OECMAKE_append_mipsarch = " -DENABLE_JIT=OFF -DENABLE_C_LOOP=ON " | ||
92 | |||
93 | # JIT not supported on X32 | ||
94 | # An attempt was made to upstream JIT support for x32 in | ||
95 | # https://bugs.webkit.org/show_bug.cgi?id=100450, but this was closed as | ||
96 | # unresolved due to limited X32 adoption. | ||
97 | EXTRA_OECMAKE_append_x86-x32 = " -DENABLE_JIT=OFF " | ||
98 | |||
99 | SECURITY_CFLAGS_remove_aarch64 = "-fpie" | ||
100 | SECURITY_CFLAGS_append_aarch64 = " -fPIE" | ||
101 | |||
102 | LDFLAGS_append_toolchain-clang = " -rtlib=compiler-rt" | ||
103 | |||
104 | FILES_${PN} += "${libdir}/webkit2gtk-4.0/injected-bundle/libwebkit2gtkinjectedbundle.so" | ||
105 | |||
106 | RRECOMMENDS_${PN} += "ca-certificates shared-mime-info" | ||
107 | |||
108 | # http://errors.yoctoproject.org/Errors/Details/20370/ | ||
109 | ARM_INSTRUCTION_SET_armv4 = "arm" | ||
110 | ARM_INSTRUCTION_SET_armv5 = "arm" | ||
111 | ARM_INSTRUCTION_SET_armv6 = "arm" | ||
112 | |||
113 | # https://bugzilla.yoctoproject.org/show_bug.cgi?id=9474 | ||
114 | # https://bugs.webkit.org/show_bug.cgi?id=159880 | ||
115 | # JSC JIT can build on ARMv7 with -marm, but doesn't work on runtime. | ||
116 | # Upstream only tests regularly the JSC JIT on ARMv7 with Thumb2 (-mthumb). | ||
117 | ARM_INSTRUCTION_SET_armv7a = "thumb" | ||
118 | ARM_INSTRUCTION_SET_armv7r = "thumb" | ||
119 | ARM_INSTRUCTION_SET_armv7ve = "thumb" | ||
120 | |||
121 | # qemu: uncaught target signal 11 (Segmentation fault) - core dumped | ||
122 | # Segmentation fault | ||
123 | GI_DATA_ENABLED_armv7a = "False" | ||
124 | GI_DATA_ENABLED_armv7ve = "False" | ||
125 | |||
126 | # Can't be built with ccache | ||
127 | CCACHE_DISABLE = "1" | ||