tcl: upgrade 8.6.9 -> 8.6.10

Refresh patches:
  alter-includedir.patch
  tcl-remove-hardcoded-install-path.patch

Backport a patch to fix tk build failure with cross compile:
  0001-Fix-abd4abedd2-Failed-to-build-tk-8.6.10-with-cross-.patch
See:
https://core.tcl-lang.org/tk/tktview/abd4abedd2f01c12839f0ad94564ae31137f7af5

(From OE-Core rev: f7226d8b28d7ee9292c53c8830c86c0619910f23)

Signed-off-by: Yi Zhao <yi.zhao@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 0 insertions, 101 deletions

diff --git a/meta/recipes-devtools/tcltk/tcl_8.6.9.bb b/meta/recipes-devtools/tcltk/tcl_8.6.9.bb
deleted file mode 100644
index 7f3778153a..0000000000
--- a/meta/recipes-devtools/tcltk/tcl_8.6.9.bb
+++ /dev/null
@@ -1,101 +0,0 @@
-SUMMARY = "Tool Command Language"
-HOMEPAGE = "http://tcl.sourceforge.net"
-SECTION = "devel/tcltk"
-
-# http://www.tcl.tk/software/tcltk/license.html
-LICENSE = "tcl & BSD-3-Clause"
-LIC_FILES_CHKSUM = "file://../license.terms;md5=058f6229798281bbcac4239c788cfa38 \
-    file://../compat/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
-    file://../library/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
-    file://../macosx/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
-    file://../tests/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
-    file://../win/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
-"
-
-DEPENDS = "tcl-native zlib"
-
-BASE_SRC_URI = "${SOURCEFORGE_MIRROR}/tcl/${BPN}${PV}-src.tar.gz \
-                file://tcl-add-soname.patch"
-SRC_URI = "${BASE_SRC_URI} \
-           file://fix_non_native_build_issue.patch \
-           file://fix_issue_with_old_distro_glibc.patch \
-           file://no_packages.patch \
-           file://tcl-remove-hardcoded-install-path.patch \
-           file://alter-includedir.patch \
-           file://run-ptest \
-"
-SRC_URI[md5sum] = "aa0a121d95a0e7b73a036f26028538d4"
-SRC_URI[sha256sum] = "ad0cd2de2c87b9ba8086b43957a0de3eb2eb565c7159d5f53ccbba3feb915f4e"
-
-SRC_URI_class-native = "${BASE_SRC_URI}"
-
-S = "${WORKDIR}/${BPN}${PV}/unix"
-
-VER = "${PV}"
-
-inherit autotools ptest binconfig
-
-EXTRA_OECONF = "--enable-threads --disable-rpath --libdir=${libdir}"
-
-do_compile_prepend() {
-        echo > ${S}/../compat/fixstrtod.c
-}
-
-do_install() {
-        autotools_do_install
-        oe_runmake 'DESTDIR=${D}' install-private-headers
-        ln -sf ./tclsh${VER} ${D}${bindir}/tclsh
-        ln -sf tclsh8.6 ${D}${bindir}/tclsh${VER}
-        sed -i "s;-L${B};-L${STAGING_LIBDIR};g" tclConfig.sh
-        sed -i "s;'${WORKDIR};'${STAGING_INCDIR};g" tclConfig.sh
-        install -d ${D}${bindir_crossscripts}
-        install -m 0755 tclConfig.sh ${D}${bindir_crossscripts}
-        install -m 0755 tclConfig.sh ${D}${libdir}
-        for dir in compat generic unix; do
-                install -d ${D}${includedir}/${BPN}${VER}/$dir
-                install -m 0644 ${S}/../$dir/*.h ${D}${includedir}/${BPN}${VER}/$dir/
-        done
-}
-
-SYSROOT_DIRS += "${bindir_crossscripts}"
-
-PACKAGES =+ "tcl-lib"
-FILES_tcl-lib = "${libdir}/libtcl8.6.so.*"
-FILES_${PN} += "${libdir}/tcl${VER} ${libdir}/tcl8.6 ${libdir}/tcl8"
-FILES_${PN}-dev += "${libdir}/tclConfig.sh ${libdir}/tclooConfig.sh"
-
-# isn't getting picked up by shlibs code
-RDEPENDS_${PN} += "tcl-lib"
-RDEPENDS_${PN}_class-native = ""
-RDEPENDS_${PN}-ptest += "libgcc"
-
-BBCLASSEXTEND = "native nativesdk"
-
-do_compile_ptest() {
-        oe_runmake tcltest
-}
-
-do_install_ptest() {
-        cp ${B}/tcltest ${D}${PTEST_PATH}
-        cp -r ${S}/../library ${D}${PTEST_PATH}
-        cp -r ${S}/../tests ${D}${PTEST_PATH}
-}
-
-# Fix some paths that might be used by Tcl extensions
-BINCONFIG_GLOB = "*Config.sh"
-
-# Fix the path in sstate
-SSTATE_SCAN_FILES += "*Config.sh"
-
-# Cleanup host path from ${libdir}/tclConfig.sh and remove the
-# ${bindir_crossscripts}/tclConfig.sh from target
-PACKAGE_PREPROCESS_FUNCS += "tcl_package_preprocess"
-tcl_package_preprocess() {
-        sed -i -e "s;${DEBUG_PREFIX_MAP};;g" \
-               -e "s;-L${STAGING_LIBDIR};-L${libdir};g" \
-               -e "s;${STAGING_INCDIR};${includedir};g" \
-               -e "s;--sysroot=${RECIPE_SYSROOT};;g" \
-               ${PKGD}${libdir}/tclConfig.sh
-
-        rm -f ${PKGD}${bindir_crossscripts}/tclConfig.sh
-}