base-passwd: Update to 3.6.1

Add a patch to support configuring whether SELinux is enabled or not.
Also add a PACKAGECONFIG for SELinux support and enable it if the
"selinux" distro feature is enabled.

Remove two patches that have been applied upstream.

Changes since 3.5.52:
* 5928e85: German (thanks, Helge Kreutzmann)
* 72cb6a6: Remove constraints unnecessary since buster
* 2f71444: Merge branch 'scrub-obsolete' into 'master'
* 5a578e7: Drop Build-Depends: dpkg
* 44f28e1: Apply wrap-and-sort -at
* 1fe0338: Upgrade to debhelper v13
* d77d38c: Simplify some debhelper overrides slightly
* 2143651: Implement SELinux awareness when updating
  /etc/{passwd,group,shadow}
* 0b824ad: improve enforcing handling
* e2f0c03: update-passwd.c: use raw selinux labeles
* 8d45264: selinux_prepare_create_file: return error from
  setfscreatecon_raw
* 2f23448: selinux_after_create_file: save errno
* 6953dd1: update-passwd.c: replace goto error handling
* 32fbf59: cleanup
* 3c3eb67: fixup goto
* 585126f: implement feedback
* 02a366b: users-and-groups: Update copyright years
* 7849c61: users-and-groups: Rename ssh group to _ssh
* 06ed6f4: update-passwd.c: set walk to walk->next before removing
* ef6baea: users-and-groups: Document libvirt group
* 68e02a3: Stop creating the gnats user and group on new installations
* cb6e2a9: Restore Build-Depends sorting
* 0e1afc1: Tidy up whitespace
* 6005a06: Merge branch 'selinux' into 'master'
* 24046cb: Bump version to 3.6.0
* c72aa5d: Make it possible to build without debconf support
* 2a6d16e: Make it possible to disable the generation of the
  documentation
* 60ece0c: Merge branch 'master' into 'master'
* 63d0f94: Add changelog entry
* cbae4a5: update-passwd: add format attribute
* b71eb04: update-passwd: use strict prototypes
* df48ea8: update-passwd: silence potential null dereference
* cddc9df: update-passwd: print filename on fclose error
* d05f8a3: update-passwd: use correct filename in copy_filemodes
* 11e6466: update-passwd: drop t flag from fopen
* 347aeb6: update-passwd: open temporary file exclusively
* a697493: d/salsa-ci.yml: add standard salsa ci configuration
* 2f622f4: configure: replace obsolete macro
* 43ebe64: Add changelog entry
* e1a186b: frozen the group id for crontab, in order to fix #1012622
* 5ce7773: frozen the group id for crontab, closes: #1012622
* 670c2be: Revert "frozen the group id for crontab, closes: #1012622"
* bc1ad19: Revert "Revert "frozen the group id for crontab, closes:
  #1012622""
* 12122c6: Revert "frozen the group id for crontab, in order to fix
  #1012622"
* 0145e8a: Revert "frozen the group id for crontab, closes: #1012622"
* c8125ff: releasing package base-passwd version 3.6.0
* dc157c6: passwd.master: Add _apt user
* e50024c: Merge branch 'misc' into 'master'
* 7fb5ad8: debian/postinst: Fix several shellcheck issues
* 8f07b66: releasing package base-passwd version 3.6.1

(From OE-Core rev: 41a9eb6c3afc6de000eaeb0fbe0c691b6c8d1285)

Signed-off-by: Peter Kjellerstedt <peter.kjellerstedt@axis.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 124 insertions, 0 deletions

