diff options
author | Alistair Francis <alistair.francis@wdc.com> | 2020-02-13 15:25:28 -0800 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2020-02-15 10:26:42 +0000 |
commit | 24b24a5450f07df83017b3638fbb8d1073b97978 (patch) | |
tree | f0aa0d6cafe23ebd029867540ce484122a16a767 /meta/recipes-devtools/strace/strace_5.5.bb | |
parent | fab2591a3cddfe6ab7e829331e39dcdb0ceb3e24 (diff) | |
download | poky-24b24a5450f07df83017b3638fbb8d1073b97978.tar.gz |
strace: Update to 5.5
Update strace to 5.5. This includes a small change in the license file
to change the date to 2020.
(From OE-Core rev: 3e1e8d24ce122ddb5897418d1bae123051e1f450)
Signed-off-by: Alistair Francis <alistair.francis@wdc.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-devtools/strace/strace_5.5.bb')
-rw-r--r-- | meta/recipes-devtools/strace/strace_5.5.bb | 55 |
1 files changed, 55 insertions, 0 deletions
diff --git a/meta/recipes-devtools/strace/strace_5.5.bb b/meta/recipes-devtools/strace/strace_5.5.bb new file mode 100644 index 0000000000..6e7d63949d --- /dev/null +++ b/meta/recipes-devtools/strace/strace_5.5.bb | |||
@@ -0,0 +1,55 @@ | |||
1 | SUMMARY = "System call tracing tool" | ||
2 | HOMEPAGE = "http://strace.io" | ||
3 | SECTION = "console/utils" | ||
4 | LICENSE = "LGPL-2.1+ & GPL-2+" | ||
5 | LIC_FILES_CHKSUM = "file://COPYING;md5=c756d9d5dabc27663df64f0bf492166c" | ||
6 | |||
7 | SRC_URI = "https://strace.io/files/${PV}/strace-${PV}.tar.xz \ | ||
8 | file://disable-git-version-gen.patch \ | ||
9 | file://update-gawk-paths.patch \ | ||
10 | file://Makefile-ptest.patch \ | ||
11 | file://run-ptest \ | ||
12 | file://mips-SIGEMT.patch \ | ||
13 | file://0001-caps-abbrev.awk-fix-gawk-s-path.patch \ | ||
14 | file://ptest-spacesave.patch \ | ||
15 | file://uintptr_t.patch \ | ||
16 | " | ||
17 | SRC_URI[md5sum] = "dbce2e84632b39a4ed86b9fc60447af9" | ||
18 | SRC_URI[sha256sum] = "9f58958c8e59ea62293d907d10572e352b582bd7948ed21aa28ebb47e5bf30ff" | ||
19 | |||
20 | inherit autotools ptest | ||
21 | |||
22 | PACKAGECONFIG_class-target ??= "\ | ||
23 | ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} \ | ||
24 | " | ||
25 | |||
26 | PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,bluez5" | ||
27 | PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind" | ||
28 | |||
29 | EXTRA_OECONF += "--enable-mpers=no" | ||
30 | |||
31 | CFLAGS_append_libc-musl = " -Dsigcontext_struct=sigcontext" | ||
32 | |||
33 | TESTDIR = "tests" | ||
34 | PTEST_BUILD_HOST_PATTERN = "^(DEB_CHANGELOGTIME|RPM_CHANGELOGTIME|WARN_CFLAGS_FOR_BUILD|LDFLAGS_FOR_BUILD)" | ||
35 | |||
36 | do_install_append() { | ||
37 | # We don't ship strace-graph here because it needs perl | ||
38 | rm ${D}${bindir}/strace-graph | ||
39 | } | ||
40 | |||
41 | do_compile_ptest() { | ||
42 | oe_runmake -C ${TESTDIR} buildtest-TESTS | ||
43 | } | ||
44 | |||
45 | do_install_ptest() { | ||
46 | oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR} | ||
47 | install -m 755 ${S}/test-driver ${D}${PTEST_PATH} | ||
48 | install -m 644 ${B}/config.h ${D}${PTEST_PATH} | ||
49 | sed -i -e '/^src/s/strace.*[1-9]/ptest/' ${D}/${PTEST_PATH}/${TESTDIR}/Makefile | ||
50 | } | ||
51 | |||
52 | RDEPENDS_${PN}-ptest += "make coreutils grep gawk sed" | ||
53 | |||
54 | BBCLASSEXTEND = "native" | ||
55 | TOOLCHAIN = "gcc" | ||