netbase: update to ver. 5.0

(From OE-Core rev: 5beb7176d361d4bfa279bbfab5a17b8fe4fa3b73)

Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/meta/recipes-core/netbase/netbase_5.0.bb b/meta/recipes-core/netbase/netbase_5.0.bb
new file mode 100644
index 0000000000..3aea87412d
--- /dev/null
+++ b/meta/recipes-core/netbase/netbase_5.0.bb
@@ -0,0 +1,48 @@
+SUMMARY = "Basic TCP/IP networking support"
+DESCRIPTION = "This package provides the necessary infrastructure for basic TCP/IP based networking"
+HOMEPAGE = "http://packages.debian.org/netbase"
+SECTION = "base"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://debian/copyright;md5=3dd6192d306f582dee7687da3d8748ab"
+PR = "r0"
+
+inherit update-rc.d
+
+INITSCRIPT_NAME = "networking"
+INITSCRIPT_PARAMS = "start 40 S . stop 40 0 6 1 ."
+
+SRC_URI = "${DEBIAN_MIRROR}/main/n/netbase/netbase_${PV}.tar.gz \
+           file://init \
+           file://hosts \
+           file://interfaces \
+           file://nfsroot"
+
+SRC_URI[md5sum] = "a379d9199d44d817543eddc211a29b70"
+SRC_URI[sha256sum] = "ac9424d3cb2bd3c07b6c5bc5875c434d3bc687a73cd7c54b7dc7122308afa9dc"
+
+do_install () {
+        install -d ${D}${sysconfdir}/init.d \
+                   ${D}${mandir}/man8 \
+                   ${D}${sysconfdir}/network/if-pre-up.d \
+                   ${D}${sysconfdir}/network/if-up.d \
+                   ${D}${sysconfdir}/network/if-down.d \
+                   ${D}${sysconfdir}/network/if-post-down.d
+        install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/networking
+        install -m 0644 ${WORKDIR}/hosts ${D}${sysconfdir}/hosts
+        install -m 0644 etc-rpc ${D}${sysconfdir}/rpc
+        install -m 0644 etc-protocols ${D}${sysconfdir}/protocols
+        install -m 0644 etc-services ${D}${sysconfdir}/services
+        install -m 0644 ${WORKDIR}/interfaces ${D}${sysconfdir}/network/interfaces
+        install -m 0755 ${WORKDIR}/nfsroot ${D}${sysconfdir}/network/if-pre-up.d
+
+        # Disable network manager on machines that commonly do NFS booting
+        case "${MACHINE}" in
+                "qemuarm*" | "qemux86" | "qemux86-64" | "qemumips*" | "qemuppc" | "qemush*")
+                        touch ${D}${sysconfdir}/network/nm-disabled-eth0
+                        ;;
+                *)
+                        ;;
+        esac
+}
+
+CONFFILES_${PN} = "${sysconfdir}/hosts ${sysconfdir}/network/interfaces"