systemd: Upgrade v246 -> v246.1

Commits:

  972391ac396f fix typo in systemctl help
  443aacfcda39 man: clarify that LogNamespace= is for system services only
  5aec8fe54e47 _sd-common.h: avoid parsing errors with Coverity
  f9ad4ea2ca06 analyze: fix 'cat-config systemd/zram-generator.conf'
  dda6fec1dfc7 man: describe that changing Storage= does not move existing data
  2bbd33e476ac core: reset bus error before reuse
  b81504a3c76b nspawn: Fix incorrect usage of putenv
  cb263973acf8 man: fix typo in systemd.service
  73b432e7ef21 network: fix DHCPv6 Prefix Delegation example after option rename

(From OE-Core rev: 26c30c4cccb05d68d22e66dd3b34882837cac5dd)

Signed-off-by: Alex Kiernan <alex.kiernan@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/meta/recipes-core/systemd/systemd-conf_246.1.bb b/meta/recipes-core/systemd/systemd-conf_246.1.bb
new file mode 100644
index 0000000000..d9ec023bfd
--- /dev/null
+++ b/meta/recipes-core/systemd/systemd-conf_246.1.bb
@@ -0,0 +1,38 @@
+SUMMARY = "Systemd system configuration"
+DESCRIPTION = "Systemd may require slightly different configuration for \
+different machines.  For example, qemu machines require a longer \
+DefaultTimeoutStartSec setting."
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+SRC_URI = "\
+    file://journald.conf \
+    file://logind.conf \
+    file://system.conf \
+    file://system.conf-qemuall \
+    file://wired.network \
+"
+
+do_install() {
+        install -D -m0644 ${WORKDIR}/journald.conf ${D}${systemd_unitdir}/journald.conf.d/00-${PN}.conf
+        install -D -m0644 ${WORKDIR}/logind.conf ${D}${systemd_unitdir}/logind.conf.d/00-${PN}.conf
+        install -D -m0644 ${WORKDIR}/system.conf ${D}${systemd_unitdir}/system.conf.d/00-${PN}.conf
+        install -D -m0644 ${WORKDIR}/wired.network ${D}${systemd_unitdir}/network/80-wired.network
+}
+
+# Based on change from YP bug 8141, OE commit 5196d7bacaef1076c361adaa2867be31759c1b52
+do_install_append_qemuall() {
+        install -D -m0644 ${WORKDIR}/system.conf-qemuall ${D}${systemd_unitdir}/system.conf.d/01-${PN}.conf
+
+        # Do not install wired.network for qemu bsps
+        rm -rf ${D}${systemd_unitdir}/network
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+FILES_${PN} = "\
+    ${systemd_unitdir}/journald.conf.d/ \
+    ${systemd_unitdir}/logind.conf.d/ \
+    ${systemd_unitdir}/system.conf.d/ \
+    ${systemd_unitdir}/network/ \
+"