diff options
author | Wang Mingyu <wangmy@fujitsu.com> | 2024-04-24 16:42:08 +0800 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2024-04-25 10:06:02 +0100 |
commit | 8f0971215ae6689681ed3003186ab59d2d557319 (patch) | |
tree | 93b66d043c76098c6621a8c01ac9604f702af11f /meta/recipes-extended/lighttpd/lighttpd_1.4.76.bb | |
parent | fb21371fef2d905da7f080fb2c1047676440dcf3 (diff) | |
download | poky-8f0971215ae6689681ed3003186ab59d2d557319.tar.gz |
lighttpd: upgrade 1.4.75 -> 1.4.76
Changelog:
==========
* [core] add default to builtin mimetype.assign
* [core] add MPTCP support
* [core] disable MPTCP support by default
* [mod_expire] omit caching hdrs for 204 No Content
* [mod_staticfile] noinline cold func
* [core] GNU/Hurd preadv2() RWF_NOWAIT ENOTSUP
* [core] special value for Linux POLLRDHUP on SPARC
* [mod_openssl] define asn1 time w/ OPENSSL_NO_OCSP
* [h2] VU#421644 HTTP/2 CONTINUATION Flood
* [build] packdist.sh git archive; replace make dist
* [core] gw_network_backend_write_error() cold func
* [core] reduce syscalls in some backend connect
* [core] defer TCP_FIN propagate if connect()ing
* [ci] workaround some packaging issues in NetBSD 10
(From OE-Core rev: 09ee0fb9f36eb856354b551855323b8ca38c0e80)
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-extended/lighttpd/lighttpd_1.4.76.bb')
-rw-r--r-- | meta/recipes-extended/lighttpd/lighttpd_1.4.76.bb | 76 |
1 files changed, 76 insertions, 0 deletions
diff --git a/meta/recipes-extended/lighttpd/lighttpd_1.4.76.bb b/meta/recipes-extended/lighttpd/lighttpd_1.4.76.bb new file mode 100644 index 0000000000..f0fdda4190 --- /dev/null +++ b/meta/recipes-extended/lighttpd/lighttpd_1.4.76.bb | |||
@@ -0,0 +1,76 @@ | |||
1 | SUMMARY = "Lightweight high-performance web server" | ||
2 | HOMEPAGE = "http://www.lighttpd.net/" | ||
3 | DESCRIPTION = "Lightweight high-performance web server is designed and optimized for high performance environments. With a small memory footprint compared to other web-servers, effective management of the cpu-load, and advanced feature set (FastCGI, SCGI, Auth, Output-Compression, URL-Rewriting and many more)" | ||
4 | BUGTRACKER = "http://redmine.lighttpd.net/projects/lighttpd/issues" | ||
5 | |||
6 | LICENSE = "BSD-3-Clause" | ||
7 | LIC_FILES_CHKSUM = "file://COPYING;md5=e4dac5c6ab169aa212feb5028853a579" | ||
8 | |||
9 | SECTION = "net" | ||
10 | RDEPENDS:${PN} = "lighttpd-module-dirlisting" | ||
11 | RRECOMMENDS:${PN} = "lighttpd-module-accesslog" | ||
12 | |||
13 | SRC_URI = "http://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${PV}.tar.xz \ | ||
14 | file://index.html.lighttpd \ | ||
15 | file://lighttpd.conf \ | ||
16 | file://lighttpd \ | ||
17 | " | ||
18 | |||
19 | SRC_URI[sha256sum] = "8cbf4296e373cfd0cedfe9d978760b5b05c58fdc4048b4e2bcaf0a61ac8f5011" | ||
20 | |||
21 | DEPENDS = "virtual/crypt" | ||
22 | |||
23 | PACKAGECONFIG ??= "openssl pcre zlib \ | ||
24 | ${@bb.utils.contains('DISTRO_FEATURES', 'xattr', 'attr', '', d)} \ | ||
25 | " | ||
26 | |||
27 | PACKAGECONFIG[libev] = "-Dwith_libev=enabled,-Dwith_libev=disabled,libev" | ||
28 | PACKAGECONFIG[mysql] = "-Dwith_mysql=enabled,-Dwith_mysql=disabled,mariadb" | ||
29 | PACKAGECONFIG[ldap] = "-Dwith_ldap=enabled,-Dwith_ldap=disabled,openldap" | ||
30 | PACKAGECONFIG[attr] = "-Dwith_xattr=true,-Dwith_xattr=false,attr" | ||
31 | PACKAGECONFIG[openssl] = "-Dwith_openssl=true,-Dwith_openssl=false,openssl" | ||
32 | PACKAGECONFIG[krb5] = "-Dwith_krb5=enabled,-Dwith_krb5=disabled,krb5" | ||
33 | PACKAGECONFIG[pcre] = "-Dwith_pcre=pcre2,-Dwith_pcre=disabled,libpcre2" | ||
34 | PACKAGECONFIG[zlib] = "-Dwith_zlib=enabled,-Dwith_zlib=disabled,zlib" | ||
35 | PACKAGECONFIG[bzip2] = "-Dwith_bzip=enabled,-Dwith_bzip=disabled,bzip2" | ||
36 | PACKAGECONFIG[webdav-props] = "-Dwith_webdav_props=enabled,-Dwith_webdav_props=disabled,libxml2 sqlite3" | ||
37 | PACKAGECONFIG[webdav-locks] = "-Dwith_webdav_locks=enabled,-Dwith_webdav_locks=disabled,util-linux" | ||
38 | PACKAGECONFIG[lua] = "-Dwith_lua=true,-Dwith_lua=false,lua" | ||
39 | PACKAGECONFIG[zstd] = "-Dwith_zstd=enabled,-Dwith_zstd=disabled,zstd" | ||
40 | |||
41 | inherit meson pkgconfig update-rc.d gettext systemd | ||
42 | |||
43 | INITSCRIPT_NAME = "lighttpd" | ||
44 | INITSCRIPT_PARAMS = "defaults 70" | ||
45 | |||
46 | SYSTEMD_SERVICE:${PN} = "lighttpd.service" | ||
47 | |||
48 | do_install:append() { | ||
49 | install -d ${D}${sysconfdir}/init.d ${D}${sysconfdir}/lighttpd ${D}${sysconfdir}/lighttpd.d ${D}/www/pages/dav | ||
50 | install -m 0755 ${WORKDIR}/lighttpd ${D}${sysconfdir}/init.d | ||
51 | install -m 0644 ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}/lighttpd | ||
52 | install -m 0644 ${WORKDIR}/index.html.lighttpd ${D}/www/pages/index.html | ||
53 | |||
54 | install -d ${D}${systemd_system_unitdir} | ||
55 | install -m 0644 ${S}/doc/systemd/lighttpd.service ${D}${systemd_system_unitdir} | ||
56 | sed -i -e 's,@SBINDIR@,${sbindir},g' \ | ||
57 | -e 's,@SYSCONFDIR@,${sysconfdir},g' \ | ||
58 | -e 's,@BASE_BINDIR@,${base_bindir},g' \ | ||
59 | ${D}${systemd_system_unitdir}/lighttpd.service | ||
60 | #For FHS compliance, create symbolic links to /var/log and /var/tmp for logs and temporary data | ||
61 | ln -sf ${localstatedir}/log ${D}/www/logs | ||
62 | ln -sf ${localstatedir}/tmp ${D}/www/var | ||
63 | } | ||
64 | |||
65 | # bitbake.conf sets ${libdir}/${BPN}/* in FILES, which messes up the module split. | ||
66 | # So we re-do the variable. | ||
67 | FILES:${PN} = "${sysconfdir} /www ${sbindir}" | ||
68 | |||
69 | CONFFILES:${PN} = "${sysconfdir}/lighttpd/lighttpd.conf" | ||
70 | |||
71 | PACKAGES_DYNAMIC += "^lighttpd-module-.*" | ||
72 | |||
73 | python populate_packages:prepend () { | ||
74 | lighttpd_libdir = d.expand('${prefix}/lib/lighttpd') | ||
75 | do_split_packages(d, lighttpd_libdir, r'^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='') | ||
76 | } | ||