diff options
author | Alexander Kanavin <alex.kanavin@gmail.com> | 2019-12-05 16:50:05 +0100 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2019-12-09 12:00:43 +0000 |
commit | 70d3ef49a8883c19b87189a73193e9ad991edbb4 (patch) | |
tree | 3bbdf23b9a41d3d0a6eeeb5eabf64991ae2e1777 /meta/recipes-extended/texinfo/texinfo_6.7.bb | |
parent | bbd9f784fbee8ab1cac94a3bfd6749fc0d142691 (diff) | |
download | poky-70d3ef49a8883c19b87189a73193e9ad991edbb4.tar.gz |
texinfo: update to 6.7
Drop 0001-Unset-need_charset_alias-when-building-for-musl.patch
as the problematic code is gone.
Rebase the other patches.
License-Update: http links changed to https
(From OE-Core rev: b234a4ed4d6a9c2e00f5fa38cf04867c7ada24a0)
Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-extended/texinfo/texinfo_6.7.bb')
-rw-r--r-- | meta/recipes-extended/texinfo/texinfo_6.7.bb | 91 |
1 files changed, 91 insertions, 0 deletions
diff --git a/meta/recipes-extended/texinfo/texinfo_6.7.bb b/meta/recipes-extended/texinfo/texinfo_6.7.bb new file mode 100644 index 0000000000..d421b79a0b --- /dev/null +++ b/meta/recipes-extended/texinfo/texinfo_6.7.bb | |||
@@ -0,0 +1,91 @@ | |||
1 | SUMMARY = "Documentation system for on-line information and printed output" | ||
2 | DESCRIPTION = "Texinfo is a documentation system that can produce both \ | ||
3 | online information and printed output from a single source file. The \ | ||
4 | GNU Project uses the Texinfo file format for most of its documentation." | ||
5 | HOMEPAGE = "http://www.gnu.org/software/texinfo/" | ||
6 | SECTION = "console/utils" | ||
7 | LICENSE = "GPLv3+" | ||
8 | LIC_FILES_CHKSUM = "file://COPYING;md5=1ebbd3e34237af26da5dc08a4e440464" | ||
9 | |||
10 | PROVIDES_append_class-native = " texinfo-replacement-native" | ||
11 | |||
12 | def compress_pkg(d): | ||
13 | if bb.data.inherits_class('compress_doc', d): | ||
14 | compress = d.getVar("DOC_COMPRESS") | ||
15 | if compress == "gz": | ||
16 | return "gzip" | ||
17 | elif compress == "bz2": | ||
18 | return "bzip2" | ||
19 | elif compress == "xz": | ||
20 | return "xz" | ||
21 | return "" | ||
22 | |||
23 | RDEPENDS_info += "${@compress_pkg(d)}" | ||
24 | |||
25 | DEPENDS = "zlib ncurses texinfo-replacement-native" | ||
26 | DEPENDS_class-native = "zlib-native ncurses-native" | ||
27 | |||
28 | TARGET_PATCH = "file://use_host_makedoc.patch" | ||
29 | TARGET_PATCH_class-native = "" | ||
30 | |||
31 | SRC_URI = "${GNU_MIRROR}/texinfo/${BP}.tar.gz \ | ||
32 | file://texinfo-4.12-zlib.patch \ | ||
33 | file://disable-native-tools.patch \ | ||
34 | file://link-zip.patch \ | ||
35 | file://dont-depend-on-help2man.patch \ | ||
36 | ${TARGET_PATCH} \ | ||
37 | " | ||
38 | |||
39 | SRC_URI[md5sum] = "f0c1782f68ef73738d74bd1e9e30793a" | ||
40 | SRC_URI[sha256sum] = "a52d05076b90032cb2523673c50e53185938746482cf3ca0213e9b4b50ac2d3e" | ||
41 | |||
42 | tex_texinfo = "texmf/tex/texinfo" | ||
43 | |||
44 | inherit gettext autotools multilib_script | ||
45 | |||
46 | MULTILIB_SCRIPTS = "${PN}:${bindir}/texi2any" | ||
47 | |||
48 | EXTRA_AUTORECONF += "-I ${S}/gnulib/m4" | ||
49 | |||
50 | do_configure_prepend () { | ||
51 | # autotools_do_configure updates po/Makefile.in.in, we also need | ||
52 | # update po_document. | ||
53 | cp -f ${STAGING_DATADIR_NATIVE}/gettext/po/Makefile.in.in ${S}/po_document/ | ||
54 | } | ||
55 | |||
56 | do_compile_prepend() { | ||
57 | if [ -d tools ];then | ||
58 | oe_runmake -C tools/gnulib/lib | ||
59 | fi | ||
60 | } | ||
61 | |||
62 | do_install_append() { | ||
63 | mkdir -p ${D}${datadir}/${tex_texinfo} | ||
64 | install -p -m644 ${S}/doc/texinfo.tex ${S}/doc/txi-??.tex ${D}${datadir}/${tex_texinfo} | ||
65 | sed -i -e '1s,#!.*perl,#! ${USRBINPATH}/env perl,' ${D}${bindir}/texi2any ${D}${bindir}/pod2texi | ||
66 | } | ||
67 | |||
68 | do_install_append_class-native() { | ||
69 | install -m 755 info/makedoc ${D}${bindir} | ||
70 | } | ||
71 | |||
72 | PACKAGES += "info info-doc" | ||
73 | |||
74 | FILES_info = "${bindir}/info ${bindir}/infokey ${bindir}/install-info" | ||
75 | FILES_info-doc = "${infodir}/info.info* ${infodir}/dir ${infodir}/info-*.info* \ | ||
76 | ${mandir}/man1/info.1* ${mandir}/man5/info.5* \ | ||
77 | ${mandir}/man1/infokey.1* ${mandir}/man1/install-info.1*" | ||
78 | |||
79 | FILES_${PN} = "${bindir}/makeinfo ${bindir}/texi* ${bindir}/pdftexi2dvi ${bindir}/pod2texi ${datadir}/texinfo" | ||
80 | RDEPENDS_${PN} = "perl" | ||
81 | FILES_${PN}-doc = "${infodir}/texinfo* \ | ||
82 | ${datadir}/${tex_texinfo} \ | ||
83 | ${mandir}/man1 ${mandir}/man5" | ||
84 | |||
85 | # Lie about providing the Locale::gettext_xs module. It is not actually built, | ||
86 | # but the code will test for it and if not found use Locale::gettext_pp instead. | ||
87 | # However, this causes a file dependency on perl(Locale::gettext_xs) to be | ||
88 | # generated, which must be satisfied. | ||
89 | RPROVIDES_${PN} += "perl(Locale::gettext_xs)" | ||
90 | |||
91 | BBCLASSEXTEND = "native nativesdk" | ||