go: upgrade 1.22.1 -> 1.22.2

Include fixes for CVE-2023-45288

Upgrade to latest 1.22.x release [1]:

$ git --no-pager log --oneline go1.22.1..go1.22.2
dddf0ae40f (tag: go1.22.2) [release-branch.go1.22] go1.22.2
e55d7cf843 [release-branch.go1.22] net/http: update bundled golang.org/x/net/http2
4edf4bb2c6 [release-branch.go1.22] all: update golang.org/x/net
2c6d106541 [release-branch.go1.22] cmd/compile: don't assume args are always zero-extended
46587483e3 [release-branch.go1.22] cmd/compile: fix sign/zero-extension removal
0a5b33a883 [release-branch.go1.22] encoding/gob: make x509.Certificate marshalable again
0c53f93faa [release-branch.go1.22] cmd/go/internal/modfetch: pass "-c" arguments to git before subcommands
abfd578156 [release-branch.go1.22] runtime: fix EvFrequency event value on Windows in the new tracer
7fb7acb82d [release-branch.go1.22] cmd/link/internal/riscv64: generate local text symbols for R_RISCV_CALL
e23707b59c [release-branch.go1.22] go/types, types2: handle Alias types in substitution
3826650c99 [release-branch.go1.22] cmd/compile: fix early deadcode with label statement
e71b0b1fee [release-branch.go1.22] cmd/compile: fix copying SSA-able variables optimization
9508eae5d1 [release-branch.go1.22] cmd/internal/obj/ppc64: don't modify runtime.elf_* symbols
35b1a146d9 [release-branch.go1.22] cmd/go: respect -coverpkg for unselected no-test packages

[1] https://github.com/golang/go/compare/go1.22.1...go1.22.2

(From OE-Core rev: 348e676046159b00a6f06f68336aa5443919c139)

Signed-off-by: Jose Quaresma <jose.quaresma@foundries.io>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/meta/recipes-devtools/go/go-native_1.22.2.bb b/meta/recipes-devtools/go/go-native_1.22.2.bb
new file mode 100644
index 0000000000..ddf25b2c9b
--- /dev/null
+++ b/meta/recipes-devtools/go/go-native_1.22.2.bb
@@ -0,0 +1,58 @@
+# This recipe builds a native Go (written in Go) by first building an old Go 1.4
+# (written in C). However this old Go does not support all hosts platforms.
+
+require go-${PV}.inc
+
+inherit native
+
+SRC_URI += "https://dl.google.com/go/go1.4-bootstrap-20171003.tar.gz;name=bootstrap;subdir=go1.4"
+SRC_URI[bootstrap.sha256sum] = "f4ff5b5eb3a3cae1c993723f3eab519c5bae18866b5e5f96fe1102f0cb5c3e52"
+
+export GOOS = "${BUILD_GOOS}"
+export GOARCH = "${BUILD_GOARCH}"
+CC = "${@d.getVar('BUILD_CC').strip()}"
+
+GOMAKEARGS ?= "--no-banner"
+
+do_configure() {
+        cd ${WORKDIR}/go1.4/go/src
+        CGO_ENABLED=0 GOROOT=${WORKDIR}/go1.4/go ./make.bash
+}
+
+do_compile() {
+        export GOROOT_FINAL="${libdir_native}/go"
+        export GOROOT_BOOTSTRAP="${WORKDIR}/go1.4/go"
+
+        cd src
+        ./make.bash ${GOMAKEARGS}
+        cd ${B}
+}
+do_compile[cleandirs] += "${GOTMPDIR} ${B}/bin"
+
+make_wrapper() {
+        rm -f ${D}${bindir}/$2$3
+        cat <<END >${D}${bindir}/$2$3
+#!/bin/bash
+here=\`dirname \$0\`
+export GOROOT="${GOROOT:-\`readlink -f \$here/../lib/go\`}"
+\$here/../lib/go/bin/$1 "\$@"
+END
+        chmod +x ${D}${bindir}/$2
+}
+
+do_install() {
+        install -d ${D}${libdir}/go
+        cp --preserve=mode,timestamps -R ${B}/pkg ${D}${libdir}/go/
+        install -d ${D}${libdir}/go/src
+        (cd ${S}/src; for d in *; do \
+                [ -d $d ] && cp -a ${S}/src/$d ${D}${libdir}/go/src/; \
+        done)
+        find ${D}${libdir}/go/src -depth -type d -name testdata -exec rm -rf {} \;
+        install -d ${D}${bindir} ${D}${libdir}/go/bin
+        for f in ${B}/bin/*
+        do
+                base=`basename $f`
+                install -m755 $f ${D}${libdir}/go/bin
+                make_wrapper $base $base
+        done
+}