gstreamer1.0: upgrade 1.22.3 -> 1.22.4

Bugfixes:
==========
-   Security fixes for flacparse, dvdspu, and subparse
-   d3d11videosink: Fix error on pause and play
-   decklink: Correctly handle SDK strings on macOS and free strings
    after usage on Linux
-   filesink: Fix buffered mode writing of buffer lists and buffers with
    multiple memories
-   gldownload: handle passthrough without a critical
-   h265parse: Fix framerate handling regression
-   oggdemux: vp8 fixes
-   mp4mux, qtmux, qtdemux: Opus audio mapping fixes
-   pngdec: Fix wrong colours output from 16bit RGB images
-   ptp clock: Work around ptpd bug in default configuration
-   srtpdec: fix critical warnings on shutdown
-   v4l2src: fix support for bayer format
-   v4l2videoenc: support force-keyframe event in v4l2 encoder
-   vtenc: apply DTS offset to ensure DTS <= PTS
-   gst-python: allow more functions to be called before gst_init()
-   cerbero: fix vaapi variant; add qt6 build on windows; ensure errors
    on unguarded use of new APIs, require macOS 10.13
-   packages: ship codecalpha, rtponvif, dvbsubenc, switchbin,
    videosignal plugins; fix pango crash on 32-bit windows
-   various bug fixes, memory leak fixes, and other stability and
    reliability improvements

(From OE-Core rev: d7bf88db7f2f55540bf7891474a3a28f5681ddbb)

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/meta/recipes-multimedia/gstreamer/gstreamer1.0-omx_1.22.4.bb b/meta/recipes-multimedia/gstreamer/gstreamer1.0-omx_1.22.4.bb
new file mode 100644
index 0000000000..fc70805daf
--- /dev/null
+++ b/meta/recipes-multimedia/gstreamer/gstreamer1.0-omx_1.22.4.bb
@@ -0,0 +1,47 @@
+SUMMARY = "OpenMAX IL plugins for GStreamer"
+DESCRIPTION = "Wraps available OpenMAX IL components and makes them available as standard GStreamer elements."
+HOMEPAGE = "http://gstreamer.freedesktop.org/"
+SECTION = "multimedia"
+
+LICENSE = "LGPL-2.1-or-later"
+LICENSE_FLAGS = "commercial"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
+                    file://omx/gstomx.h;beginline=1;endline=21;md5=5c8e1fca32704488e76d2ba9ddfa935f"
+
+SRC_URI = "https://gstreamer.freedesktop.org/src/gst-omx/gst-omx-${PV}.tar.xz"
+
+SRC_URI[sha256sum] = "5fcb872d977b035fb75a2d0ea955ba052dc3bdae282f8f60aa9d865808784211"
+
+S = "${WORKDIR}/gst-omx-${PV}"
+
+DEPENDS = "gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-bad virtual/libomxil"
+
+inherit meson pkgconfig upstream-version-is-even
+
+GSTREAMER_1_0_OMX_TARGET ?= "bellagio"
+GSTREAMER_1_0_OMX_CORE_NAME ?= "${libdir}/libomxil-bellagio.so.0"
+
+EXTRA_OEMESON += "-Dtarget=${GSTREAMER_1_0_OMX_TARGET}"
+
+python __anonymous () {
+    omx_target = d.getVar("GSTREAMER_1_0_OMX_TARGET")
+    if omx_target in ['generic', 'bellagio']:
+        # Bellagio headers are incomplete (they are missing the OMX_VERSION_MAJOR,#
+        # OMX_VERSION_MINOR, OMX_VERSION_REVISION, and OMX_VERSION_STEP macros);
+        # appending a directory path to gst-omx' internal OpenMAX IL headers fixes this
+        d.appendVar("CFLAGS", " -I${S}/omx/openmax")
+    elif omx_target == "rpi":
+        # Dedicated Raspberry Pi OpenMAX IL support makes this package machine specific
+        d.setVar("PACKAGE_ARCH", d.getVar("MACHINE_ARCH"))
+}
+
+set_omx_core_name() {
+        sed -i -e "s;^core-name=.*;core-name=${GSTREAMER_1_0_OMX_CORE_NAME};" "${D}${sysconfdir}/xdg/gstomx.conf"
+}
+do_install[postfuncs] += " set_omx_core_name "
+
+FILES:${PN} += "${libdir}/gstreamer-1.0/*.so"
+FILES:${PN}-staticdev += "${libdir}/gstreamer-1.0/*.a"
+
+VIRTUAL-RUNTIME_libomxil ?= "libomxil"
+RDEPENDS:${PN} = "${VIRTUAL-RUNTIME_libomxil}"