diff --git a/meta/recipes-core/base-passwd/base-passwd_3.6.1.bb b/meta/recipes-core/base-passwd/base-passwd_3.6.1.bb
new file mode 100644
index 0000000000..853717176d
--- /dev/null
+++ b/meta/recipes-core/base-passwd/base-passwd_3.6.1.bb
@@ -0,0 +1,124 @@
+SUMMARY = "Base system master password/group files"
+DESCRIPTION = "The master copies of the user database files (/etc/passwd and /etc/group).  The update-passwd tool is also provided to keep the system databases synchronized with these master files."
+HOMEPAGE = "https://launchpad.net/base-passwd"
+SECTION = "base"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=eb723b61539feef013de476e68b5c50a"
+
+SRC_URI = "https://launchpad.net/debian/+archive/primary/+files/${BPN}_${PV}.tar.xz \
+           file://0001-Add-a-shutdown-group.patch \
+           file://0002-Use-bin-sh-instead-of-bin-bash-for-the-root-user.patch \
+           file://0003-Remove-for-root-since-we-do-not-have-an-etc-shadow.patch \
+           file://0004-Add-an-input-group-for-the-dev-input-devices.patch \
+           file://0005-Add-kvm-group.patch \
+           file://0006-Make-it-possible-to-configure-whether-to-use-SELinux.patch \
+           "
+
+SRC_URI[sha256sum] = "6ff369be59d586ba63c0c5fcb00f75f9953fe49db88bc6c6428f2c92866f79af"
+
+# the package is taken from launchpad; that source is static and goes stale
+# so we check the latest upstream from a directory that does get updated
+UPSTREAM_CHECK_URI = "${DEBIAN_MIRROR}/main/b/base-passwd/"
+
+S = "${WORKDIR}/work"
+
+PACKAGECONFIG = "${@bb.utils.filter('DISTRO_FEATURES', 'selinux', d)}"
+PACKAGECONFIG[selinux] = "--enable-selinux, --disable-selinux, libselinux"
+
+inherit autotools
+
+EXTRA_OECONF += "--disable-debconf --disable-docs"
+
+NOLOGIN ?= "${base_sbindir}/nologin"
+
+do_install () {
+        install -d -m 755 ${D}${sbindir}
+        install -o root -g root -p -m 755 ${B}/update-passwd ${D}${sbindir}/
+        install -d -m 755 ${D}${mandir}/man8 ${D}${mandir}/pl/man8
+        install -p -m 644 ${S}/man/update-passwd.8 ${D}${mandir}/man8/
+        install -p -m 644 ${S}/man/update-passwd.pl.8 \
+                ${D}${mandir}/pl/man8/update-passwd.8
+        gzip -9 ${D}${mandir}/man8/* ${D}${mandir}/pl/man8/*
+        install -d -m 755 ${D}${datadir}/base-passwd
+        install -o root -g root -p -m 644 ${S}/passwd.master ${D}${datadir}/base-passwd/
+        sed -i 's#:/root:#:${ROOT_HOME}:#' ${D}${datadir}/base-passwd/passwd.master
+        sed -i 's#/usr/sbin/nologin#${NOLOGIN}#' ${D}${datadir}/base-passwd/passwd.master
+        install -o root -g root -p -m 644 ${S}/group.master ${D}${datadir}/base-passwd/
+
+        install -d -m 755 ${D}${docdir}/${BPN}
+        install -p -m 644 ${S}/debian/changelog ${D}${docdir}/${BPN}/
+        gzip -9 ${D}${docdir}/${BPN}/*
+        install -p -m 644 ${S}/README ${D}${docdir}/${BPN}/
+        install -p -m 644 ${S}/debian/copyright ${D}${docdir}/${BPN}/
+}
+
+basepasswd_sysroot_postinst() {
+#!/bin/sh
+
+# Install passwd.master and group.master to sysconfdir
+install -d -m 755 ${STAGING_DIR_TARGET}${sysconfdir}
+for i in passwd group; do
+        install -p -m 644 ${STAGING_DIR_TARGET}${datadir}/base-passwd/\$i.master \
+                ${STAGING_DIR_TARGET}${sysconfdir}/\$i
+done
+
+# Run any useradd postinsts
+for script in ${STAGING_DIR_TARGET}${bindir}/postinst-useradd-*; do
+        if [ -f \$script ]; then
+                \$script
+        fi
+done
+}
+
+SYSROOT_DIRS += "${sysconfdir}"
+SYSROOT_PREPROCESS_FUNCS += "base_passwd_tweaksysroot"
+
+base_passwd_tweaksysroot () {
+        mkdir -p ${SYSROOT_DESTDIR}${bindir}
+        dest=${SYSROOT_DESTDIR}${bindir}/postinst-${PN}
+        echo "${basepasswd_sysroot_postinst}" > $dest
+        chmod 0755 $dest
+}
+
+python populate_packages:prepend() {
+    # Add in the preinst function for ${PN}
+    # We have to do this here as prior to this, passwd/group.master
+    # would be unavailable. We need to create these files at preinst
+    # time before the files from the package may be available, hence
+    # storing the data from the files in the preinst directly.
+
+    f = open(d.expand("${STAGING_DATADIR}/base-passwd/passwd.master"), 'r')
+    passwd = "".join(f.readlines())
+    f.close()
+    f = open(d.expand("${STAGING_DATADIR}/base-passwd/group.master"), 'r')
+    group = "".join(f.readlines())
+    f.close()
+
+    preinst = """#!/bin/sh
+mkdir -p $D${sysconfdir}
+if [ ! -e $D${sysconfdir}/passwd ]; then
+\tcat << 'EOF' > $D${sysconfdir}/passwd
+""" + passwd + """EOF
+fi
+if [ ! -e $D${sysconfdir}/group ]; then
+\tcat << 'EOF' > $D${sysconfdir}/group
+""" + group + """EOF
+fi
+"""
+    d.setVar(d.expand('pkg_preinst:${PN}'), preinst)
+}
+
+addtask do_package after do_populate_sysroot
+
+ALLOW_EMPTY:${PN} = "1"
+
+PACKAGES =+ "${PN}-update"
+FILES:${PN}-update = "${sbindir}/* ${datadir}/${PN}"
+
+pkg_postinst:${PN}-update () {
+#!/bin/sh
+if [ -n "$D" ]; then
+        exit 0
+fi
+${sbindir}/update-passwd
+}