bison: 2.7.1 -> 3.0.4

* Based on Chong Lu's previous upgrade to 3.0.2
* Remove unneeded patches:
  dont-depend-on-help2man.patch and
  fix_cross_manpage_building.patch

(From OE-Core rev: fbb26d8db8e71fd979edd2bafa7e0bab7632950c)

Signed-off-by: Chong Lu <Chong.Lu@windriver.com>
Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 37 insertions, 0 deletions

diff --git a/meta/recipes-devtools/bison/bison_3.0.4.bb b/meta/recipes-devtools/bison/bison_3.0.4.bb
new file mode 100644
index 0000000000..506141041c
--- /dev/null
+++ b/meta/recipes-devtools/bison/bison_3.0.4.bb
@@ -0,0 +1,37 @@
+SUMMARY = "GNU Project parser generator (yacc replacement)"
+DESCRIPTION = "Bison is a general-purpose parser generator that converts an annotated context-free grammar into \
+an LALR(1) or GLR parser for that grammar.  Bison is upward compatible with Yacc: all properly-written Yacc \
+grammars ought to work with Bison with no change. Anyone familiar with Yacc should be able to use Bison with \
+little trouble."
+HOMEPAGE = "http://www.gnu.org/software/bison/"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+SECTION = "devel"
+DEPENDS = "bison-native flex-native"
+
+SRC_URI = "${GNU_MIRROR}/bison/bison-${PV}.tar.xz \
+           file://m4.patch \
+           file://0001-Unset-need_charset_alias-when-building-for-musl.patch \
+"
+
+# No point in hardcoding path to m4, just use PATH
+EXTRA_OECONF += "M4=m4"
+
+SRC_URI[md5sum] = "c342201de104cc9ce0a21e0ad10d4021"
+SRC_URI[sha256sum] = "a72428c7917bdf9fa93cb8181c971b6e22834125848cf1d03ce10b1bb0716fe1"
+
+LDFLAGS_prepend_libc-uclibc = " -lrt "
+DEPENDS_class-native = "gettext-minimal-native"
+
+inherit autotools gettext texinfo
+acpaths = "-I ${S}/m4"
+
+do_compile_prepend() {
+        for i in mfcalc calc++ rpcalc; do mkdir -p ${B}/examples/$i; done
+}
+
+do_install_append_class-native() {
+        create_wrapper ${D}/${bindir}/bison \
+                BISON_PKGDATADIR=${STAGING_DATADIR_NATIVE}/bison
+}
+BBCLASSEXTEND = "native nativesdk"