newlib: Upgrade newlib and libgloss to the yearly release 3.2.0

A new yearly snapshot was taken on January 2nd of 2020, this bumps
newlib to 3.2.0.

 - Mentor Graphics added tcl license (amdgcn-* targets)
 - BSD-Clause-2 was added as well by Dinux (pru-* targets)

(From OE-Core rev: e2d0e36234ba928d0cbcc98d8358b94d8d44412e)

Signed-off-by: Alejandro Enedino Hernandez Samaniego <alejandro@enedino.org>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 33 insertions, 0 deletions

diff --git a/meta/recipes-core/newlib/libgloss_3.2.0.bb b/meta/recipes-core/newlib/libgloss_3.2.0.bb
new file mode 100644
index 0000000000..c9ed30d988
--- /dev/null
+++ b/meta/recipes-core/newlib/libgloss_3.2.0.bb
@@ -0,0 +1,33 @@
+require newlib.inc
+
+DEPENDS += "newlib"
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/libgloss:"
+
+SRC_URI_append_powerpc = " file://fix-rs6000-crt0.patch"
+SRC_URI_append_arm = " file://fix_makefile_include_arm_h.patch"
+
+do_configure() {
+        ${S}/libgloss/configure ${EXTRA_OECONF}
+}
+
+do_install_prepend() {
+        # install doesn't create this itself, avoid install error
+        install -d ${D}${prefix}/${TARGET_SYS}/lib
+}
+
+do_install_append() {
+        # Move libs to default directories so they can be picked up later
+        install -d ${D}${libdir}
+        mv -v ${D}${prefix}/${TARGET_SYS}/lib/* ${D}${libdir}
+
+        # Remove original directory
+        rmdir -p --ignore-fail-on-non-empty ${D}${prefix}/${TARGET_SYS}/lib
+}
+
+# Split packages correctly
+FILES_${PN} += "${libdir}/*.ld ${libdir}/*.specs"
+FILES_${PN}-dev += "${libdir}/cpu-init/*"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"