glibc: Upgrade 2.20 -> 2.21

Drop CVE backports and ppc/fpu detection patch which is not needed anymore
Forward port eglibc option groups patch
Default to using glibc 2.21

Additional patches needed to appease -Werror option

Change-Id: I1873097cec8387ea9e8186a255122938fc28c976
(From OE-Core rev: 6617cc92076764d51f0190786f8d62b8c99ae984)

Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 0 insertions, 162 deletions

diff --git a/meta/recipes-core/glibc/glibc_2.20.bb b/meta/recipes-core/glibc/glibc_2.20.bb
deleted file mode 100644
index 8a8b296def..0000000000
--- a/meta/recipes-core/glibc/glibc_2.20.bb
+++ /dev/null
@@ -1,162 +0,0 @@
-require glibc.inc
-
-DEPENDS += "gperf-native kconfig-frontends-native"
-
-PV = "2.20"
-
-SRCREV = "b8079dd0d360648e4e8de48656c5c38972621072"
-
-SRC_URI = "git://sourceware.org/git/glibc.git;branch=release/${PV}/master \
-           file://IO-acquire-lock-fix.patch \
-           file://mips-rld-map-check.patch \
-           file://etc/ld.so.conf \
-           file://generate-supported.mk \
-           file://glibc.fix_sqrt2.patch \
-           file://multilib_readlib.patch \
-           file://ppc-sqrt_finite.patch \
-           file://ppc_slow_ieee754_sqrt.patch \
-           file://add_resource_h_to_wait_h.patch \
-           file://fsl-ppc-no-fsqrt.patch \
-           file://0001-R_ARM_TLS_DTPOFF32.patch \
-           file://0001-eglibc-run-libm-err-tab.pl-with-specific-dirs-in-S.patch \
-           file://fix-tibetian-locales.patch \
-           file://ppce6500-32b_slow_ieee754_sqrt.patch \
-           file://grok_gold.patch \
-           file://fix_am_rootsbindir.patch \
-           ${EGLIBCPATCHES} \
-           ${CVEPATCHES} \
-          "
-EGLIBCPATCHES = "\
-           file://timezone-re-written-tzselect-as-posix-sh.patch \
-           file://eglibc.patch \
-           file://option-groups.patch \
-           file://GLRO_dl_debug_mask.patch \
-           file://eglibc-header-bootstrap.patch \
-           file://eglibc-resolv-dynamic.patch \
-           file://eglibc-ppc8xx-cache-line-workaround.patch \
-           file://eglibc-sh4-fpscr_values.patch \
-           file://eglibc-use-option-groups.patch \
-          "
-#           file://eglibc-install-pic-archives.patch \
-#           file://initgroups_keys.patch \
-#
-
-CVEPATCHES = "\
-        file://CVE-2014-7817-wordexp-fails-to-honour-WRDE_NOCMD.patch \
-        file://CVE-2012-3406-Stack-overflow-in-vfprintf-BZ-16617.patch \
-        file://CVE-2014-9402_endless-loop-in-getaddr_r.patch \
-    "
-LIC_FILES_CHKSUM = "file://LICENSES;md5=e9a558e243b36d3209f380deb394b213 \
-      file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
-      file://posix/rxspencer/COPYRIGHT;md5=dc5485bb394a13b2332ec1c785f5d83a \
-      file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c"
-
-SRC_URI_append_class-nativesdk = " file://ld-search-order.patch \
-            file://relocatable_sdk.patch \
-            file://relocatable_sdk_fix_openpath.patch \
-            "
-S = "${WORKDIR}/git"
-B = "${WORKDIR}/build-${TARGET_SYS}"
-
-PACKAGES_DYNAMIC = ""
-
-# the -isystem in bitbake.conf screws up glibc do_stage
-BUILD_CPPFLAGS = "-I${STAGING_INCDIR_NATIVE}"
-TARGET_CPPFLAGS = "-I${STAGING_DIR_TARGET}${includedir}"
-
-GLIBC_BROKEN_LOCALES = " _ER _ET so_ET yn_ER sid_ET tr_TR mn_MN gez_ET gez_ER bn_BD te_IN es_CR.ISO-8859-1"
-
-#
-# For now, we will skip building of a gcc package if it is a uclibc one
-# and our build is not a uclibc one, and we skip a glibc one if our build
-# is a uclibc build.
-#
-# See the note in gcc/gcc_3.4.0.oe
-#
-
-python __anonymous () {
-    import re
-    uc_os = (re.match('.*uclibc$', d.getVar('TARGET_OS', True)) != None)
-    if uc_os:
-        raise bb.parse.SkipPackage("incompatible with target %s" %
-                                   d.getVar('TARGET_OS', True))
-}
-
-EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \
-                --without-cvs --disable-profile \
-                --disable-debug --without-gd \
-                --enable-clocale=gnu \
-                --enable-add-ons \
-                --with-headers=${STAGING_INCDIR} \
-                --without-selinux \
-                --enable-obsolete-rpc \
-                --with-kconfig=${STAGING_BINDIR_NATIVE} \
-                --disable-nscd \
-                ${GLIBC_EXTRA_OECONF}"
-
-EXTRA_OECONF += "${@get_libc_fpu_setting(bb, d)}"
-EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'libc-inet-anl', '--enable-nscd', '--disable-nscd', d)}"
-
-
-do_patch_append() {
-    bb.build.exec_func('do_fix_readlib_c', d)
-}
-
-# for mips glibc now builds syscall tables for all abi's
-# so we make sure that we choose right march option which is
-# compatible with o32,n32 and n64 abi's
-# e.g. -march=mips32 is not compatible with n32 and n64 therefore
-# we filter it out in such case -march=from-abi which will be
-# mips1 when using o32 and mips3 when using n32/n64
-
-TUNE_CCARGS_mips := "${@oe_filter_out('-march=mips32', '${TUNE_CCARGS}', d)}"
-TUNE_CCARGS_mipsel := "${@oe_filter_out('-march=mips32', '${TUNE_CCARGS}', d)}"
-
-do_fix_readlib_c () {
-        sed -i -e 's#OECORE_KNOWN_INTERPRETER_NAMES#${EGLIBC_KNOWN_INTERPRETER_NAMES}#' ${S}/elf/readlib.c
-}
-
-do_configure () {
-# override this function to avoid the autoconf/automake/aclocal/autoheader
-# calls for now
-# don't pass CPPFLAGS into configure, since it upsets the kernel-headers
-# version check and doesn't really help with anything
-        if [ -z "`which rpcgen`" ]; then
-                echo "rpcgen not found.  Install glibc-devel."
-                exit 1
-        fi
-        (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
-        find ${S} -name "configure" | xargs touch
-        CPPFLAGS="" oe_runconf
-}
-
-rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
-          yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
-          rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
-
-do_compile () {
-        # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
-        unset LDFLAGS
-        base_do_compile
-        (
-                cd ${S}/sunrpc/rpcsvc
-                for r in ${rpcsvc}; do
-                        h=`echo $r|sed -e's,\.x$,.h,'`
-                        rpcgen -h $r -o $h || bbwarn "unable to generate header for $r"
-                done
-        )
-        echo "Adjust ldd script"
-        if [ -n "${RTLDLIST}" ]
-        then
-                prevrtld=`cat ${B}/elf/ldd | grep "^RTLDLIST=" | sed 's#^RTLDLIST="\?\([^"]*\)"\?$#\1#'`
-                if [ "${prevrtld}" != "${RTLDLIST}" ]
-                then
-                        sed -i ${B}/elf/ldd -e "s#^RTLDLIST=.*\$#RTLDLIST=\"${prevrtld} ${RTLDLIST}\"#"
-                fi
-        fi
-
-}
-
-require glibc-package.inc
-
-BBCLASSEXTEND = "nativesdk"