binutils: update to 2.29.1

update to 2.29.1 to fix the following missing CVEs:

CVE-2017-15939, CVE-2017-15938, CVE-2017-15225, CVE-2017-15025,
CVE-2017-15024, CVE-2017-15023, CVE-2017-15022, CVE-2017-15021,
CVE-2017-15020, CVE-2017-14974, CVE-2017-14940, CVE-2017-14939,
CVE-2017-14938, CVE-2017-14934, CVE-2017-14933, CVE-2017-14932,
CVE-2017-14930, CVE-2017-14745, CVE-2017-14729, CVE-2017-14529,
CVE-2017-14333, CVE-2017-14130, CVE-2017-14129, CVE-2017-14128,
CVE-2017-13757, CVE-2017-13716, CVE-2017-13710, CVE-2017-12967,
CVE-2017-12799, CVE-2017-12459, CVE-2017-12458, CVE-2017-12457,
CVE-2017-12456, CVE-2017-12455, CVE-2017-12454, CVE-2017-12453,
CVE-2017-12452, CVE-2017-12451, CVE-2017-12450, CVE-2017-12449,
CVE-2017-12448

see Changelogs for additional information

(From OE-Core rev: 19da8865d31f10af4d5e3b91aa31958c8ad00bfd)

Signed-off-by: Armin Kuster <akuster@mvista.com>
(cherry picked from commit 53df200cb5edab04a7ab38b974f96281733fadb2)
Signed-off-by: Armin Kuster <akuster808@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/meta/recipes-devtools/binutils/binutils_2.29.1.bb b/meta/recipes-devtools/binutils/binutils_2.29.1.bb
new file mode 100644
index 0000000000..51a9748906
--- /dev/null
+++ b/meta/recipes-devtools/binutils/binutils_2.29.1.bb
@@ -0,0 +1,49 @@
+require binutils.inc
+require binutils-${PV}.inc
+
+DEPENDS += "flex bison zlib"
+
+EXTRA_OECONF += "--with-sysroot=/ \
+                --enable-install-libbfd \
+                --enable-install-libiberty \
+                --enable-shared \
+                --with-system-zlib \
+                "
+
+EXTRA_OEMAKE_append_libc-musl = "\
+                                 gt_cv_func_gnugettext1_libc=yes \
+                                 gt_cv_func_gnugettext2_libc=yes \
+                                "
+EXTRA_OECONF_class-native = "--enable-targets=all \
+                             --enable-64-bit-bfd \
+                             --enable-install-libiberty \
+                             --enable-install-libbfd \
+                             --disable-werror"
+
+do_install_class-native () {
+        autotools_do_install
+
+        # Install the libiberty header
+        install -d ${D}${includedir}
+        install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
+        install -m 644 ${S}/include/libiberty.h ${D}${includedir}
+
+        # We only want libiberty, libbfd and libopcodes
+        rm -rf ${D}${bindir}
+        rm -rf ${D}${prefix}/${TARGET_SYS}
+        rm -rf ${D}${prefix}/lib/ldscripts
+        rm -rf ${D}${prefix}/share/info
+        rm -rf ${D}${prefix}/share/locale
+        rm -rf ${D}${prefix}/share/man
+        rmdir ${D}${prefix}/share || :
+        rmdir ${D}/${libdir}/gcc-lib || :
+        rmdir ${D}/${libdir}64/gcc-lib || :
+        rmdir ${D}/${libdir} || :
+        rmdir ${D}/${libdir}64 || :
+}
+
+# Split out libbfd-*.so so including perf doesn't include extra stuff
+PACKAGE_BEFORE_PN += "libbfd"
+FILES_libbfd = "${libdir}/libbfd-*.so"
+
+BBCLASSEXTEND = "native nativesdk"