summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/gettext/gettext_0.21.bb
diff options
context:
space:
mode:
authorAlexander Kanavin <alex.kanavin@gmail.com>2022-11-14 20:00:49 +0100
committerRichard Purdie <richard.purdie@linuxfoundation.org>2022-11-15 09:38:37 +0000
commitf595da926eb6b887a716edd26829ad922dd6861b (patch)
tree3fd311f4d21851e17890833a22af4da4e2f3f94e /meta/recipes-core/gettext/gettext_0.21.bb
parent93b26a86ef0b7f6eb0fdc1e0a1aa524023c8203e (diff)
downloadpoky-f595da926eb6b887a716edd26829ad922dd6861b.tar.gz
gettext: update 0.21 -> 0.21.1
License-update: formatting Refresh gettext-minimal files from the 0.21.1 install tree. (From OE-Core rev: 250a265893661c1ca12c31e5b78b527b96cbcfc6) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-core/gettext/gettext_0.21.bb')
-rw-r--r--meta/recipes-core/gettext/gettext_0.21.bb218
1 files changed, 0 insertions, 218 deletions
diff --git a/meta/recipes-core/gettext/gettext_0.21.bb b/meta/recipes-core/gettext/gettext_0.21.bb
deleted file mode 100644
index 364e6a52a1..0000000000
--- a/meta/recipes-core/gettext/gettext_0.21.bb
+++ /dev/null
@@ -1,218 +0,0 @@
1SUMMARY = "Utilities and libraries for producing multi-lingual messages"
2DESCRIPTION = "GNU gettext is a set of tools that provides a framework to help other programs produce multi-lingual messages. \
3These tools include a set of conventions about how programs should be written to support message catalogs, a directory and file \
4naming organization for the message catalogs themselves, a runtime library supporting the retrieval of translated messages, and \
5a few stand-alone programs to massage in various ways the sets of translatable and already translated strings."
6HOMEPAGE = "http://www.gnu.org/software/gettext/gettext.html"
7SECTION = "libs"
8LICENSE = "GPL-3.0-or-later & LGPL-2.1-or-later"
9LIC_FILES_CHKSUM = "file://COPYING;md5=c678957b0c8e964aa6c70fd77641a71e"
10
11# without libxml in PACKAGECONFIG vendor copy of the lib will be used
12LICENSE:append = " ${@bb.utils.contains('PACKAGECONFIG', 'libxml', '', '& MIT', d)}"
13LIC_FILES_CHKSUM:append = " ${@bb.utils.contains('PACKAGECONFIG', 'libxml', '', 'file://libtextstyle/lib/libxml/COPYING;md5=2044417e2e5006b65a8b9067b683fcf1', d)}"
14# without croco in PACKAGECONFIG vendor copy of the lib will be used
15LIC_FILES_CHKSUM:append = " ${@bb.utils.contains('PACKAGECONFIG', 'croco', '', 'file://libtextstyle/lib/libcroco/libcroco.h;md5=915a46e7307c2f7f8d2b9c503fc434ed;beginline=10;endline=28', d)}"
16# without glib in PACKAGECONFIG vendor copy of the lib will be used
17LIC_FILES_CHKSUM:append = " ${@bb.utils.contains('PACKAGECONFIG', 'glib', '', 'file://libtextstyle/lib/glib/ghash.c;md5=af89a160226edf0b276b6183888037d0;beginline=10;endline=27', d)}"
18
19
20DEPENDS = "gettext-native virtual/libiconv"
21DEPENDS:class-native = "gettext-minimal-native"
22PROVIDES = "virtual/libintl virtual/gettext"
23PROVIDES:class-native = "virtual/gettext-native"
24RCONFLICTS:${PN} = "proxy-libintl"
25SRC_URI = "${GNU_MIRROR}/gettext/gettext-${PV}.tar.gz \
26 file://parallel.patch \
27 file://use-pkgconfig.patch \
28 file://run-ptest \
29 file://serial-tests-config.patch \
30 file://0001-tests-autopoint-3-unset-MAKEFLAGS.patch \
31 file://0001-init-env.in-do-not-add-C-CXX-parameters.patch \
32 file://mingw.patch \
33 file://0001-msgmerge-29-Add-executable-file-mode-bits.patch \
34 file://0001-libtextstyle-fix-builds-with-automake-1.16.4-and-new.patch \
35 "
36SRC_URI[sha256sum] = "c77d0da3102aec9c07f43671e60611ebff89a996ef159497ce8e59d075786b12"
37
38inherit autotools texinfo pkgconfig ptest
39
40EXTRA_OECONF += "--without-lispdir \
41 --disable-csharp \
42 --disable-libasprintf \
43 --disable-java \
44 --disable-native-java \
45 --disable-openmp \
46 --disable-acl \
47 --without-emacs \
48 --without-cvs \
49 --without-git \
50 --cache-file=${B}/config.cache \
51 "
52EXTRA_OECONF:append:class-target = " \
53 --with-bisonlocaledir=${datadir}/locale \
54 gt_cv_locale_fr_utf8=fr_FR \
55 gt_cv_locale_fr=fr_FR.ISO-8859-1 \
56 gt_cv_locale_de_utf8=de_DE \
57 gt_cv_locale_de=de_DE.ISO-8859-1 \
58"
59
60PACKAGECONFIG ??= "croco glib libxml"
61PACKAGECONFIG:class-native = ""
62PACKAGECONFIG:class-nativesdk = ""
63
64PACKAGECONFIG[croco] = "--without-included-libcroco,--with-included-libcroco,libcroco"
65PACKAGECONFIG[glib] = "--without-included-glib,--with-included-glib,glib-2.0"
66PACKAGECONFIG[libxml] = "--without-included-libxml,--with-included-libxml,libxml2"
67# Need paths here to avoid host contamination but this can cause RPATH warnings
68# or problems if $libdir isn't $prefix/lib.
69PACKAGECONFIG[libunistring] = "--with-libunistring-prefix=${STAGING_LIBDIR}/..,--with-included-libunistring,libunistring"
70PACKAGECONFIG[msgcat-curses] = "--with-libncurses-prefix=${STAGING_LIBDIR}/..,--disable-curses,ncurses,"
71
72acpaths = '-I ${S}/gettext-runtime/m4 \
73 -I ${S}/gettext-tools/m4'
74
75do_install:append:libc-musl () {
76 rm -f ${D}${libdir}/charset.alias
77 rm -f ${D}${includedir}/libintl.h
78 rm -f ${D}${libdir}/libintl.la
79}
80
81# these lack the .x behind the .so, but shouldn't be in the -dev package
82# Otherwise you get the following results:
83# 7.4M glibc/images/ep93xx/Angstrom-console-image-glibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
84# 25M uclibc/images/ep93xx/Angstrom-console-image-uclibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
85# because gettext depends on gettext-dev, which pulls in more -dev packages:
86# 15228 KiB /ep93xx/libstdc++-dev_4.2.2-r2_ep93xx.ipk
87# 1300 KiB /ep93xx/uclibc-dev_0.9.29-r8_ep93xx.ipk
88# 140 KiB /armv4t/gettext-dev_0.14.1-r6_armv4t.ipk
89# 4 KiB /ep93xx/libgcc-s-dev_4.2.2-r2_ep93xx.ipk
90
91PACKAGES =+ "libgettextlib libgettextsrc"
92FILES:libgettextlib = "${libdir}/libgettextlib-*.so*"
93FILES:libgettextsrc = "${libdir}/libgettextsrc-*.so*"
94
95PACKAGES =+ "gettext-runtime gettext-runtime-dev gettext-runtime-doc"
96
97FILES:${PN} += "${libdir}/${BPN}/*"
98
99# The its/Makefile.am has defined:
100# itsdir = $(pkgdatadir)$(PACKAGE_SUFFIX)/its
101# not itsdir = $(pkgdatadir), so use wildcard to match the version.
102FILES:${PN} += "${datadir}/${BPN}-*/*"
103
104FILES:gettext-runtime = "${bindir}/gettext \
105 ${bindir}/ngettext \
106 ${bindir}/envsubst \
107 ${bindir}/gettext.sh \
108 ${libdir}/libasprintf.so* \
109 ${libdir}/GNU.Gettext.dll \
110 "
111FILES:gettext-runtime-dev += "${libdir}/libasprintf.a \
112 ${includedir}/autosprintf.h \
113 "
114FILES:gettext-runtime-doc = "${mandir}/man1/gettext.* \
115 ${mandir}/man1/ngettext.* \
116 ${mandir}/man1/envsubst.* \
117 ${mandir}/man1/.* \
118 ${mandir}/man3/* \
119 ${docdir}/gettext/gettext.* \
120 ${docdir}/gettext/ngettext.* \
121 ${docdir}/gettext/envsubst.* \
122 ${docdir}/gettext/*.3.html \
123 ${datadir}/gettext/ABOUT-NLS \
124 ${docdir}/gettext/csharpdoc/* \
125 ${docdir}/libasprintf/autosprintf.html \
126 ${infodir}/autosprintf.info \
127 "
128
129do_install:append() {
130 rm -f ${D}${libdir}/preloadable_libintl.so
131}
132
133do_install:append:class-native () {
134 rm ${D}${datadir}/aclocal/*
135 rm ${D}${datadir}/gettext/config.rpath
136 rm ${D}${datadir}/gettext/po/Makefile.in.in
137 rm ${D}${datadir}/gettext/po/remove-potcdate.sin
138
139 create_wrapper ${D}${bindir}/msgfmt \
140 GETTEXTDATADIR="${STAGING_DATADIR_NATIVE}/gettext-${PV}/"
141
142}
143
144do_compile_ptest() {
145 cd ${B}/gettext-tools/tests/
146 sed -i '/^buildtest-TESTS: /c buildtest-TESTS: $(TESTS) $(check_PROGRAMS)' Makefile
147 oe_runmake buildtest-TESTS
148 cd -
149}
150
151do_install_ptest() {
152 if [ ${PTEST_ENABLED} = "1" ]; then
153 mkdir -p ${D}${PTEST_PATH}/tests
154 mkdir -p ${D}${PTEST_PATH}/src
155 mkdir -p ${D}${PTEST_PATH}/po
156 mkdir -p ${D}${PTEST_PATH}/misc
157 mkdir -p ${D}${PTEST_PATH}/its
158 mkdir -p ${D}${PTEST_PATH}/styles
159 mkdir -p ${D}${PTEST_PATH}/gnulib-lib
160 mkdir -p ${D}${PTEST_PATH}/examples
161 cp -rf ${S}/gettext-tools/its/* ${D}${PTEST_PATH}/its
162 cp -rf ${S}/gettext-tools/styles/* ${D}${PTEST_PATH}/styles
163 cp -rf ${S}/gettext-tools/gnulib-lib/gettext.h ${D}${PTEST_PATH}/gnulib-lib
164 cp -rf ${S}/gettext-tools/examples/hello-c ${D}${PTEST_PATH}/examples
165 cp -rf ${S}/gettext-tools/tests/* ${D}${PTEST_PATH}/tests
166 cp -rf ${B}/gettext-tools/tests/.libs/* ${D}${PTEST_PATH}/tests
167 cp -rf ${B}/gettext-runtime/intl/.libs/libgnuintl.so.8* ${D}${libdir}/
168 cp -rf ${B}/gettext-tools/tests/Makefile ${D}${PTEST_PATH}/tests
169 cp -rf ${B}/gettext-tools/tests/init-env ${D}${PTEST_PATH}/tests
170 sed -i '/^Makefile:/c Makefile:' ${D}${PTEST_PATH}/tests/Makefile
171 sed -i -e 's:lang-c lang-c++:lang-c++:g' ${D}${PTEST_PATH}/tests/Makefile
172 install ${S}/gettext-tools/src/msgunfmt.tcl ${D}${PTEST_PATH}/src
173 install ${S}/gettext-tools/src/project-id ${D}${PTEST_PATH}/src
174 install ${B}/gettext-runtime/src/gettext.sh ${D}${PTEST_PATH}/src
175 install ${B}/gettext-runtime/src/ngettext ${D}${PTEST_PATH}/src
176 install ${B}/gettext-runtime/src/envsubst ${D}${PTEST_PATH}/src
177 install ${B}/gettext-runtime/src/gettext ${D}${PTEST_PATH}/src
178 install ${B}/gettext-tools/src/.libs/cldr-plurals ${D}${PTEST_PATH}/src
179 install ${S}/gettext-tools/po/gettext-tools.pot ${D}${PTEST_PATH}/po
180 install ${B}/gettext-tools/misc/* ${D}${PTEST_PATH}/misc
181 find ${D}${PTEST_PATH}/ -name "*.o" -exec rm {} \;
182 chmod 0755 ${D}${PTEST_PATH}/tests/lang-vala ${D}${PTEST_PATH}/tests/plural-1 ${D}${PTEST_PATH}/tests/xgettext-tcl-4 \
183 ${D}${PTEST_PATH}/tests/xgettext-vala-1 ${D}${PTEST_PATH}/tests/xgettext-po-2
184 sed -i -e 's|${DEBUG_PREFIX_MAP}||g' ${D}${PTEST_PATH}/tests/init-env
185 fi
186}
187
188RDEPENDS:${PN}-ptest += "make xz"
189RDEPENDS:${PN}-ptest:append:libc-glibc = "\
190 glibc-gconv-big5 \
191 glibc-charmap-big5 \
192 glibc-gconv-cp1251 \
193 glibc-charmap-cp1251 \
194 glibc-charmap-iso-8859-9 \
195 glibc-gconv-iso8859-9 \
196 glibc-charmap-koi8-r \
197 glibc-gconv-koi8-r \
198 glibc-gconv-iso8859-2 \
199 glibc-charmap-iso-8859-2 \
200 glibc-gconv-iso8859-1 \
201 glibc-charmap-iso-8859-1 \
202 glibc-gconv-euc-kr \
203 glibc-charmap-euc-kr \
204 glibc-gconv-euc-jp \
205 glibc-charmap-euc-jp \
206 locale-base-de-de \
207 locale-base-fr-fr \
208"
209
210RRECOMMENDS:${PN}-ptest:append:libc-glibc = "\
211 locale-base-de-de.iso-8859-1 \
212 locale-base-fr-fr.iso-8859-1 \
213"
214
215INSANE_SKIP:${PN}-ptest += "ldflags"
216INSANE_SKIP:${PN}-ptest += "rpaths"
217
218BBCLASSEXTEND = "native nativesdk"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-06-24 16:39:10 +0000