summaryrefslogtreecommitdiffstats
path: root/meta/recipes-extended/libarchive/libarchive_3.2.0.bb
diff options
context:
space:
mode:
authorPaul Barker <paul@paulbarker.me.uk>2016-05-28 14:26:15 +0100
committerRichard Purdie <richard.purdie@linuxfoundation.org>2016-06-01 12:38:42 +0100
commitc6e5c00d408d4109e4f7d9557ba92f471bbe178f (patch)
tree88a742f59505ef49b2545cea6a811b905d1d6041 /meta/recipes-extended/libarchive/libarchive_3.2.0.bb
parent9d7867a054f84e6e53cff1da26f32caeec0180d6 (diff)
downloadpoky-c6e5c00d408d4109e4f7d9557ba92f471bbe178f.tar.gz
libarchive: Upgrade to v3.2.0
All patches are removed as they are no longer needed. Most were merged into this release of libarchive. "0001-Set-xattrs-after-setting-times.patch" was dropped upstream after discussion, see https://github.com/libarchive/libarchive/pull/664. The COPYING file in libarchive had a couple of minor changes to clarify which files are under which copyrights but the overall license is unaffected. (From OE-Core rev: 4976382011106b9515e44359f2f6bb1d0c69fdb3) Signed-off-by: Paul Barker <paul@paulbarker.me.uk> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-extended/libarchive/libarchive_3.2.0.bb')
-rw-r--r--meta/recipes-extended/libarchive/libarchive_3.2.0.bb66
1 files changed, 66 insertions, 0 deletions
diff --git a/meta/recipes-extended/libarchive/libarchive_3.2.0.bb b/meta/recipes-extended/libarchive/libarchive_3.2.0.bb
new file mode 100644
index 0000000000..e1f0202931
--- /dev/null
+++ b/meta/recipes-extended/libarchive/libarchive_3.2.0.bb
@@ -0,0 +1,66 @@
1SUMMARY = "Support for reading various archive formats"
2DESCRIPTION = "C library and command-line tools for reading and writing tar, cpio, zip, ISO, and other archive formats"
3HOMEPAGE = "http://www.libarchive.org/"
4SECTION = "devel"
5LICENSE = "BSD"
6LIC_FILES_CHKSUM = "file://COPYING;md5=ed99aca006bc346974bb745a35336425"
7
8DEPENDS = "e2fsprogs-native"
9
10PACKAGECONFIG ?= "zlib bz2"
11
12PACKAGECONFIG_append_class-target = "\
13 libxml2 \
14 ${@bb.utils.contains('DISTRO_FEATURES', 'acl', 'acl', '', d)} \
15 ${@bb.utils.contains('DISTRO_FEATURES', 'xattr', 'xattr', '', d)} \
16 ${@bb.utils.contains('DISTRO_FEATURES', 'largefile', 'largefile', '', d)} \
17"
18
19PACKAGECONFIG_append_class-nativesdk = " largefile"
20
21PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
22PACKAGECONFIG[xattr] = "--enable-xattr,--disable-xattr,attr,"
23PACKAGECONFIG[largefile] = "--enable-largefile,--disable-largefile,,"
24PACKAGECONFIG[zlib] = "--with-zlib,--without-zlib,zlib,"
25PACKAGECONFIG[bz2] = "--with-bz2lib,--without-bz2lib,bzip2,"
26PACKAGECONFIG[xz] = "--with-lzmadec --with-lzma,--without-lzmadec --without-lzma,xz,"
27PACKAGECONFIG[openssl] = "--with-openssl,--without-openssl,openssl,"
28PACKAGECONFIG[libxml2] = "--with-xml2,--without-xml2,libxml2,"
29PACKAGECONFIG[expat] = "--with-expat,--without-expat,expat,"
30PACKAGECONFIG[lzo] = "--with-lzo2,--without-lzo2,lzo,"
31PACKAGECONFIG[nettle] = "--with-nettle,--without-nettle,nettle,"
32
33SRC_URI = "http://libarchive.org/downloads/libarchive-${PV}.tar.gz \
34 "
35
36SRC_URI[md5sum] = "596210b5a9c2ff74a0f7ca34838d655f"
37SRC_URI[sha256sum] = "7bce45fd71ff01dc20d19edd78322d4965583d81b8bed8e26cacb65d6f5baa87"
38
39inherit autotools update-alternatives pkgconfig
40
41CPPFLAGS += "-I${WORKDIR}/extra-includes"
42
43do_configure[cleandirs] += "${WORKDIR}/extra-includes"
44do_configure_prepend() {
45 # We just need the headers for some type constants, so no need to
46 # build all of e2fsprogs for the target
47 cp -R ${STAGING_INCDIR_NATIVE}/ext2fs ${WORKDIR}/extra-includes/
48}
49
50ALTERNATIVE_PRIORITY = "100"
51
52PACKAGES =+ "bsdtar"
53FILES_bsdtar = "${bindir}/bsdtar"
54
55ALTERNATIVE_bsdtar = "tar"
56ALTERNATIVE_LINK_NAME[tar] = "${base_bindir}/tar"
57ALTERNATIVE_TARGET[tar] = "${bindir}/bsdtar"
58
59PACKAGES =+ "bsdcpio"
60FILES_bsdcpio = "${bindir}/bsdcpio"
61
62ALTERNATIVE_bsdcpio = "cpio"
63ALTERNATIVE_LINK_NAME[cpio] = "${base_bindir}/cpio"
64ALTERNATIVE_TARGET[cpio] = "${bindir}/bsdcpio"
65
66BBCLASSEXTEND = "native nativesdk"