glib-2.0: update to upstream version 2.34.3

(From OE-Core rev: db9b8ad76335613e2de1e568a14ae95c68af6288)

Signed-off-by: Marko Lindqvist <cazfi74@gmail.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/meta/recipes-core/glib-2.0/glib-2.0_2.34.3.bb b/meta/recipes-core/glib-2.0/glib-2.0_2.34.3.bb
new file mode 100644
index 0000000000..966a851f76
--- /dev/null
+++ b/meta/recipes-core/glib-2.0/glib-2.0_2.34.3.bb
@@ -0,0 +1,39 @@
+require glib.inc
+
+PR = "r0"
+PE = "1"
+
+DEPENDS += "libffi python-argparse-native zlib"
+DEPENDS_class-native += "libffi-native python-argparse-native"
+DEPENDS_class-nativesdk += "nativesdk-libffi python-argparse-native nativesdk-zlib ${BPN}-native"
+
+SHRT_VER = "${@d.getVar('PV',1).split('.')[0]}.${@d.getVar('PV',1).split('.')[1]}"
+
+SRC_URI = "${GNOME_MIRROR}/glib/${SHRT_VER}/glib-${PV}.tar.xz \
+           file://configure-libtool.patch \
+           file://glib-2.0_fix_for_x32.patch \
+          "
+SRC_URI[md5sum] = "a4ca31e258273c3761e3de2edd607661"
+SRC_URI[sha256sum] = "855fcbf87cb93065b488358e351774d8a39177281023bae58c286f41612658a7"
+
+SRC_URI_append_class-native = " file://glib-gettextize-dir.patch"
+BBCLASSEXTEND = "native nativesdk"
+
+do_configure_prepend() {
+        sed -i -e '1s,#!.*,#!${USRBINPATH}/env python,' ${S}/gio/gdbus-2.0/codegen/gdbus-codegen.in
+}
+
+do_install_append() {
+  # remove some unpackaged files
+  rm -f ${D}${libdir}/gdbus-2.0/codegen/*.pyc
+  rm -f ${D}${libdir}/gdbus-2.0/codegen/*.pyo
+  # and empty dirs
+  rmdir ${D}${libdir}/gio/modules/
+  rmdir ${D}${libdir}/gio/
+
+  # Some distros have both /bin/perl and /usr/bin/perl, but we set perl location
+  # for target as /usr/bin/perl, so fix it to /usr/bin/perl.
+  if [ -f ${D}${bindir}/glib-mkenums ]; then
+    sed -i -e '1s,#!.*perl,#! ${USRBINPATH}/env perl,' ${D}${bindir}/glib-mkenums
+  fi
+}