autogen-native: upgrade to 5.18.2

* Upgrade from 5.17.4 to 5.18.2
* Rename files -> autogen

(From OE-Core rev: 6bcd2dafa379badab11bff9d7b607f7f5d72fc94)

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 31 insertions, 0 deletions

diff --git a/meta/recipes-devtools/autogen/autogen-native_5.18.2.bb b/meta/recipes-devtools/autogen/autogen-native_5.18.2.bb
new file mode 100644
index 0000000000..c7950c3c6a
--- /dev/null
+++ b/meta/recipes-devtools/autogen/autogen-native_5.18.2.bb
@@ -0,0 +1,31 @@
+SUMMARY = "AutoGen is a tool to manage programs that contain large amounts of repetitious text."
+DESCRIPTION = "AutoGen is a tool designed to simplify the creation and\
+ maintenance of programs that contain large amounts of repetitious text.\
+ It is especially valuable in programs that have several blocks of text\
+ that must be kept synchronized."
+HOMEPAGE = "http://www.gnu.org/software/autogen/"
+SECTION = "devel"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+SRC_URI = "${GNU_MIRROR}/autogen/rel${PV}/autogen-${PV}.tar.gz \
+           file://guile.patch \
+           file://increase-timeout-limit.patch"
+
+SRC_URI[md5sum] = "117c4bc5613c57e1b97d760a5d1910a4"
+SRC_URI[sha256sum] = "cc2702dec21ba5b01144865163f6d1a54268d2b72aafc5520ad0e0cb57104068"
+
+DEPENDS = "guile-native libtool-native libxml2-native"
+
+inherit autotools native
+
+# autogen-native links against libguile which may have been relocated with sstate
+# these environment variables ensure there isn't a relocation issue
+export GUILE_LOAD_PATH = "${STAGING_DATADIR_NATIVE}/guile/2.0"
+export GUILE_LOAD_COMPILED_PATH = "${STAGING_LIBDIR_NATIVE}/guile/2.0/ccache"
+
+do_install_append () {
+        create_wrapper ${D}/${bindir}/autogen \
+                GUILE_LOAD_PATH=${STAGING_DATADIR_NATIVE}/guile/2.0 \
+                GUILE_LOAD_COMPILED_PATH=${STAGING_LIBDIR_NATIVE}/guile/2.0/ccache
+}