diff options
author | Tudor Florea <tudor.florea@enea.com> | 2015-10-09 22:59:03 +0200 |
---|---|---|
committer | Tudor Florea <tudor.florea@enea.com> | 2015-10-09 22:59:03 +0200 |
commit | 972dcfcdbfe75dcfeb777150c136576cf1a71e99 (patch) | |
tree | 97a61cd7e293d7ae9d56ef7ed0f81253365bb026 /meta/recipes-devtools/perl/perl_5.20.0.bb | |
download | poky-972dcfcdbfe75dcfeb777150c136576cf1a71e99.tar.gz |
initial commit for Enea Linux 5.0 arm
Signed-off-by: Tudor Florea <tudor.florea@enea.com>
Diffstat (limited to 'meta/recipes-devtools/perl/perl_5.20.0.bb')
-rw-r--r-- | meta/recipes-devtools/perl/perl_5.20.0.bb | 365 |
1 files changed, 365 insertions, 0 deletions
diff --git a/meta/recipes-devtools/perl/perl_5.20.0.bb b/meta/recipes-devtools/perl/perl_5.20.0.bb new file mode 100644 index 0000000000..bc7866b61f --- /dev/null +++ b/meta/recipes-devtools/perl/perl_5.20.0.bb | |||
@@ -0,0 +1,365 @@ | |||
1 | SUMMARY = "Perl scripting language" | ||
2 | HOMEPAGE = "http://www.perl.org/" | ||
3 | SECTION = "devel" | ||
4 | LICENSE = "Artistic-1.0 | GPL-1.0" | ||
5 | LIC_FILES_CHKSUM = "file://Copying;md5=5b122a36d0f6dc55279a0ebc69f3c60b \ | ||
6 | file://Artistic;md5=2e6fd2475335af892494fe1f7327baf3" | ||
7 | # We need gnugrep (for -I) | ||
8 | DEPENDS = "virtual/db grep-native" | ||
9 | DEPENDS += "gdbm zlib" | ||
10 | PR = "r1" | ||
11 | |||
12 | # 5.10.1 has Module::Build built-in | ||
13 | PROVIDES += "libmodule-build-perl" | ||
14 | |||
15 | SRC_URI = "http://www.cpan.org/src/5.0/perl-${PV}.tar.gz \ | ||
16 | " | ||
17 | |||
18 | # Pick up patches from debian | ||
19 | # http://ftp.de.debian.org/debian/pool/main/p/perl/perl_5.20.0-1.debian.tar.xz | ||
20 | SRC_URI += " \ | ||
21 | file://debian/cpan_definstalldirs.diff \ | ||
22 | file://debian/db_file_ver.diff \ | ||
23 | file://debian/doc_info.diff \ | ||
24 | file://debian/enc2xs_inc.diff \ | ||
25 | file://debian/errno_ver.diff \ | ||
26 | file://debian/libperl_embed_doc.diff \ | ||
27 | file://debian/fixes/respect_umask.diff \ | ||
28 | file://debian/writable_site_dirs.diff \ | ||
29 | file://debian/extutils_set_libperl_path.diff \ | ||
30 | file://debian/no_packlist_perllocal.diff \ | ||
31 | file://debian/prefix_changes.diff \ | ||
32 | file://debian/instmodsh_doc.diff \ | ||
33 | file://debian/ld_run_path.diff \ | ||
34 | file://debian/libnet_config_path.diff \ | ||
35 | file://debian/mod_paths.diff \ | ||
36 | file://debian/module_build_man_extensions.diff \ | ||
37 | file://debian/prune_libs.diff \ | ||
38 | file://debian/fixes/net_smtp_docs.diff \ | ||
39 | file://debian/perlivp.diff \ | ||
40 | file://debian/squelch-locale-warnings.diff \ | ||
41 | file://debian/skip-upstream-git-tests.diff \ | ||
42 | file://debian/skip-kfreebsd-crash.diff \ | ||
43 | file://debian/fixes/document_makemaker_ccflags.diff \ | ||
44 | file://debian/find_html2text.diff \ | ||
45 | file://debian/hurd_test_skip_stack.diff \ | ||
46 | file://debian/perl5db-x-terminal-emulator.patch \ | ||
47 | file://debian/cpan-missing-site-dirs.diff \ | ||
48 | file://debian/fixes/memoize_storable_nstore.diff \ | ||
49 | file://debian/regen-skip.diff \ | ||
50 | " | ||
51 | |||
52 | SRC_URI += " \ | ||
53 | file://Makefile.patch \ | ||
54 | file://Makefile.SH.patch \ | ||
55 | file://installperl.patch \ | ||
56 | file://perl-dynloader.patch \ | ||
57 | file://perl-moreconfig.patch \ | ||
58 | file://letgcc-find-errno.patch \ | ||
59 | file://generate-sh.patch \ | ||
60 | file://native-perlinc.patch \ | ||
61 | file://perl-enable-gdbm.patch \ | ||
62 | file://cross-generate_uudmap.patch \ | ||
63 | file://fix_bad_rpath.patch \ | ||
64 | file://perl-archlib-exp.patch \ | ||
65 | file://dynaloaderhack.patch \ | ||
66 | file://fix-FF_MORE-crash.patch \ | ||
67 | \ | ||
68 | \ | ||
69 | file://config.sh \ | ||
70 | file://config.sh-32 \ | ||
71 | file://config.sh-32-le \ | ||
72 | file://config.sh-32-be \ | ||
73 | file://config.sh-64 \ | ||
74 | file://config.sh-64-le \ | ||
75 | file://config.sh-64-be \ | ||
76 | file://perl-5.14.3-fix-CVE-2010-4777.patch \ | ||
77 | file://0001-Makefile.SH-fix-do_install-failed.patch \ | ||
78 | file://make_ext.pl-fix-regenerate-makefile-failed-while-cc-.patch \ | ||
79 | " | ||
80 | |||
81 | # Fix test case issues | ||
82 | SRC_URI_append_class-target = " \ | ||
83 | file://test/dist-threads-t-join.t-adjust-ps-option.patch \ | ||
84 | file://test/ext-DynaLoader-t-DynaLoader.t-fix-calling-dl_findfil.patch \ | ||
85 | " | ||
86 | |||
87 | SRC_URI[md5sum] = "406ec049ebe3afcc80d9c76ec78ca4f8" | ||
88 | SRC_URI[sha256sum] = "4e8c28ad6ecc89902f9cb2e76f2815bb1a8287ded278e15f7a36ca45f8bbcd02" | ||
89 | |||
90 | inherit perlnative siteinfo | ||
91 | |||
92 | # Where to find the native perl | ||
93 | HOSTPERL = "${STAGING_BINDIR_NATIVE}/perl-native/perl${PV}" | ||
94 | |||
95 | # Where to find .so files - use the -native versions not those from the target build | ||
96 | export PERLHOSTLIB = "${STAGING_LIBDIR_NATIVE}/perl-native/perl/${PV}/" | ||
97 | |||
98 | # Where to find perl @INC/#include files | ||
99 | # - use the -native versions not those from the target build | ||
100 | export PERL_LIB = "${STAGING_LIBDIR_NATIVE}/perl-native/perl/${PV}/" | ||
101 | export PERL_ARCHLIB = "${STAGING_LIBDIR_NATIVE}/perl-native/perl/${PV}/" | ||
102 | |||
103 | # LDFLAGS for shared libraries | ||
104 | export LDDLFLAGS = "${LDFLAGS} -shared" | ||
105 | |||
106 | LDFLAGS_append = " -fstack-protector" | ||
107 | |||
108 | # We're almost Debian, aren't we? | ||
109 | CFLAGS += "-DDEBIAN" | ||
110 | |||
111 | do_nolargefile() { | ||
112 | sed -i -e "s,\(uselargefiles=\)'define',\1'undef',g" \ | ||
113 | -e "s,\(d_readdir64_r=\)'define',\1'undef',g" \ | ||
114 | -e "s,\(readdir64_r_proto=\)'\w+',\1'0',g" \ | ||
115 | -e "/ccflags_uselargefiles/d" \ | ||
116 | -e "s/-Duselargefiles//" \ | ||
117 | -e "s/-D_FILE_OFFSET_BITS=64//" \ | ||
118 | -e "s/-D_LARGEFILE_SOURCE//" \ | ||
119 | ${S}/Cross/config.sh-${TARGET_ARCH}-${TARGET_OS} | ||
120 | } | ||
121 | |||
122 | do_configure() { | ||
123 | # Make hostperl in build directory be the native perl | ||
124 | ln -sf ${HOSTPERL} hostperl | ||
125 | |||
126 | if [ -n "${CONFIGURESTAMPFILE}" -a -e "${CONFIGURESTAMPFILE}" ]; then | ||
127 | if [ "`cat ${CONFIGURESTAMPFILE}`" != "${BB_TASKHASH}" -a -e Makefile ]; then | ||
128 | ${MAKE} clean | ||
129 | fi | ||
130 | find ${S} -name *.so -delete | ||
131 | fi | ||
132 | if [ -n "${CONFIGURESTAMPFILE}" ]; then | ||
133 | echo ${BB_TASKHASH} > ${CONFIGURESTAMPFILE} | ||
134 | fi | ||
135 | |||
136 | # Do our work in the cross subdir | ||
137 | cd Cross | ||
138 | |||
139 | # Generate configuration | ||
140 | rm -f config.sh-${TARGET_ARCH}-${TARGET_OS} | ||
141 | for i in ${WORKDIR}/config.sh \ | ||
142 | ${WORKDIR}/config.sh-${SITEINFO_BITS} \ | ||
143 | ${WORKDIR}/config.sh-${SITEINFO_BITS}-${SITEINFO_ENDIANNESS}; do | ||
144 | cat $i >> config.sh-${TARGET_ARCH}-${TARGET_OS} | ||
145 | done | ||
146 | |||
147 | # Fixups for uclibc | ||
148 | if [ "${TARGET_OS}" = "linux-uclibc" -o "${TARGET_OS}" = "linux-uclibceabi" ]; then | ||
149 | sed -i -e "s,\(d_crypt_r=\)'define',\1'undef',g" \ | ||
150 | -e "s,\(d_futimes=\)'define',\1'undef',g" \ | ||
151 | -e "s,\(crypt_r_proto=\)'\w+',\1'0',g" \ | ||
152 | -e "s,\(d_getnetbyname_r=\)'define',\1'undef',g" \ | ||
153 | -e "s,\(getnetbyname_r_proto=\)'\w+',\1'0',g" \ | ||
154 | -e "s,\(d_getnetbyaddr_r=\)'define',\1'undef',g" \ | ||
155 | -e "s,\(getnetbyaddr_r_proto=\)'\w+',\1'0',g" \ | ||
156 | -e "s,\(d_getnetent_r=\)'define',\1'undef',g" \ | ||
157 | -e "s,\(getnetent_r_proto=\)'\w+',\1'0',g" \ | ||
158 | -e "s,\(d_sockatmark=\)'define',\1'undef',g" \ | ||
159 | -e "s,\(d_sockatmarkproto=\)'\w+',\1'0',g" \ | ||
160 | -e "s,\(d_eaccess=\)'define',\1'undef',g" \ | ||
161 | -e "s,\(d_stdio_ptr_lval=\)'define',\1'undef',g" \ | ||
162 | -e "s,\(d_stdio_ptr_lval_sets_cnt=\)'define',\1'undef',g" \ | ||
163 | -e "s,\(d_stdiobase=\)'define',\1'undef',g" \ | ||
164 | -e "s,\(d_stdstdio=\)'define',\1'undef',g" \ | ||
165 | -e "s,-fstack-protector,-fno-stack-protector,g" \ | ||
166 | config.sh-${TARGET_ARCH}-${TARGET_OS} | ||
167 | fi | ||
168 | |||
169 | ${@bb.utils.contains('DISTRO_FEATURES', 'largefile', '', 'do_nolargefile', d)} | ||
170 | |||
171 | # Update some paths in the configuration | ||
172 | sed -i -e 's,@ARCH@-thread-multi,,g' \ | ||
173 | -e 's,@ARCH@,${TARGET_ARCH}-${TARGET_OS},g' \ | ||
174 | -e 's,@STAGINGDIR@,${STAGING_DIR_HOST},g' \ | ||
175 | -e "s,@INCLUDEDIR@,${STAGING_INCDIR},g" \ | ||
176 | -e "s,@LIBDIR@,${libdir},g" \ | ||
177 | -e "s,@BASELIBDIR@,${base_libdir},g" \ | ||
178 | -e "s,@EXECPREFIX@,${exec_prefix},g" \ | ||
179 | -e 's,@USRBIN@,${bindir},g' \ | ||
180 | config.sh-${TARGET_ARCH}-${TARGET_OS} | ||
181 | |||
182 | case "${TARGET_ARCH}" in | ||
183 | x86_64 | powerpc | s390) | ||
184 | sed -i -e "s,\(need_va_copy=\)'undef',\1'define',g" \ | ||
185 | config.sh-${TARGET_ARCH}-${TARGET_OS} | ||
186 | ;; | ||
187 | arm) | ||
188 | sed -i -e "s,\(d_u32align=\)'undef',\1'define',g" \ | ||
189 | config.sh-${TARGET_ARCH}-${TARGET_OS} | ||
190 | ;; | ||
191 | esac | ||
192 | # These are strewn all over the source tree | ||
193 | for foo in `grep -I --exclude="*.patch" --exclude="*.diff" --exclude="*.pod" --exclude="README*" -m1 "/usr/include/.*\.h" ${S}/* -r -l` ${S}/utils/h2xs.PL ; do | ||
194 | echo Fixing: $foo | ||
195 | sed -e 's|\([ "^'\''I]\+\)/usr/include/|\1${STAGING_INCDIR}/|g' -i $foo | ||
196 | done | ||
197 | |||
198 | rm -f config | ||
199 | echo "ARCH = ${TARGET_ARCH}" > config | ||
200 | echo "OS = ${TARGET_OS}" >> config | ||
201 | } | ||
202 | |||
203 | do_compile() { | ||
204 | # Fix to avoid recursive substitution of path | ||
205 | sed -i -e "s|\([ \"\']\+\)/usr/include|\1${STAGING_INCDIR}|g" ext/Errno/Errno_pm.PL | ||
206 | sed -i -e "s|\([ \"\']\+\)/usr/include|\1${STAGING_INCDIR}|g" cpan/Compress-Raw-Zlib/config.in | ||
207 | sed -i -e 's|/usr/lib|""|g' cpan/Compress-Raw-Zlib/config.in | ||
208 | sed -i -e 's|(@libpath, ".*"|(@libpath, "${STAGING_LIBDIR}"|g' cpan/ExtUtils-MakeMaker/lib/ExtUtils/Liblist/Kid.pm | ||
209 | |||
210 | cd Cross | ||
211 | oe_runmake perl LD="${CCLD}" | ||
212 | } | ||
213 | |||
214 | do_install() { | ||
215 | #export hostperl="${STAGING_BINDIR_NATIVE}/perl-native/perl${PV}" | ||
216 | oe_runmake install DESTDIR=${D} | ||
217 | # Add perl pointing at current version | ||
218 | ln -sf perl${PV} ${D}${bindir}/perl | ||
219 | |||
220 | ln -sf perl ${D}/${libdir}/perl5 | ||
221 | |||
222 | # Remove unwanted file and empty directories | ||
223 | rm -f ${D}/${libdir}/perl/${PV}/.packlist | ||
224 | rmdir ${D}/${libdir}/perl/site_perl/${PV} | ||
225 | rmdir ${D}/${libdir}/perl/site_perl | ||
226 | |||
227 | # Fix up shared library | ||
228 | mv ${D}/${libdir}/perl/${PV}/CORE/libperl.so ${D}/${libdir}/libperl.so.${PV} | ||
229 | ln -sf libperl.so.${PV} ${D}/${libdir}/libperl.so.5 | ||
230 | ln -sf ../../../libperl.so.${PV} ${D}/${libdir}/perl/${PV}/CORE/libperl.so | ||
231 | |||
232 | # target config, used by cpan.bbclass to extract version information | ||
233 | install config.sh ${D}${libdir}/perl | ||
234 | |||
235 | ln -s Config_heavy.pl ${D}${libdir}/perl/${PV}/Config_heavy-target.pl | ||
236 | } | ||
237 | |||
238 | do_install_append_class-nativesdk () { | ||
239 | create_wrapper ${D}${bindir}/perl \ | ||
240 | PERL5LIB='$PERL5LIB:$OECORE_NATIVE_SYSROOT/${libdir_nativesdk}/perl:$OECORE_NATIVE_SYSROOT/${libdir_nativesdk}/perl/${PV}:$OECORE_NATIVE_SYSROOT/${libdir_nativesdk}/perl/site_perl/${PV}:$OECORE_NATIVE_SYSROOT/${libdir_nativesdk}/perl/vendor_perl/${PV}' | ||
241 | } | ||
242 | |||
243 | PACKAGE_PREPROCESS_FUNCS += "perl_package_preprocess" | ||
244 | |||
245 | perl_package_preprocess () { | ||
246 | # Fix up installed configuration | ||
247 | sed -i -e "s,${D},,g" \ | ||
248 | -e "s,--sysroot=${STAGING_DIR_HOST},,g" \ | ||
249 | -e "s,-isystem${STAGING_INCDIR} ,,g" \ | ||
250 | -e "s,${STAGING_LIBDIR},${libdir},g" \ | ||
251 | -e "s,${STAGING_BINDIR},${bindir},g" \ | ||
252 | -e "s,${STAGING_INCDIR},${includedir},g" \ | ||
253 | -e "s,${STAGING_BINDIR_NATIVE}/perl-native/,${bindir}/,g" \ | ||
254 | -e "s,${STAGING_BINDIR_NATIVE}/,,g" \ | ||
255 | -e "s,${STAGING_BINDIR_TOOLCHAIN}/${TARGET_PREFIX},${bindir},g" \ | ||
256 | ${PKGD}${bindir}/h2xs \ | ||
257 | ${PKGD}${bindir}/h2ph \ | ||
258 | ${PKGD}${bindir}/pod2man \ | ||
259 | ${PKGD}${bindir}/pod2text \ | ||
260 | ${PKGD}${bindir}/pod2usage \ | ||
261 | ${PKGD}${bindir}/podchecker \ | ||
262 | ${PKGD}${bindir}/podselect \ | ||
263 | ${PKGD}${libdir}/perl/${PV}/CORE/config.h \ | ||
264 | ${PKGD}${libdir}/perl/${PV}/CORE/perl.h \ | ||
265 | ${PKGD}${libdir}/perl/${PV}/CORE/pp.h \ | ||
266 | ${PKGD}${libdir}/perl/${PV}/Config.pm \ | ||
267 | ${PKGD}${libdir}/perl/${PV}/Config.pod \ | ||
268 | ${PKGD}${libdir}/perl/${PV}/Config_heavy.pl \ | ||
269 | ${PKGD}${libdir}/perl/${PV}/ExtUtils/Liblist/Kid.pm \ | ||
270 | ${PKGD}${libdir}/perl/${PV}/FileCache.pm \ | ||
271 | ${PKGD}${libdir}/perl/${PV}/pod/*.pod \ | ||
272 | ${PKGD}${libdir}/perl/config.sh | ||
273 | } | ||
274 | |||
275 | PACKAGES = "perl-dbg perl perl-misc perl-dev perl-pod perl-doc perl-lib \ | ||
276 | perl-module-cpan perl-module-cpanplus perl-module-unicore" | ||
277 | FILES_${PN} = "${bindir}/perl ${bindir}/perl${PV} \ | ||
278 | ${libdir}/perl/${PV}/Config.pm \ | ||
279 | ${libdir}/perl/${PV}/strict.pm \ | ||
280 | ${libdir}/perl/${PV}/warnings.pm \ | ||
281 | ${libdir}/perl/${PV}/warnings \ | ||
282 | ${libdir}/perl/${PV}/vars.pm \ | ||
283 | " | ||
284 | FILES_${PN}_append_class-nativesdk = " ${bindir}/perl.real" | ||
285 | RPROVIDES_${PN} += "perl-module-strict perl-module-vars perl-module-config perl-module-warnings \ | ||
286 | perl-module-warnings-register" | ||
287 | FILES_${PN}-dev = "${libdir}/perl/${PV}/CORE" | ||
288 | FILES_${PN}-lib = "${libdir}/libperl.so* \ | ||
289 | ${libdir}/perl5 \ | ||
290 | ${libdir}/perl/config.sh \ | ||
291 | ${libdir}/perl/${PV}/Config_heavy.pl \ | ||
292 | ${libdir}/perl/${PV}/Config_heavy-target.pl" | ||
293 | FILES_${PN}-pod = "${libdir}/perl/${PV}/pod \ | ||
294 | ${libdir}/perl/${PV}/*.pod \ | ||
295 | ${libdir}/perl/${PV}/*/*.pod \ | ||
296 | ${libdir}/perl/${PV}/*/*/*.pod " | ||
297 | FILES_perl-misc = "${bindir}/*" | ||
298 | FILES_${PN}-dbg += "${libdir}/perl/${PV}/auto/*/.debug \ | ||
299 | ${libdir}/perl/${PV}/auto/*/*/.debug \ | ||
300 | ${libdir}/perl/${PV}/auto/*/*/*/.debug \ | ||
301 | ${libdir}/perl/${PV}/CORE/.debug \ | ||
302 | ${libdir}/perl/${PV}/*/.debug \ | ||
303 | ${libdir}/perl/${PV}/*/*/.debug \ | ||
304 | ${libdir}/perl/${PV}/*/*/*/.debug " | ||
305 | FILES_${PN}-doc = "${libdir}/perl/${PV}/*/*.txt \ | ||
306 | ${libdir}/perl/${PV}/*/*/*.txt \ | ||
307 | ${libdir}/perl/${PV}/auto/XS/Typemap \ | ||
308 | ${libdir}/perl/${PV}/B/assemble \ | ||
309 | ${libdir}/perl/${PV}/B/cc_harness \ | ||
310 | ${libdir}/perl/${PV}/B/disassemble \ | ||
311 | ${libdir}/perl/${PV}/B/makeliblinks \ | ||
312 | ${libdir}/perl/${PV}/CGI/eg \ | ||
313 | ${libdir}/perl/${PV}/CPAN/PAUSE2003.pub \ | ||
314 | ${libdir}/perl/${PV}/CPAN/SIGNATURE \ | ||
315 | ${libdir}/perl/${PV}/CPANPLUS/Shell/Default/Plugins/HOWTO.pod \ | ||
316 | ${libdir}/perl/${PV}/Encode/encode.h \ | ||
317 | ${libdir}/perl/${PV}/ExtUtils/MANIFEST.SKIP \ | ||
318 | ${libdir}/perl/${PV}/ExtUtils/NOTES \ | ||
319 | ${libdir}/perl/${PV}/ExtUtils/PATCHING \ | ||
320 | ${libdir}/perl/${PV}/ExtUtils/typemap \ | ||
321 | ${libdir}/perl/${PV}/ExtUtils/xsubpp \ | ||
322 | ${libdir}/perl/${PV}/ExtUtils/Changes_EU-Install \ | ||
323 | ${libdir}/perl/${PV}/Net/*.eg \ | ||
324 | ${libdir}/perl/${PV}/unicore/mktables \ | ||
325 | ${libdir}/perl/${PV}/unicore/mktables.lst \ | ||
326 | ${libdir}/perl/${PV}/unicore/version " | ||
327 | |||
328 | FILES_perl-module-cpan += "${libdir}/perl/${PV}/CPAN \ | ||
329 | ${libdir}/perl/${PV}/CPAN.pm" | ||
330 | FILES_perl-module-cpanplus += "${libdir}/perl/${PV}/CPANPLUS \ | ||
331 | ${libdir}/perl/${PV}/CPANPLUS.pm" | ||
332 | FILES_perl-module-unicore += "${libdir}/perl/${PV}/unicore" | ||
333 | |||
334 | # Create a perl-modules package recommending all the other perl | ||
335 | # packages (actually the non modules packages and not created too) | ||
336 | ALLOW_EMPTY_perl-modules = "1" | ||
337 | PACKAGES_append = " perl-modules " | ||
338 | |||
339 | python populate_packages_prepend () { | ||
340 | libdir = d.expand('${libdir}/perl/${PV}') | ||
341 | do_split_packages(d, libdir, 'auto/([^.]*)/[^/]*\.(so|ld|ix|al)', 'perl-module-%s', 'perl module %s', recursive=True, match_path=True, prepend=False) | ||
342 | do_split_packages(d, libdir, 'Module/([^\/]*)\.pm', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True, prepend=False) | ||
343 | do_split_packages(d, libdir, 'Module/([^\/]*)/.*', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True, prepend=False) | ||
344 | do_split_packages(d, libdir, '(^(?!(CPAN\/|CPANPLUS\/|Module\/|unicore\/|auto\/)[^\/]).*)\.(pm|pl|e2x)', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True, prepend=False) | ||
345 | |||
346 | # perl-modules should recommend every perl module, and only the | ||
347 | # modules. Don't attempt to use the result of do_split_packages() as some | ||
348 | # modules are manually split (eg. perl-module-unicore). | ||
349 | packages = filter(lambda p: 'perl-module-' in p, d.getVar('PACKAGES', True).split()) | ||
350 | d.setVar("RRECOMMENDS_${PN}-modules", ' '.join(packages)) | ||
351 | } | ||
352 | |||
353 | PACKAGES_DYNAMIC += "^perl-module-.*" | ||
354 | PACKAGES_DYNAMIC_class-nativesdk += "^nativesdk-perl-module-.*" | ||
355 | |||
356 | RPROVIDES_perl-lib = "perl-lib" | ||
357 | |||
358 | require perl-rdepends_${PV}.inc | ||
359 | require perl-rprovides.inc | ||
360 | require perl-rprovides_${PV}.inc | ||
361 | require perl-ptest.inc | ||
362 | |||
363 | SSTATE_SCAN_FILES += "*.pm *.pod *.h *.pl *.sh" | ||
364 | |||
365 | BBCLASSEXTEND = "nativesdk" | ||