glibc: Upgrade 2.20 -> 2.21

Drop CVE backports and ppc/fpu detection patch which is not needed anymore
Forward port eglibc option groups patch
Default to using glibc 2.21

Additional patches needed to appease -Werror option

Change-Id: I1873097cec8387ea9e8186a255122938fc28c976
(From OE-Core rev: 6617cc92076764d51f0190786f8d62b8c99ae984)

Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/meta/recipes-core/glibc/cross-localedef-native_2.21.bb b/meta/recipes-core/glibc/cross-localedef-native_2.21.bb
new file mode 100644
index 0000000000..814ae9df92
--- /dev/null
+++ b/meta/recipes-core/glibc/cross-localedef-native_2.21.bb
@@ -0,0 +1,57 @@
+SUMMARY = "Cross locale generation tool for glibc"
+HOMEPAGE = "http://www.gnu.org/software/libc/libc.html"
+SECTION = "libs"
+LICENSE = "LGPL-2.1"
+
+LIC_FILES_CHKSUM = "file://LICENSES;md5=e9a558e243b36d3209f380deb394b213 \
+      file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+      file://posix/rxspencer/COPYRIGHT;md5=dc5485bb394a13b2332ec1c785f5d83a \
+      file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c"
+
+
+inherit native
+inherit autotools
+
+FILESEXTRAPATHS =. "${FILE_DIRNAME}/${PN}:${FILE_DIRNAME}/glibc:"
+
+#BRANCH = "release/${PV}/master"
+BRANCH = "master"
+
+SRC_URI = "git://sourceware.org/git/glibc.git;branch=${BRANCH};name=glibc \
+           git://github.com/kraj/localedef;branch=master;name=localedef;destsuffix=git/localedef \
+           file://fix_for_centos_5.8.patch \
+           ${EGLIBCPATCHES} \
+          "
+EGLIBCPATCHES = "\
+           file://timezone-re-written-tzselect-as-posix-sh.patch \
+           file://eglibc.patch \
+           file://option-groups.patch \
+           file://GLRO_dl_debug_mask.patch \
+           file://eglibc-header-bootstrap.patch \
+           file://eglibc-resolv-dynamic.patch \
+           file://eglibc-ppc8xx-cache-line-workaround.patch \
+           file://eglibc-sh4-fpscr_values.patch \
+           file://eglibc-use-option-groups.patch \
+          "
+
+SRCREV_glibc = "edac0a60c7514b8c9b59488cffdac6b22267e757"
+SRCREV_localedef = "c833367348d39dad7ba018990bfdaffaec8e9ed3"
+
+# Makes for a rather long rev (22 characters), but...
+#
+SRCREV_FORMAT = "glibc_localedef"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OECONF = "--with-glibc=${S}"
+CFLAGS += "-fgnu89-inline -std=gnu99 -DIS_IN\(x\)='0'"
+
+do_configure () {
+        ${S}/localedef/configure ${EXTRA_OECONF}
+}
+
+
+do_install() {
+        install -d ${D}${bindir}
+        install -m 0755 ${B}/localedef ${D}${bindir}/cross-localedef
+}