diff options
author | Anuj Mittal <anuj.mittal@intel.com> | 2023-05-05 11:12:30 +0800 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2023-05-09 07:50:14 +0100 |
commit | aa53f70b44327c2f29819fa62c92169d58dd4cb8 (patch) | |
tree | 6105240614919023d3eaace2ea00422fe6b82a15 /meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.2.bb | |
parent | 4641605c794db6648311b931fb3a36fe9e5dea56 (diff) | |
download | poky-aa53f70b44327c2f29819fa62c92169d58dd4cb8.tar.gz |
gstreamer1.0: upgrade 1.22.0 -> 1.22.2
(From OE-Core rev: 3da67b03cff75df3f109da961818b3aa6c4ddf95)
(From OE-Core rev: 136a3ea22179eb8e1087928fc8c83ed8eca40b57)
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.2.bb')
-rw-r--r-- | meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.2.bb | 94 |
1 files changed, 94 insertions, 0 deletions
diff --git a/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.2.bb b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.2.bb new file mode 100644 index 0000000000..c1e5d0cd09 --- /dev/null +++ b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.2.bb | |||
@@ -0,0 +1,94 @@ | |||
1 | require gstreamer1.0-plugins-common.inc | ||
2 | |||
3 | SUMMARY = "'Base' GStreamer plugins and helper libraries" | ||
4 | HOMEPAGE = "https://gstreamer.freedesktop.org/" | ||
5 | BUGTRACKER = "https://gitlab.freedesktop.org/gstreamer/gst-plugins-base/-/issues" | ||
6 | LICENSE = "LGPL-2.1-or-later" | ||
7 | LIC_FILES_CHKSUM = "file://COPYING;md5=69333daa044cb77e486cc36129f7a770" | ||
8 | |||
9 | SRC_URI = "https://gstreamer.freedesktop.org/src/gst-plugins-base/gst-plugins-base-${PV}.tar.xz \ | ||
10 | file://0001-ENGR00312515-get-caps-from-src-pad-when-query-caps.patch \ | ||
11 | file://0003-viv-fb-Make-sure-config.h-is-included.patch \ | ||
12 | file://0002-ssaparse-enhance-SSA-text-lines-parsing.patch \ | ||
13 | " | ||
14 | SRC_URI[sha256sum] = "eb65120c4ee79b7a153c3c1972d5c0158c2151877cc51ec7725bba5749679d49" | ||
15 | |||
16 | S = "${WORKDIR}/gst-plugins-base-${PV}" | ||
17 | |||
18 | DEPENDS += "iso-codes util-linux zlib" | ||
19 | |||
20 | inherit gobject-introspection | ||
21 | |||
22 | # opengl packageconfig factored out to make it easy for distros | ||
23 | # and BSP layers to choose OpenGL APIs/platforms/window systems | ||
24 | PACKAGECONFIG_GL ?= "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'gles2 egl', '', d)}" | ||
25 | |||
26 | PACKAGECONFIG ??= " \ | ||
27 | ${GSTREAMER_ORC} \ | ||
28 | ${PACKAGECONFIG_GL} \ | ||
29 | ${@bb.utils.filter('DISTRO_FEATURES', 'alsa x11', d)} \ | ||
30 | jpeg ogg pango png theora vorbis \ | ||
31 | ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland egl', '', d)} \ | ||
32 | " | ||
33 | |||
34 | OPENGL_APIS = 'opengl gles2' | ||
35 | OPENGL_PLATFORMS = 'egl' | ||
36 | |||
37 | X11DEPENDS = "virtual/libx11 libsm libxrender libxv" | ||
38 | X11ENABLEOPTS = "-Dx11=enabled -Dxvideo=enabled -Dxshm=enabled" | ||
39 | X11DISABLEOPTS = "-Dx11=disabled -Dxvideo=disabled -Dxshm=disabled" | ||
40 | |||
41 | PACKAGECONFIG[alsa] = "-Dalsa=enabled,-Dalsa=disabled,alsa-lib" | ||
42 | PACKAGECONFIG[cdparanoia] = "-Dcdparanoia=enabled,-Dcdparanoia=disabled,cdparanoia" | ||
43 | PACKAGECONFIG[graphene] = "-Dgl-graphene=enabled,-Dgl-graphene=disabled,graphene" | ||
44 | PACKAGECONFIG[jpeg] = "-Dgl-jpeg=enabled,-Dgl-jpeg=disabled,jpeg" | ||
45 | PACKAGECONFIG[ogg] = "-Dogg=enabled,-Dogg=disabled,libogg" | ||
46 | PACKAGECONFIG[opus] = "-Dopus=enabled,-Dopus=disabled,libopus" | ||
47 | PACKAGECONFIG[pango] = "-Dpango=enabled,-Dpango=disabled,pango" | ||
48 | PACKAGECONFIG[png] = "-Dgl-png=enabled,-Dgl-png=disabled,libpng" | ||
49 | # This enables Qt5 QML examples in -base. The Qt5 GStreamer | ||
50 | # qmlglsink and qmlglsrc plugins still exist in -good. | ||
51 | PACKAGECONFIG[qt5] = "-Dqt5=enabled,-Dqt5=disabled,qtbase qtdeclarative qtbase-native" | ||
52 | PACKAGECONFIG[theora] = "-Dtheora=enabled,-Dtheora=disabled,libtheora" | ||
53 | PACKAGECONFIG[tremor] = "-Dtremor=enabled,-Dtremor=disabled,tremor" | ||
54 | PACKAGECONFIG[visual] = "-Dlibvisual=enabled,-Dlibvisual=disabled,libvisual" | ||
55 | PACKAGECONFIG[vorbis] = "-Dvorbis=enabled,-Dvorbis=disabled,libvorbis" | ||
56 | PACKAGECONFIG[x11] = "${X11ENABLEOPTS},${X11DISABLEOPTS},${X11DEPENDS}" | ||
57 | |||
58 | # OpenGL API packageconfigs | ||
59 | PACKAGECONFIG[opengl] = ",,virtual/libgl libglu" | ||
60 | PACKAGECONFIG[gles2] = ",,virtual/libgles2" | ||
61 | |||
62 | # OpenGL platform packageconfigs | ||
63 | PACKAGECONFIG[egl] = ",,virtual/egl" | ||
64 | |||
65 | # OpenGL window systems (except for X11) | ||
66 | PACKAGECONFIG[gbm] = ",,virtual/libgbm libgudev libdrm" | ||
67 | PACKAGECONFIG[wayland] = ",,wayland-native wayland wayland-protocols libdrm" | ||
68 | PACKAGECONFIG[dispmanx] = ",,virtual/libomxil" | ||
69 | PACKAGECONFIG[viv-fb] = ",,virtual/libgles2 virtual/libg2d" | ||
70 | |||
71 | OPENGL_WINSYS = "${@bb.utils.filter('PACKAGECONFIG', 'x11 gbm wayland dispmanx egl viv-fb', d)}" | ||
72 | |||
73 | EXTRA_OEMESON += " \ | ||
74 | -Ddoc=disabled \ | ||
75 | ${@get_opengl_cmdline_list('gl_api', d.getVar('OPENGL_APIS'), d)} \ | ||
76 | ${@get_opengl_cmdline_list('gl_platform', d.getVar('OPENGL_PLATFORMS'), d)} \ | ||
77 | ${@get_opengl_cmdline_list('gl_winsys', d.getVar('OPENGL_WINSYS'), d)} \ | ||
78 | " | ||
79 | |||
80 | FILES:${PN}-dev += "${libdir}/gstreamer-1.0/include/gst/gl/gstglconfig.h" | ||
81 | FILES:${MLPREFIX}libgsttag-1.0 += "${datadir}/gst-plugins-base/1.0/license-translations.dict" | ||
82 | |||
83 | def get_opengl_cmdline_list(switch_name, options, d): | ||
84 | selected_options = [] | ||
85 | if bb.utils.contains('DISTRO_FEATURES', 'opengl', True, False, d): | ||
86 | for option in options.split(): | ||
87 | if bb.utils.contains('PACKAGECONFIG', option, True, False, d): | ||
88 | selected_options += [option] | ||
89 | if selected_options: | ||
90 | return '-D' + switch_name + '=' + ','.join(selected_options) | ||
91 | else: | ||
92 | return '' | ||
93 | |||
94 | CVE_PRODUCT += "gst-plugins-base" | ||