diff options
author | Alexander Kanavin <alex.kanavin@gmail.com> | 2021-07-30 13:45:02 +0200 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2021-08-02 15:44:10 +0100 |
commit | 3665b46e5ff5014110f427e681c11134e61963d7 (patch) | |
tree | 0d1e360474f93352126cef028f9fbb0aeca8a79b /meta/recipes-extended/iputils/iputils_20210722.bb | |
parent | 0b46f264a4c2e8cb75958a81a25a87830db726aa (diff) | |
download | poky-3665b46e5ff5014110f427e681c11134e61963d7.tar.gz |
iputils: update 20210202 -> 20210722
Drop rdisc part from 0001-rarpd-rdisc-Drop-PrivateUsers.patch
as it's been fixed upstream; rarpd still isn't.
(From OE-Core rev: 521a8b2161614db50deed16a7a70d924b8ffe12f)
Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-extended/iputils/iputils_20210722.bb')
-rw-r--r-- | meta/recipes-extended/iputils/iputils_20210722.bb | 71 |
1 files changed, 71 insertions, 0 deletions
diff --git a/meta/recipes-extended/iputils/iputils_20210722.bb b/meta/recipes-extended/iputils/iputils_20210722.bb new file mode 100644 index 0000000000..c2a5bf44ea --- /dev/null +++ b/meta/recipes-extended/iputils/iputils_20210722.bb | |||
@@ -0,0 +1,71 @@ | |||
1 | SUMMARY = "Network monitoring tools" | ||
2 | DESCRIPTION = "Utilities for the IP protocol, including traceroute6, \ | ||
3 | tracepath, tracepath6, ping, ping6 and arping." | ||
4 | HOMEPAGE = "https://github.com/iputils/iputils" | ||
5 | SECTION = "console/network" | ||
6 | |||
7 | LICENSE = "BSD & GPLv2+" | ||
8 | |||
9 | LIC_FILES_CHKSUM = "file://LICENSE;md5=55aa8c9fcad0691cef0ecd420361e390" | ||
10 | |||
11 | DEPENDS = "gnutls" | ||
12 | |||
13 | SRC_URI = "git://github.com/iputils/iputils \ | ||
14 | file://0001-rarpd-rdisc-Drop-PrivateUsers.patch \ | ||
15 | " | ||
16 | SRCREV = "71bb2a6c72e9f658e90ac618c73d873a76bbaa81" | ||
17 | |||
18 | S = "${WORKDIR}/git" | ||
19 | |||
20 | UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>20\d+)" | ||
21 | |||
22 | # Fixed in 2000-10-10, but the versioning of iputils | ||
23 | # breaks the version order. | ||
24 | CVE_CHECK_WHITELIST += "CVE-2000-1213 CVE-2000-1214" | ||
25 | |||
26 | PACKAGECONFIG ??= "libcap rarpd \ | ||
27 | ${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', 'ninfod traceroute6', '', d)} \ | ||
28 | ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}" | ||
29 | PACKAGECONFIG[libcap] = "-DUSE_CAP=true, -DUSE_CAP=false -DNO_SETCAP_OR_SUID=true, libcap libcap-native" | ||
30 | PACKAGECONFIG[libidn] = "-DUSE_IDN=true, -DUSE_IDN=false, libidn2" | ||
31 | PACKAGECONFIG[gettext] = "-DUSE_GETTEXT=true, -DUSE_GETTEXT=false, gettext" | ||
32 | PACKAGECONFIG[ninfod] = "-DBUILD_NINFOD=true,-DBUILD_NINFOD=false," | ||
33 | PACKAGECONFIG[rarpd] = "-DBUILD_RARPD=true,-DBUILD_RARPD=false," | ||
34 | PACKAGECONFIG[systemd] = "-Dsystemdunitdir=${systemd_unitdir}/system,,systemd" | ||
35 | PACKAGECONFIG[tftpd] = "-DBUILD_TFTPD=true, -DBUILD_TFTPD=false," | ||
36 | PACKAGECONFIG[traceroute6] = "-DBUILD_TRACEROUTE6=true,-DBUILD_TRACEROUTE6=false," | ||
37 | PACKAGECONFIG[docs] = "-DBUILD_HTML_MANS=true -DBUILD_MANS=true,-DBUILD_HTML_MANS=false -DBUILD_MANS=false, libxslt" | ||
38 | |||
39 | inherit meson systemd update-alternatives | ||
40 | |||
41 | EXTRA_OEMESON += "--prefix=${root_prefix}/" | ||
42 | |||
43 | ALTERNATIVE_PRIORITY = "100" | ||
44 | |||
45 | ALTERNATIVE:${PN}-ping = "ping" | ||
46 | ALTERNATIVE_LINK_NAME[ping] = "${base_bindir}/ping" | ||
47 | |||
48 | SPLITPKGS = "${PN}-ping ${PN}-arping ${PN}-tracepath ${PN}-clockdiff ${PN}-rdisc \ | ||
49 | ${@bb.utils.contains('PACKAGECONFIG', 'rarpd', '${PN}-rarpd', '', d)} \ | ||
50 | ${@bb.utils.contains('PACKAGECONFIG', 'tftpd', '${PN}-tftpd', '', d)} \ | ||
51 | ${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', '${PN}-traceroute6 ${PN}-ninfod', '', d)}" | ||
52 | PACKAGES += "${SPLITPKGS}" | ||
53 | |||
54 | ALLOW_EMPTY:${PN} = "1" | ||
55 | RDEPENDS:${PN} += "${SPLITPKGS}" | ||
56 | |||
57 | FILES:${PN} = "" | ||
58 | FILES:${PN}-ping = "${base_bindir}/ping.${BPN}" | ||
59 | FILES:${PN}-arping = "${base_bindir}/arping" | ||
60 | FILES:${PN}-tracepath = "${base_bindir}/tracepath" | ||
61 | FILES:${PN}-traceroute6 = "${base_bindir}/traceroute6" | ||
62 | FILES:${PN}-clockdiff = "${base_bindir}/clockdiff" | ||
63 | FILES:${PN}-tftpd = "${base_bindir}/tftpd ${sysconfdir}/xinetd.d/tftp" | ||
64 | FILES:${PN}-rarpd = "${base_sbindir}/rarpd ${systemd_unitdir}/system/rarpd@.service" | ||
65 | FILES:${PN}-rdisc = "${base_sbindir}/rdisc" | ||
66 | FILES:${PN}-ninfod = "${base_sbindir}/ninfod ${sysconfdir}/init.d/ninfod.sh" | ||
67 | |||
68 | SYSTEMD_PACKAGES = "${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', '${PN}-ninfod', '', d)} \ | ||
69 | ${PN}-rdisc" | ||
70 | SYSTEMD_SERVICE:${PN}-ninfod = "ninfod.service" | ||
71 | SYSTEMD_SERVICE:${PN}-rdisc = "rdisc.service" | ||