diff options
author | Khem Raj <raj.khem@gmail.com> | 2017-07-27 10:40:11 -0700 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2017-07-31 15:13:32 +0100 |
commit | 5c77067ee9c18e056515a5e83e7282b0035dfb49 (patch) | |
tree | 50508739f29e81b23586480eab22bda43f0e936a /meta/recipes-devtools/llvm/llvm_git.bb | |
parent | e7bb5ae841eabe86763f8e2fe5c92f4c7080420d (diff) | |
download | poky-5c77067ee9c18e056515a5e83e7282b0035dfb49.tar.gz |
llvm: Add recipe for 5.0
Based on recipe from meta-oe and clang recipe from meta-clang
Needed by mesa
Fixes
[YOCTO #11529]
(From OE-Core rev: 8724ef9c53e7804ead9ba0f019369b0e4daada63)
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-devtools/llvm/llvm_git.bb')
-rw-r--r-- | meta/recipes-devtools/llvm/llvm_git.bb | 182 |
1 files changed, 182 insertions, 0 deletions
diff --git a/meta/recipes-devtools/llvm/llvm_git.bb b/meta/recipes-devtools/llvm/llvm_git.bb new file mode 100644 index 0000000000..5dcb508c23 --- /dev/null +++ b/meta/recipes-devtools/llvm/llvm_git.bb | |||
@@ -0,0 +1,182 @@ | |||
1 | # Copyright (C) 2017 Khem Raj <raj.khem@gmail.com> | ||
2 | # Released under the MIT license (see COPYING.MIT for the terms) | ||
3 | |||
4 | DESCRIPTION = "The LLVM Compiler Infrastructure" | ||
5 | HOMEPAGE = "http://llvm.org" | ||
6 | LICENSE = "NCSA" | ||
7 | SECTION = "devel" | ||
8 | |||
9 | LIC_FILES_CHKSUM = "file://LICENSE.TXT;md5=e825e017edc35cfd58e26116e5251771" | ||
10 | |||
11 | DEPENDS = "libffi libxml2-native zlib ninja-native llvm-native" | ||
12 | |||
13 | DEPENDS_remove_toolchain-clang = "llvm-native" | ||
14 | |||
15 | RDEPENDS_${PN}_append_class-target = " ncurses-terminfo" | ||
16 | |||
17 | inherit perlnative pythonnative cmake pkgconfig | ||
18 | |||
19 | PROVIDES += "llvm${PV}" | ||
20 | |||
21 | LLVM_RELEASE = "${PV}" | ||
22 | LLVM_DIR = "llvm${LLVM_RELEASE}" | ||
23 | |||
24 | SRCREV = "9a5c333388cbb54a0ce3a67c4f539f5e590a089b" | ||
25 | PV = "5.0" | ||
26 | PATCH_VERSION = "0" | ||
27 | SRC_URI = "git://github.com/llvm-mirror/llvm.git;branch=release_50;protocol=http \ | ||
28 | file://0001-llvm-TargetLibraryInfo-Undefine-libc-functions-if-th.patch \ | ||
29 | file://0002-llvm-allow-env-override-of-exe-path.patch \ | ||
30 | " | ||
31 | S = "${WORKDIR}/git" | ||
32 | |||
33 | LLVM_INSTALL_DIR = "${WORKDIR}/llvm-install" | ||
34 | def get_llvm_arch(bb, d, arch_var): | ||
35 | import re | ||
36 | a = d.getVar(arch_var, True) | ||
37 | if re.match('(i.86|athlon|x86.64)$', a): return 'X86' | ||
38 | elif re.match('arm$', a): return 'ARM' | ||
39 | elif re.match('armeb$', a): return 'ARM' | ||
40 | elif re.match('aarch64$', a): return 'AArch64' | ||
41 | elif re.match('aarch64_be$', a): return 'AArch64' | ||
42 | elif re.match('mips(isa|)(32|64|)(r6|)(el|)$', a): return 'Mips' | ||
43 | elif re.match('p(pc|owerpc)(|64)', a): return 'PowerPC' | ||
44 | else: | ||
45 | bb.error("cannot map '%s' to a supported llvm architecture" % a) | ||
46 | return "" | ||
47 | |||
48 | def get_llvm_target_arch(bb, d): | ||
49 | return get_llvm_arch(bb, d, 'TARGET_ARCH') | ||
50 | # | ||
51 | # Default to build all OE-Core supported target arches (user overridable). | ||
52 | # | ||
53 | LLVM_TARGETS ?= "${@get_llvm_target_arch(bb, d)}" | ||
54 | LLVM_TARGETS_prepend_x86 = "AMDGPU;" | ||
55 | LLVM_TARGETS_prepend_x86-64 = "AMDGPU;" | ||
56 | |||
57 | EXTRA_OECMAKE += "-DLLVM_ENABLE_ASSERTIONS=OFF \ | ||
58 | -DLLVM_ENABLE_EXPENSIVE_CHECKS=OFF \ | ||
59 | -DLLVM_ENABLE_PIC=ON \ | ||
60 | -DLLVM_BINDINGS_LIST='' \ | ||
61 | -DLLVM_LINK_LLVM_DYLIB=ON \ | ||
62 | -DLLVM_ENABLE_FFI=ON \ | ||
63 | -DFFI_INCLUDE_DIR=$(pkg-config --variable=includedir libffi) \ | ||
64 | -DLLVM_OPTIMIZED_TABLEGEN=ON \ | ||
65 | -DLLVM_TARGETS_TO_BUILD="${LLVM_TARGETS}" \ | ||
66 | -G Ninja" | ||
67 | |||
68 | EXTRA_OECMAKE_append_class-target = "\ | ||
69 | -DCMAKE_CROSSCOMPILING:BOOL=ON \ | ||
70 | -DLLVM_TABLEGEN=${STAGING_BINDIR_NATIVE}/llvm-tblgen \ | ||
71 | " | ||
72 | |||
73 | EXTRA_OECMAKE_append_class-nativesdk = "\ | ||
74 | -DCMAKE_CROSSCOMPILING:BOOL=ON \ | ||
75 | -DLLVM_TABLEGEN=${STAGING_BINDIR_NATIVE}/llvm-tblgen \ | ||
76 | " | ||
77 | |||
78 | do_configure_prepend() { | ||
79 | # Fix paths in llvm-config | ||
80 | sed -i "s|sys::path::parent_path(CurrentPath))\.str()|sys::path::parent_path(sys::path::parent_path(CurrentPath))).str()|g" ${S}/tools/llvm-config/llvm-config.cpp | ||
81 | sed -ri "s#/(bin|include|lib)(/?\")#/\1/${LLVM_DIR}\2#g" ${S}/tools/llvm-config/llvm-config.cpp | ||
82 | sed -ri "s#lib/${LLVM_DIR}#${baselib}/${LLVM_DIR}#g" ${S}/tools/llvm-config/llvm-config.cpp | ||
83 | } | ||
84 | |||
85 | do_compile() { | ||
86 | NINJA_STATUS="[%p] " ninja -v ${PARALLEL_MAKE} | ||
87 | } | ||
88 | |||
89 | do_compile_class-native() { | ||
90 | NINJA_STATUS="[%p] " ninja -v ${PARALLEL_MAKE} llvm-tblgen | ||
91 | } | ||
92 | |||
93 | do_install() { | ||
94 | NINJA_STATUS="[%p] " DESTDIR=${LLVM_INSTALL_DIR} ninja -v install | ||
95 | install -D -m 0755 ${B}/NATIVE/bin/llvm-config ${D}${libdir}/${LLVM_DIR}/llvm-config-host | ||
96 | |||
97 | install -d ${D}${bindir}/${LLVM_DIR} | ||
98 | cp -r ${LLVM_INSTALL_DIR}${bindir}/* ${D}${bindir}/${LLVM_DIR}/ | ||
99 | |||
100 | install -d ${D}${includedir}/${LLVM_DIR} | ||
101 | cp -r ${LLVM_INSTALL_DIR}${includedir}/* ${D}${includedir}/${LLVM_DIR}/ | ||
102 | |||
103 | install -d ${D}${libdir}/${LLVM_DIR} | ||
104 | |||
105 | # The LLVM sources have "/lib" embedded and so we cannot completely rely on the ${libdir} variable | ||
106 | if [ -d ${LLVM_INSTALL_DIR}${libdir}/ ]; then | ||
107 | cp -r ${LLVM_INSTALL_DIR}${libdir}/* ${D}${libdir}/${LLVM_DIR}/ | ||
108 | elif [ -d ${LLVM_INSTALL_DIR}${prefix}/lib ]; then | ||
109 | cp -r ${LLVM_INSTALL_DIR}${prefix}/lib/* ${D}${libdir}/${LLVM_DIR}/ | ||
110 | elif [ -d ${LLVM_INSTALL_DIR}${prefix}/lib64 ]; then | ||
111 | cp -r ${LLVM_INSTALL_DIR}${prefix}/lib64/* ${D}${libdir}/${LLVM_DIR}/ | ||
112 | fi | ||
113 | |||
114 | # Remove unnecessary cmake files | ||
115 | rm -rf ${D}${libdir}/${LLVM_DIR}/cmake | ||
116 | |||
117 | ln -s ${LLVM_DIR}/libLLVM-${PV}${SOLIBSDEV} ${D}${libdir}/libLLVM-${PV}${SOLIBSDEV} | ||
118 | |||
119 | # We'll have to delete the libLLVM.so due to multiple reasons... | ||
120 | rm -rf ${D}${libdir}/${LLVM_DIR}/libLLVM.so | ||
121 | rm -rf ${D}${libdir}/${LLVM_DIR}/libLTO.so | ||
122 | } | ||
123 | do_install_class-native() { | ||
124 | install -D -m 0755 ${B}/bin/llvm-tblgen ${D}${bindir}/llvm-tblgen | ||
125 | } | ||
126 | |||
127 | PACKAGES += "${PN}-bugpointpasses ${PN}-llvmhello" | ||
128 | ALLOW_EMPTY_${PN} = "1" | ||
129 | ALLOW_EMPTY_${PN}-staticdev = "1" | ||
130 | FILES_${PN} = "" | ||
131 | FILES_${PN}-staticdev = "" | ||
132 | FILES_${PN}-dbg = " \ | ||
133 | ${bindir}/${LLVM_DIR}/.debug \ | ||
134 | ${libdir}/${LLVM_DIR}/.debug/BugpointPasses.so \ | ||
135 | ${libdir}/${LLVM_DIR}/.debug/LLVMHello.so \ | ||
136 | ${libdir}/${LLVM_DIR}/.debug/libLTO.so* \ | ||
137 | ${libdir}/${LLVM_DIR}/.debug/llvm-config-host \ | ||
138 | /usr/src/debug \ | ||
139 | " | ||
140 | |||
141 | FILES_${PN}-dev = " \ | ||
142 | ${bindir}/${LLVM_DIR} \ | ||
143 | ${includedir}/${LLVM_DIR} \ | ||
144 | ${libdir}/${LLVM_DIR}/llvm-config-host \ | ||
145 | " | ||
146 | |||
147 | RRECOMMENDS_${PN}-dev += "${PN}-bugpointpasses ${PN}-llvmhello" | ||
148 | |||
149 | FILES_${PN}-bugpointpasses = "\ | ||
150 | ${libdir}/${LLVM_DIR}/BugpointPasses.so \ | ||
151 | " | ||
152 | FILES_${PN} += "\ | ||
153 | ${libdir}/${LLVM_DIR}/libLTO.so.* \ | ||
154 | " | ||
155 | |||
156 | FILES_${PN}-llvmhello = "\ | ||
157 | ${libdir}/${LLVM_DIR}/LLVMHello.so \ | ||
158 | " | ||
159 | |||
160 | PACKAGES_DYNAMIC = "^libllvm${LLVM_RELEASE}-.*$" | ||
161 | NOAUTOPACKAGEDEBUG = "1" | ||
162 | |||
163 | INSANE_SKIP_${MLPREFIX}libllvm${LLVM_RELEASE}-llvm-${LLVM_RELEASE}.${PATCH_VERSION} += "dev-so" | ||
164 | INSANE_SKIP_${MLPREFIX}libllvm${LLVM_RELEASE}-llvm-${LLVM_RELEASE} += "dev-so" | ||
165 | INSANE_SKIP_${MLPREFIX}libllvm${LLVM_RELEASE}-llvm += "dev-so" | ||
166 | |||
167 | python llvm_populate_packages() { | ||
168 | libdir = bb.data.expand('${libdir}', d) | ||
169 | libllvm_libdir = bb.data.expand('${libdir}/${LLVM_DIR}', d) | ||
170 | split_dbg_packages = do_split_packages(d, libllvm_libdir+'/.debug', '^lib(.*)\.so$', 'libllvm${LLVM_RELEASE}-%s-dbg', 'Split debug package for %s', allow_dirs=True) | ||
171 | split_packages = do_split_packages(d, libdir, '^lib(.*)\.so$', 'libllvm${LLVM_RELEASE}-%s', 'Split package for %s', allow_dirs=True, allow_links=True, recursive=True) | ||
172 | split_staticdev_packages = do_split_packages(d, libllvm_libdir, '^lib(.*)\.a$', 'libllvm${LLVM_RELEASE}-%s-staticdev', 'Split staticdev package for %s', allow_dirs=True) | ||
173 | if split_packages: | ||
174 | pn = d.getVar('PN', True) | ||
175 | d.appendVar('RDEPENDS_' + pn, ' '+' '.join(split_packages)) | ||
176 | d.appendVar('RDEPENDS_' + pn + '-dbg', ' '+' '.join(split_dbg_packages)) | ||
177 | d.appendVar('RDEPENDS_' + pn + '-staticdev', ' '+' '.join(split_staticdev_packages)) | ||
178 | } | ||
179 | |||
180 | PACKAGESPLITFUNCS_prepend = "llvm_populate_packages " | ||
181 | |||
182 | BBCLASSEXTEND = "native nativesdk" | ||