perl, perl-native, perl-ptest: upgrade from 5.14.3 to 5.20.0

Changed:

- The Copying has no change, except the company address.

- pick patches from debian
  http://ftp.de.debian.org/debian/pool/main/p/perl/perl_5.20.0-1.debian.tar.xz
  - Not used by oe:
    deprecate-with-apt.diff
    patchlevel.diff
    fakeroot.diff

- Create/Update perl-rdepends_${PV}.inc by the hardcode script;

- Update config.sh by:
  1) Copy the Perl 5.20.0 source code onto your TARGET machine
    linux qemuarm 3.14.5-yocto-standard from OE-Core rev:
    f506d0660c9949485268a92724ac770b5457b0ca
  2) Execute sh Configure as normal and configure as required,
     do not "make";
  3) Compare with the old config.sh files, and update;

- perl-ptest.inc
  1) Copy the souce code to ptest since almost 112 test cases
     failed with the reason that no souce code found;
  2) Add two patches to fix test case issue;

- perl-native
  Reference perl (5.20.0-1) in debian to update perl shared library headers
  https://packages.debian.org/experimental/i386/perl/filelist

Obsolete:

- 09_fix_installperl.patch
  The dead code was removed from installperl
  http://perl5.git.perl.org/perl.git/commit/236818e0b9d9fe874831086b4d0b94dc6f245dfd

- perl-build-in-t-dir.patch
  The upstream has fix it. The issue description:
  Perl cannot cross build in a path containing a directory that has the
  name of "t".  As an example, you can make the perl build fail with
  "mkdir -p /tmp/build/t", go to the directory, unpack the sources,
  configure and cross build.

- 0001-Fix-misparsing-of-maketext-strings.patch
  as they are part of the upstream code now:
  http://perl5.git.perl.org/perl.git/commit/1735f6f53ca19f99c6e9e39496c486af323ba6a8

- 0001-Prevent-premature-hsplit-calls-and-only-trigger-REHA.patch
  the hash function changed:
  http://perl5.git.perl.org/perl.git/commit/7dc8663964c66a698d31bbdc8e8abed69bddeec3

(From OE-Core rev: c7ac82415efc42ff7a93c6df163f88f2dde00d26)

Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 0 insertions, 124 deletions

