mtools: upgrade 4.0.41 -> 4.0.42

disable-hardcoded-configs.patch
refreshed for new version.

Changelog:
==========
- Added postcmd attribute in drive description to allow to
  execute "device release" code automatically at end of
  command
- Code cleanup (unneeded functions, initializations, added
  comments to unobvious code, obsolete stuff in Makefile)
- signedness cleanup about directory entries

(From OE-Core rev: 7e7abbe7743f16e0524c9a1d6990fb304f648a56)

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/meta/recipes-devtools/mtools/mtools_4.0.42.bb b/meta/recipes-devtools/mtools/mtools_4.0.42.bb
new file mode 100644
index 0000000000..85d9e451c2
--- /dev/null
+++ b/meta/recipes-devtools/mtools/mtools_4.0.42.bb
@@ -0,0 +1,49 @@
+SUMMARY = "Utilities to access MS-DOS disks without mounting them"
+DESCRIPTION = "Mtools is a collection of utilities to access MS-DOS disks from GNU and Unix without mounting them."
+HOMEPAGE = "http://www.gnu.org/software/mtools/"
+SECTION = "optional"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+DEPENDS += "virtual/libiconv"
+
+RDEPENDS:${PN}:libc-glibc = "glibc-gconv-ibm850"
+RRECOMMENDS:${PN}:libc-glibc = "\
+        glibc-gconv-ibm437 \
+        glibc-gconv-ibm737 \
+        glibc-gconv-ibm775 \
+        glibc-gconv-ibm851 \
+        glibc-gconv-ibm852 \
+        glibc-gconv-ibm855 \
+        glibc-gconv-ibm857 \
+        glibc-gconv-ibm860 \
+        glibc-gconv-ibm861 \
+        glibc-gconv-ibm862 \
+        glibc-gconv-ibm863 \
+        glibc-gconv-ibm865 \
+        glibc-gconv-ibm866 \
+        glibc-gconv-ibm869 \
+        "
+SRC_URI[sha256sum] = "64bfdfde4d82af6b22f3c1c72c3e231cbb618f4c2309cc46f54d16d5502ccf15"
+
+SRC_URI = "${GNU_MIRROR}/mtools/mtools-${PV}.tar.bz2 \
+           file://mtools-makeinfo.patch \
+           file://clang_UNUSED.patch \
+           "
+
+SRC_URI:append:class-native = " file://disable-hardcoded-configs.patch"
+
+inherit autotools texinfo
+
+EXTRA_OECONF = "--without-x"
+
+BBCLASSEXTEND = "native nativesdk"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[libbsd] = "ac_cv_lib_bsd_main=yes,ac_cv_lib_bsd_main=no,libbsd"
+
+do_install:prepend () {
+    # Create bindir to fix parallel installation issues
+    mkdir -p ${D}/${bindir}
+    mkdir -p ${D}/${datadir}
+}