diff options
author | Alexander Kanavin <alex.kanavin@gmail.com> | 2021-11-02 09:42:55 +0100 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2021-11-03 11:12:25 +0000 |
commit | 933a4bd663fad17203d306239140bbb4880e2371 (patch) | |
tree | d1cf19db1ef1d2d265ec4ca6e097545ea7614759 /meta/recipes-gnome/librsvg/librsvg_2.52.3.bb | |
parent | 5b543a7e72503dd2727a59998de9f41da53a94c8 (diff) | |
download | poky-933a4bd663fad17203d306239140bbb4880e2371.tar.gz |
librsvg: update 2.52.2 -> 2.52.3
(From OE-Core rev: 72a378cf09d297ab7d64b3905cdf313b63c5fa6b)
Signed-off-by: Alexander Kanavin <alex@linutronix.de>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-gnome/librsvg/librsvg_2.52.3.bb')
-rw-r--r-- | meta/recipes-gnome/librsvg/librsvg_2.52.3.bb | 76 |
1 files changed, 76 insertions, 0 deletions
diff --git a/meta/recipes-gnome/librsvg/librsvg_2.52.3.bb b/meta/recipes-gnome/librsvg/librsvg_2.52.3.bb new file mode 100644 index 0000000000..335d891f05 --- /dev/null +++ b/meta/recipes-gnome/librsvg/librsvg_2.52.3.bb | |||
@@ -0,0 +1,76 @@ | |||
1 | SUMMARY = "Library for rendering SVG files" | ||
2 | DESCRIPTION = "A small library to render Scalable Vector Graphics (SVG), \ | ||
3 | associated with the GNOME Project. It renders SVG files to Cairo surfaces. \ | ||
4 | Cairo is the 2D, antialiased drawing library that GNOME uses to draw things to \ | ||
5 | the screen or to generate output for printing." | ||
6 | HOMEPAGE = "https://gitlab.gnome.org/GNOME/librsvg" | ||
7 | BUGTRACKER = "https://gitlab.gnome.org/GNOME/librsvg/issues" | ||
8 | |||
9 | LICENSE = "LGPLv2.1+" | ||
10 | LIC_FILES_CHKSUM = "file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c \ | ||
11 | " | ||
12 | |||
13 | SECTION = "x11/utils" | ||
14 | DEPENDS = "cairo gdk-pixbuf glib-2.0 libcroco libxml2 pango" | ||
15 | BBCLASSEXTEND = "native" | ||
16 | |||
17 | inherit gnomebase gtk-doc pixbufcache upstream-version-is-even gobject-introspection rust | ||
18 | |||
19 | SRC_URI += "file://0001-Makefile.am-pass-rust-target-to-cargo-also-when-not-.patch \ | ||
20 | file://0001-system-deps-src-lib.rs-do-not-probe-into-harcoded-li.patch \ | ||
21 | file://0001-crossbeam-utils-check-only-the-architecture-not-the-.patch \ | ||
22 | file://0001-vendor-system-deps-sort-dependencies-before-using-th.patch \ | ||
23 | file://0005-Add-base-definitions-for-riscv64-musl-libc-0.2.93.patch \ | ||
24 | file://0006-FIXUP-linux-musl-mod.rs-add-riscv64-to-b64-set-libc-.patch \ | ||
25 | file://0007-FIXUP-Correct-definitions-to-match-musl-libc-0.2.93.patch \ | ||
26 | file://0001-Update-checksums-for-modified-files-for-libc.patch \ | ||
27 | " | ||
28 | |||
29 | SRC_URI[archive.sha256sum] = "36e7f5bc88d78608ea7f6c05e4afe4acc1606b9af13c2845d4385073d082b8a4" | ||
30 | |||
31 | # librsvg is still autotools-based, but is calling cargo from its automake-driven makefiles | ||
32 | # so we cannot use cargo class directly, but still need bits and pieces from it | ||
33 | # for cargo to be happy | ||
34 | BASEDEPENDS:append = " cargo-native" | ||
35 | |||
36 | export RUST_BACKTRACE = "full" | ||
37 | export RUSTFLAGS | ||
38 | export RUST_TARGET_PATH | ||
39 | |||
40 | export RUST_TARGET = "${HOST_SYS}" | ||
41 | |||
42 | # rust-cross writes the target linker binary into target json definition without any flags. | ||
43 | # This breaks here because the linker isn't going to work without at least knowing where | ||
44 | # the sysroot is. So copy the json to workdir, and patch in the path to wrapper from rust class | ||
45 | # which supplies the needed flags. | ||
46 | do_compile:prepend() { | ||
47 | cp ${STAGING_LIBDIR_NATIVE}/rustlib/${HOST_SYS}.json ${WORKDIR} | ||
48 | cp ${STAGING_LIBDIR_NATIVE}/rustlib/${BUILD_SYS}.json ${WORKDIR} | ||
49 | sed -ie 's,"linker": ".*","linker": "${RUST_TARGET_CC}",g' ${WORKDIR}/${HOST_SYS}.json | ||
50 | RUST_TARGET_PATH="${WORKDIR}" | ||
51 | export RUST_TARGET_PATH | ||
52 | } | ||
53 | |||
54 | # Issue only on windows | ||
55 | CVE_CHECK_WHITELIST += "CVE-2018-1000041" | ||
56 | |||
57 | CACHED_CONFIGUREVARS = "ac_cv_path_GDK_PIXBUF_QUERYLOADERS=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/gdk-pixbuf-query-loaders" | ||
58 | |||
59 | PACKAGECONFIG ??= "gdkpixbuf" | ||
60 | # The gdk-pixbuf loader | ||
61 | PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader,gdk-pixbuf-native" | ||
62 | |||
63 | do_install:append() { | ||
64 | # Loadable modules don't need .a or .la on Linux | ||
65 | rm -f ${D}${libdir}/gdk-pixbuf-2.0/*/loaders/*.a ${D}${libdir}/gdk-pixbuf-2.0/*/loaders/*.la | ||
66 | } | ||
67 | |||
68 | PACKAGES =+ "librsvg-gtk rsvg" | ||
69 | FILES:rsvg = "${bindir}/rsvg* \ | ||
70 | ${datadir}/pixmaps/svg-viewer.svg \ | ||
71 | ${datadir}/themes" | ||
72 | FILES:librsvg-gtk = "${libdir}/gdk-pixbuf-2.0/*/*/*.so \ | ||
73 | ${datadir}/thumbnailers/librsvg.thumbnailer" | ||
74 | RRECOMMENDS:librsvg-gtk = "gdk-pixbuf-bin" | ||
75 | |||
76 | PIXBUF_PACKAGES = "librsvg-gtk" | ||