diff options
author | Alexander Kanavin <alex.kanavin@gmail.com> | 2019-08-20 17:32:15 +0200 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2019-08-22 22:48:26 +0100 |
commit | 1bab9aa31e1d29591352bad52032ff6fdadf331f (patch) | |
tree | daa14cf1f5695a7915f8f6ec5f38b0a6d14e010b /meta/recipes-gnome/gtk-doc/gtk-doc_1.31.bb | |
parent | 4e4ebda4794c2915beb898caac004a9aef1c6bb1 (diff) | |
download | poky-1bab9aa31e1d29591352bad52032ff6fdadf331f.tar.gz |
gtk-doc: upgrade 1.30 -> 1.31
Drop backported patch.
(From OE-Core rev: bf9cff0177aad35efe58276e1dd65b47872dc6d5)
Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-gnome/gtk-doc/gtk-doc_1.31.bb')
-rw-r--r-- | meta/recipes-gnome/gtk-doc/gtk-doc_1.31.bb | 50 |
1 files changed, 50 insertions, 0 deletions
diff --git a/meta/recipes-gnome/gtk-doc/gtk-doc_1.31.bb b/meta/recipes-gnome/gtk-doc/gtk-doc_1.31.bb new file mode 100644 index 0000000000..4f97ce0633 --- /dev/null +++ b/meta/recipes-gnome/gtk-doc/gtk-doc_1.31.bb | |||
@@ -0,0 +1,50 @@ | |||
1 | SUMMARY = "Documentation generator for glib-based software" | ||
2 | DESCRIPTION = "Gtk-doc is a set of scripts that extract specially formatted comments \ | ||
3 | from glib-based software and produce a set of html documentation files from them" | ||
4 | HOMEPAGE = "http://www.gtk.org/gtk-doc/" | ||
5 | LICENSE = "GPLv2" | ||
6 | LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f" | ||
7 | |||
8 | inherit gnomebase | ||
9 | |||
10 | # Configure the scripts correctly (and build their dependencies) only if they are actually | ||
11 | # going to be used; otheriwse we need only the m4/makefile includes from the gtk-doc tarball. | ||
12 | PACKAGECONFIG ??= "${@bb.utils.contains("DISTRO_FEATURES", "api-documentation", "working-scripts", "", d)}" | ||
13 | |||
14 | # This will cause target gtk-doc to hardcode paths of native dependencies | ||
15 | # into its scripts. This means that target gtk-doc package is broken; | ||
16 | # hopefully no one minds because its scripts are not used for anything during build | ||
17 | # and shouldn't be used on targets. | ||
18 | PACKAGECONFIG[working-scripts] = ",,libxslt-native xmlto-native python3-six python3-pygments" | ||
19 | PACKAGECONFIG[tests] = "--enable-tests,--disable-tests,glib-2.0" | ||
20 | |||
21 | SRC_URI[archive.md5sum] = "6239713011369a4fbdc7619350403772" | ||
22 | SRC_URI[archive.sha256sum] = "a51687956d0377ac70904d03fdc73c9e116589b4a01453fa92162442b3657011" | ||
23 | SRC_URI += "file://0001-Do-not-hardocode-paths-to-perl-python-in-scripts.patch \ | ||
24 | file://0001-Do-not-error-out-if-xsltproc-is-not-found.patch \ | ||
25 | file://conditionaltests.patch \ | ||
26 | file://no-clobber.patch \ | ||
27 | " | ||
28 | SRC_URI_append_class-native = " file://pkg-config-native.patch" | ||
29 | |||
30 | BBCLASSEXTEND = "native nativesdk" | ||
31 | |||
32 | # Do not check for XML catalogs when building because that | ||
33 | # information is not used for anything during build. Recipe | ||
34 | # dependencies make sure we have all the right bits. | ||
35 | do_configure_prepend() { | ||
36 | sed -i -e 's,^JH_CHECK_XML_CATALOG.*,,' ${S}/configure.ac | ||
37 | } | ||
38 | |||
39 | FILES_${PN} += "${datadir}/sgml" | ||
40 | FILES_${PN}-dev += "${libdir}/cmake" | ||
41 | FILES_${PN}-doc = "" | ||
42 | |||
43 | SYSROOT_PREPROCESS_FUNCS_append_class-native = " gtkdoc_makefiles_sysroot_preprocess" | ||
44 | gtkdoc_makefiles_sysroot_preprocess() { | ||
45 | # Patch the gtk-doc makefiles so that the qemu wrapper is used to run transient binaries | ||
46 | # instead of libtool wrapper or running them directly | ||
47 | sed -i \ | ||
48 | -e "s|GTKDOC_RUN =.*|GTKDOC_RUN = \$(top_builddir)/gtkdoc-qemuwrapper|" \ | ||
49 | ${SYSROOT_DESTDIR}${datadir}/gtk-doc/data/gtk-doc*make | ||
50 | } | ||