diff --git a/meta/recipes-devtools/perl/perl-native_5.14.3.bb b/meta/recipes-devtools/perl/perl-native_5.14.3.bb
deleted file mode 100644
index c38be41d49..0000000000
--- a/meta/recipes-devtools/perl/perl-native_5.14.3.bb
+++ /dev/null
@@ -1,124 +0,0 @@
-SUMMARY = "Perl scripting language"
-HOMEPAGE = "http://www.perl.org/"
-SECTION = "libs"
-LICENSE = "Artistic-1.0 | GPL-1.0"
-
-LIC_FILES_CHKSUM = "file://Copying;md5=2b4c6ffbcfcbdee469f02565f253d81a \
-                    file://Artistic;md5=f921793d03cc6d63ec4b15e9be8fd3f8"
-
-# 5.10.1 has Module::Build built-in
-PROVIDES += "libmodule-build-perl-native"
-
-SRC_URI = "http://www.cpan.org/src/5.0/perl-${PV}.tar.gz \
-           file://Configure-multilib.patch \
-           file://perl-configpm-switch.patch \
-           file://native-nopacklist.patch \
-           file://native-perlinc.patch \
-           file://MM_Unix.pm.patch \
-           file://debian/errno_ver.diff \
-           file://dynaloaderhack.patch \
-           file://perl-build-in-t-dir.patch \
-           file://perl-5.14.3-fix-CVE-2010-4777.patch "
-
-SRC_URI[md5sum] = "f6a3d878c688d111b495c87db56c5be5"
-SRC_URI[sha256sum] = "03638a4f01bc26b81231233671524b4163849a3a9ea5cc2397293080c4ea339f"
-
-S = "${WORKDIR}/perl-${PV}"
-
-inherit native
-
-NATIVE_PACKAGE_PATH_SUFFIX = "/${PN}"
-
-export LD="${CCLD}"
-
-do_configure () {
-        ./Configure \
-                -Dcc="${CC}" \
-                -Dcflags="${CFLAGS}" \
-                -Dldflags="${LDFLAGS}" \
-                -Dcf_by="Open Embedded" \
-                -Dprefix=${prefix} \
-                -Dvendorprefix=${prefix} \
-                -Dvendorprefix=${prefix} \
-                -Dsiteprefix=${prefix} \
-                \
-                -Dbin=${STAGING_BINDIR}/${PN} \
-                -Dprivlib=${STAGING_LIBDIR}/perl/${PV} \
-                -Darchlib=${STAGING_LIBDIR}/perl/${PV} \
-                -Dvendorlib=${STAGING_LIBDIR}/perl/${PV} \
-                -Dvendorarch=${STAGING_LIBDIR}/perl/${PV} \
-                -Dsitelib=${STAGING_LIBDIR}/perl/${PV} \
-                -Dsitearch=${STAGING_LIBDIR}/perl/${PV} \
-                \
-                -Duseshrplib \
-                -Dusethreads \
-                -Duseithreads \
-                -Duselargefiles \
-                -Dnoextensions=ODBM_File \
-                -Ud_dosuid \
-                -Ui_db \
-                -Ui_ndbm \
-                -Ui_gdbm \
-                -Di_shadow \
-                -Di_syslog \
-                -Duseperlio \
-                -Dman3ext=3pm \
-                -Dsed=/bin/sed \
-                -Uafs \
-                -Ud_csh \
-                -Uusesfio \
-                -Uusenm -des
-}
-
-do_install () {
-        oe_runmake 'DESTDIR=${D}' install
-
-        # We need a hostperl link for building perl
-        ln -sf perl${PV} ${D}${bindir}/hostperl
-
-        ln -sf perl ${D}${libdir}/perl5
-
-        install -d ${D}${libdir}/perl/${PV}/CORE \
-                   ${D}${datadir}/perl/${PV}/ExtUtils
-
-        # Save native config 
-        install config.sh ${D}${libdir}/perl
-        install lib/Config.pm ${D}${libdir}/perl/${PV}/
-        install lib/ExtUtils/typemap ${D}${libdir}/perl/${PV}/ExtUtils/
-
-        # perl shared library headers
-        for i in av.h bitcount.h config.h cop.h cv.h dosish.h embed.h embedvar.h \
-                EXTERN.h fakesdio.h fakethr.h form.h gv.h handy.h hv.h INTERN.h \
-                intrpvar.h iperlsys.h keywords.h l1_char_class_tab.h malloc_ctl.h \
-                metaconfig.h mg.h mydtrace.h nostdio.h opcode.h op.h opnames.h \
-                op_reg_common.h overload.h pad.h parser.h patchlevel.h perlapi.h \
-                perl.h perlio.h perliol.h perlsdio.h perlsfio.h perlvars.h \
-                perly.h pp.h pp_proto.h proto.h reentr.h regcharclass.h regcomp.h \
-                regexp.h regnodes.h scope.h sv.h thread.h time64_config.h \
-                time64.h uconfig.h unixish.h utf8.h utfebcdic.h util.h \
-                uudmap.h warnings.h XSUB.h 
-        do
-                install $i ${D}${libdir}/perl/${PV}/CORE
-        done
-
-        create_wrapper ${D}${bindir}/perl PERL5LIB='$PERL5LIB:${STAGING_LIBDIR}/perl/${PV}:${STAGING_LIBDIR}/perl/'
-        create_wrapper ${D}${bindir}/perl${PV} PERL5LIB='$PERL5LIB:${STAGING_LIBDIR}/perl/${PV}:${STAGING_LIBDIR}/perl/'
-}
-
-SYSROOT_PREPROCESS_FUNCS += "perl_sysroot_create_wrapper"
-
-perl_sysroot_create_wrapper () {
-        mkdir -p ${SYSROOT_DESTDIR}${bindir}
-        # Create a wrapper that /usr/bin/env perl will use to get perl-native.
-        # This MUST live in the normal bindir.
-        cat > ${SYSROOT_DESTDIR}${bindir}/../nativeperl << EOF
-#!/bin/sh
-realpath=\`readlink -fn \$0\`
-exec \`dirname \$realpath\`/perl-native/perl "\$@"
-EOF
-        chmod 0755 ${SYSROOT_DESTDIR}${bindir}/../nativeperl
-        cat ${SYSROOT_DESTDIR}${bindir}/../nativeperl
-}
-
-# Fix the path in sstate
-SSTATE_SCAN_FILES += "*.pm *.pod *.h *.pl *.sh"