summaryrefslogtreecommitdiffstats
path: root/meta/recipes-kernel
diff options
context:
space:
mode:
authorBruce Ashfield <bruce.ashfield@gmail.com>2023-07-06 00:26:38 -0400
committerRichard Purdie <richard.purdie@linuxfoundation.org>2023-07-12 16:50:45 +0100
commit98bbb8a61e698685a24b9c0c4039a02ba48df44e (patch)
tree16421fc13e7be2161568b533acf8dbba6d7d189b /meta/recipes-kernel
parentbb0f9e87700aa40ec8db880ede3c018c1d055786 (diff)
downloadpoky-98bbb8a61e698685a24b9c0c4039a02ba48df44e.tar.gz
linux-yocto: introduce 6.4 reference kernel recipes
kernel v6.4.x will be the next yocto project reference kernel. This is largely the same as the 6.1 recipes, with only SRCREV and minor differences. (From OE-Core rev: dfe90f093345721f7dbf537196ff5494bbbe13fd) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-kernel')
-rw-r--r--meta/recipes-kernel/linux/linux-yocto-rt_6.4.bb48
-rw-r--r--meta/recipes-kernel/linux/linux-yocto-tiny_6.4.bb33
-rw-r--r--meta/recipes-kernel/linux/linux-yocto_6.4.bb71
3 files changed, 152 insertions, 0 deletions
diff --git a/meta/recipes-kernel/linux/linux-yocto-rt_6.4.bb b/meta/recipes-kernel/linux/linux-yocto-rt_6.4.bb
new file mode 100644
index 0000000000..2558c03a7f
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-yocto-rt_6.4.bb
@@ -0,0 +1,48 @@
1KBRANCH ?= "v6.4/standard/preempt-rt/base"
2
3require recipes-kernel/linux/linux-yocto.inc
4
5# CVE exclusions
6include recipes-kernel/linux/cve-exclusion_6.4.inc
7
8# Skip processing of this recipe if it is not explicitly specified as the
9# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
10# to build multiple virtual/kernel providers, e.g. as dependency of
11# core-image-rt-sdk, core-image-rt.
12python () {
13 if d.getVar("KERNEL_PACKAGE_NAME") == "kernel" and d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-yocto-rt":
14 raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
15}
16
17SRCREV_machine ?= "48cdae83316b7055b4e63f3434ea26b0c04d7c71"
18SRCREV_meta ?= "f15c15c0755e36ec185927dd83a8a569186836eb"
19
20SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine;protocol=https \
21 git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-6.4;destsuffix=${KMETA};protocol=https"
22
23LINUX_VERSION ?= "6.4"
24
25LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
26
27DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
28DEPENDS += "openssl-native util-linux-native"
29
30PV = "${LINUX_VERSION}+git${SRCPV}"
31
32KMETA = "kernel-meta"
33KCONF_BSP_AUDIT_LEVEL = "1"
34
35LINUX_KERNEL_TYPE = "preempt-rt"
36
37COMPATIBLE_MACHINE = "^(qemux86|qemux86-64|qemuarm|qemuarmv5|qemuarm64|qemuppc|qemumips)$"
38
39KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
40
41# Functionality flags
42KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
43KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
44KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
45KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
46KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
47KERNEL_FEATURES:append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
48KERNEL_FEATURES:append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
diff --git a/meta/recipes-kernel/linux/linux-yocto-tiny_6.4.bb b/meta/recipes-kernel/linux/linux-yocto-tiny_6.4.bb
new file mode 100644
index 0000000000..5c8008232b
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-yocto-tiny_6.4.bb
@@ -0,0 +1,33 @@
1KBRANCH ?= "v6.4/standard/tiny/base"
2
3LINUX_KERNEL_TYPE = "tiny"
4KCONFIG_MODE = "--allnoconfig"
5
6require recipes-kernel/linux/linux-yocto.inc
7
8# CVE exclusions
9include recipes-kernel/linux/cve-exclusion_6.4.inc
10
11LINUX_VERSION ?= "6.4"
12LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
13
14DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
15DEPENDS += "openssl-native util-linux-native"
16
17KMETA = "kernel-meta"
18KCONF_BSP_AUDIT_LEVEL = "2"
19
20SRCREV_machine ?= "154c43de4e13946ccecf0ff13772db6c2adba355"
21SRCREV_meta ?= "f15c15c0755e36ec185927dd83a8a569186836eb"
22
23PV = "${LINUX_VERSION}+git${SRCPV}"
24
25SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine;protocol=https \
26 git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-6.4;destsuffix=${KMETA};protocol=https"
27
28COMPATIBLE_MACHINE = "^(qemux86|qemux86-64|qemuarm64|qemuarm|qemuarmv5)$"
29
30# Functionality flags
31KERNEL_FEATURES = ""
32
33KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
diff --git a/meta/recipes-kernel/linux/linux-yocto_6.4.bb b/meta/recipes-kernel/linux/linux-yocto_6.4.bb
new file mode 100644
index 0000000000..e3e6e54d64
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-yocto_6.4.bb
@@ -0,0 +1,71 @@
1KBRANCH ?= "v6.4/standard/base"
2
3require recipes-kernel/linux/linux-yocto.inc
4
5# CVE exclusions
6include recipes-kernel/linux/cve-exclusion_6.4.inc
7
8# board specific branches
9KBRANCH:qemuarm ?= "v6.4/standard/arm-versatile-926ejs"
10KBRANCH:qemuarm64 ?= "v6.4/standard/qemuarm64"
11KBRANCH:qemumips ?= "v6.4/standard/mti-malta32"
12KBRANCH:qemuppc ?= "v6.4/standard/qemuppc"
13KBRANCH:qemuriscv64 ?= "v6.4/standard/base"
14KBRANCH:qemuriscv32 ?= "v6.4/standard/base"
15KBRANCH:qemux86 ?= "v6.4/standard/base"
16KBRANCH:qemux86-64 ?= "v6.4/standard/base"
17KBRANCH:qemuloongarch64 ?= "v6.4/standard/base"
18KBRANCH:qemumips64 ?= "v6.4/standard/mti-malta64"
19
20SRCREV_machine:qemuarm ?= "fccbb53f81908991a69214e09ae0eea360410617"
21SRCREV_machine:qemuarm64 ?= "154c43de4e13946ccecf0ff13772db6c2adba355"
22SRCREV_machine:qemuloongarch64 ?= "154c43de4e13946ccecf0ff13772db6c2adba355"
23SRCREV_machine:qemumips ?= "8370d3d4823bcff9532dd6bb163359f75a5416cd"
24SRCREV_machine:qemuppc ?= "154c43de4e13946ccecf0ff13772db6c2adba355"
25SRCREV_machine:qemuriscv64 ?= "154c43de4e13946ccecf0ff13772db6c2adba355"
26SRCREV_machine:qemuriscv32 ?= "154c43de4e13946ccecf0ff13772db6c2adba355"
27SRCREV_machine:qemux86 ?= "154c43de4e13946ccecf0ff13772db6c2adba355"
28SRCREV_machine:qemux86-64 ?= "154c43de4e13946ccecf0ff13772db6c2adba355"
29SRCREV_machine:qemumips64 ?= "efe0a0701a1a8c5b6113d6a06b65857f8c84ac9f"
30SRCREV_machine ?= "154c43de4e13946ccecf0ff13772db6c2adba355"
31SRCREV_meta ?= "f15c15c0755e36ec185927dd83a8a569186836eb"
32
33# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
34# get the <version>/base branch, which is pure upstream -stable, and the same
35# meta SRCREV as the linux-yocto-standard builds. Select your version using the
36# normal PREFERRED_VERSION settings.
37BBCLASSEXTEND = "devupstream:target"
38SRCREV_machine:class-devupstream ?= "0f4ac6b4c5f00f45b7a429c8a5b028a598c6400c"
39PN:class-devupstream = "linux-yocto-upstream"
40KBRANCH:class-devupstream = "v6.4/base"
41
42SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH};protocol=https \
43 git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-6.4;destsuffix=${KMETA};protocol=https"
44
45LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
46LINUX_VERSION ?= "6.4"
47
48PV = "${LINUX_VERSION}+git${SRCPV}"
49
50KMETA = "kernel-meta"
51KCONF_BSP_AUDIT_LEVEL = "1"
52
53KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
54
55COMPATIBLE_MACHINE = "^(qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32|qemuloongarch64)$"
56
57# Functionality flags
58KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
59KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
60KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc cfg/net/mdio.scc"
61KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
62KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
63KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
64KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
65KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
66KERNEL_FEATURES:append:powerpc =" arch/powerpc/powerpc-debug.scc"
67KERNEL_FEATURES:append:powerpc64 =" arch/powerpc/powerpc-debug.scc"
68KERNEL_FEATURES:append:powerpc64le =" arch/powerpc/powerpc-debug.scc"
69
70INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
71
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-06-29 05:35:25 +0000