strace: update to 5.8 (fix build against v5.8 uapi headers)

Updating strace to the 5.8 release. The signficant change in this
release is fixes to build against the v5.8 kernel.

Noteworthy changes from the strace site:

 - Changes in behaviour

    - Modified %process class to contain system calls associated with
      process lifecycle (creation, exec, termination):
      kill, tkill, tgkill, pidfd_send_signal and rt_sigqueueinfo are added,
      arch_prctl and unshare are removed.

 - Improvements
    - Implemented decoding of faccessat2 syscall.
    - Implemented decoding of LOOP_CONFIGURE ioctl command.
    - Updated decoding of io_uring_setup syscall to match Linux 5.8.
    - Updated lists of AUDIT_*, BPF_*, CAP_*, ETH_*, INET_DIAG_*, IORING_*,
      KEYCTL_*, KVM_*, LOOP_*, NDA_*, RTC_*, TCA_*, STATX_*, and *_MAGIC
      constants.
    - Updated lists of ioctl commands from Linux 5.8.

 - Bug fixes

    - Added statx syscall to %fstat trace class.

(From OE-Core rev: d656936ec7fbd4c2748a8f2239b6c09e5b9216d9)

Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/meta/recipes-devtools/strace/strace_5.8.bb b/meta/recipes-devtools/strace/strace_5.8.bb
new file mode 100644
index 0000000000..70d5940f60
--- /dev/null
+++ b/meta/recipes-devtools/strace/strace_5.8.bb
@@ -0,0 +1,55 @@
+SUMMARY = "System call tracing tool"
+HOMEPAGE = "http://strace.io"
+SECTION = "console/utils"
+LICENSE = "LGPL-2.1+ & GPL-2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c756d9d5dabc27663df64f0bf492166c"
+
+SRC_URI = "https://strace.io/files/${PV}/strace-${PV}.tar.xz \
+           file://disable-git-version-gen.patch \
+           file://update-gawk-paths.patch \
+           file://Makefile-ptest.patch \
+           file://run-ptest \
+           file://mips-SIGEMT.patch \
+           file://0001-caps-abbrev.awk-fix-gawk-s-path.patch \
+           file://ptest-spacesave.patch \
+           file://uintptr_t.patch \
+           file://0001-strace-fix-reproducibilty-issues.patch \
+           "
+SRC_URI[sha256sum] = "df4a669f7fff9cc302784085bd4b72fab216a426a3f72c892b28a537b71e7aa9"
+
+inherit autotools ptest
+
+PACKAGECONFIG_class-target ??= "\
+    ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} \
+"
+
+PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,bluez5"
+PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
+
+EXTRA_OECONF += "--enable-mpers=no --disable-gcc-Werror"
+
+CFLAGS_append_libc-musl = " -Dsigcontext_struct=sigcontext"
+
+TESTDIR = "tests"
+PTEST_BUILD_HOST_PATTERN = "^(DEB_CHANGELOGTIME|RPM_CHANGELOGTIME|WARN_CFLAGS_FOR_BUILD|LDFLAGS_FOR_BUILD)"
+
+do_install_append() {
+        # We don't ship strace-graph here because it needs perl
+        rm ${D}${bindir}/strace-graph
+}
+
+do_compile_ptest() {
+        oe_runmake -C ${TESTDIR} buildtest-TESTS
+}
+
+do_install_ptest() {
+        oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
+        install -m 755 ${S}/test-driver ${D}${PTEST_PATH}
+        install -m 644 ${B}/config.h ${D}${PTEST_PATH}
+        sed -i -e '/^src/s/strace.*[1-9]/ptest/' ${D}/${PTEST_PATH}/${TESTDIR}/Makefile
+}
+
+RDEPENDS_${PN}-ptest += "make coreutils grep gawk sed"
+
+BBCLASSEXTEND = "native"
+TOOLCHAIN = "gcc"