diff options
author | Yue Tao <Yue.Tao@windriver.com> | 2015-05-26 12:55:42 +0800 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2015-05-29 10:17:15 +0100 |
commit | 46bca1b82908a4bfca310b1d8d951c3331924c4d (patch) | |
tree | 435eaffaa59bf19bfe2b356409896980678efa98 /meta/recipes-connectivity/wpa-supplicant/wpa-supplicant.inc | |
parent | 2d2d5e69776113aa6d8b4b3204d5bc70310d3858 (diff) | |
download | poky-46bca1b82908a4bfca310b1d8d951c3331924c4d.tar.gz |
wpa-supplicant: upgrade to 2.4
1. upgrade to 2.4
2. update the checksum, and license checksum since date in it is changed
3. Backport a patch to fix CVE-2015-1863
4. remove two deprecated patches
(From OE-Core rev: fd0880c2b0958b72d641a6821ddd6d6790a92b7a)
Signed-off-by: Roy Li <rongqing.li@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-connectivity/wpa-supplicant/wpa-supplicant.inc')
-rw-r--r-- | meta/recipes-connectivity/wpa-supplicant/wpa-supplicant.inc | 111 |
1 files changed, 0 insertions, 111 deletions
diff --git a/meta/recipes-connectivity/wpa-supplicant/wpa-supplicant.inc b/meta/recipes-connectivity/wpa-supplicant/wpa-supplicant.inc deleted file mode 100644 index dae0606876..0000000000 --- a/meta/recipes-connectivity/wpa-supplicant/wpa-supplicant.inc +++ /dev/null | |||
@@ -1,111 +0,0 @@ | |||
1 | SUMMARY = "Client for Wi-Fi Protected Access (WPA)" | ||
2 | HOMEPAGE = "http://hostap.epitest.fi/wpa_supplicant/" | ||
3 | BUGTRACKER = "http://hostap.epitest.fi/bugz/" | ||
4 | SECTION = "network" | ||
5 | LICENSE = "BSD" | ||
6 | LIC_FILES_CHKSUM = "file://COPYING;md5=ab87f20cd7e8c0d0a6539b34d3791d0e \ | ||
7 | file://README;beginline=1;endline=56;md5=a07250b28e857455336bb59fc31cb845 \ | ||
8 | file://wpa_supplicant/wpa_supplicant.c;beginline=1;endline=12;md5=e8e021e30f3a6ab7c341b66b86626a5a" | ||
9 | DEPENDS = "dbus libnl libgcrypt" | ||
10 | RRECOMMENDS_${PN} = "wpa-supplicant-passphrase wpa-supplicant-cli" | ||
11 | |||
12 | PACKAGECONFIG ??= "gnutls" | ||
13 | PACKAGECONFIG[gnutls] = ",,gnutls" | ||
14 | PACKAGECONFIG[openssl] = ",,openssl" | ||
15 | |||
16 | inherit systemd | ||
17 | |||
18 | SYSTEMD_SERVICE_${PN} = "wpa_supplicant.service wpa_supplicant-nl80211@.service wpa_supplicant-wired@.service" | ||
19 | SYSTEMD_AUTO_ENABLE = "disable" | ||
20 | |||
21 | SRC_URI = "http://hostap.epitest.fi/releases/wpa_supplicant-${PV}.tar.gz \ | ||
22 | file://defconfig \ | ||
23 | file://wpa-supplicant.sh \ | ||
24 | file://wpa_supplicant.conf \ | ||
25 | file://wpa_supplicant.conf-sane \ | ||
26 | file://99_wpa_supplicant \ | ||
27 | file://fix-libnl3-host-contamination.patch \ | ||
28 | file://0001-linux_wext-Fix-types-for-musl.patch \ | ||
29 | " | ||
30 | SRC_URI[md5sum] = "f2ed8fef72cf63d8d446a2d0a6da630a" | ||
31 | SRC_URI[sha256sum] = "eaaa5bf3055270e521b2dff64f2d203ec8040f71958b8588269a82c00c9d7b6a" | ||
32 | |||
33 | S = "${WORKDIR}/wpa_supplicant-${PV}" | ||
34 | |||
35 | PACKAGES_prepend = "wpa-supplicant-passphrase wpa-supplicant-cli " | ||
36 | FILES_wpa-supplicant-passphrase = "${bindir}/wpa_passphrase" | ||
37 | FILES_wpa-supplicant-cli = "${sbindir}/wpa_cli" | ||
38 | FILES_${PN} += "${datadir}/dbus-1/system-services/*" | ||
39 | CONFFILES_${PN} += "${sysconfdir}/wpa_supplicant.conf" | ||
40 | |||
41 | do_configure () { | ||
42 | ${MAKE} -C wpa_supplicant clean | ||
43 | install -m 0755 ${WORKDIR}/defconfig wpa_supplicant/.config | ||
44 | echo "CFLAGS +=\"-I${STAGING_INCDIR}/libnl3\"" >> wpa_supplicant/.config | ||
45 | echo "DRV_CFLAGS +=\"-I${STAGING_INCDIR}/libnl3\"" >> wpa_supplicant/.config | ||
46 | |||
47 | if echo "${PACKAGECONFIG}" | grep -qw "openssl"; then | ||
48 | ssl=openssl | ||
49 | elif echo "${PACKAGECONFIG}" | grep -qw "gnutls"; then | ||
50 | ssl=gnutls | ||
51 | fi | ||
52 | if [ -n "$ssl" ]; then | ||
53 | sed -i "s/%ssl%/$ssl/" wpa_supplicant/.config | ||
54 | fi | ||
55 | |||
56 | # For rebuild | ||
57 | rm -f wpa_supplicant/*.d wpa_supplicant/dbus/*.d | ||
58 | } | ||
59 | |||
60 | export EXTRA_CFLAGS = "${CFLAGS}" | ||
61 | export BINDIR = "${sbindir}" | ||
62 | |||
63 | do_compile () { | ||
64 | unset CFLAGS CPPFLAGS CXXFLAGS | ||
65 | sed -e "s:CFLAGS\ =.*:& \$(EXTRA_CFLAGS):g" -i ${S}/src/lib.rules | ||
66 | oe_runmake -C wpa_supplicant | ||
67 | } | ||
68 | |||
69 | do_install () { | ||
70 | install -d ${D}${sbindir} | ||
71 | install -m 755 wpa_supplicant/wpa_supplicant ${D}${sbindir} | ||
72 | install -m 755 wpa_supplicant/wpa_cli ${D}${sbindir} | ||
73 | |||
74 | install -d ${D}${bindir} | ||
75 | install -m 755 wpa_supplicant/wpa_passphrase ${D}${bindir} | ||
76 | |||
77 | install -d ${D}${docdir}/wpa_supplicant | ||
78 | install -m 644 wpa_supplicant/README ${WORKDIR}/wpa_supplicant.conf ${D}${docdir}/wpa_supplicant | ||
79 | |||
80 | install -d ${D}${sysconfdir} | ||
81 | install -m 600 ${WORKDIR}/wpa_supplicant.conf-sane ${D}${sysconfdir}/wpa_supplicant.conf | ||
82 | |||
83 | install -d ${D}${sysconfdir}/network/if-pre-up.d/ | ||
84 | install -d ${D}${sysconfdir}/network/if-post-down.d/ | ||
85 | install -d ${D}${sysconfdir}/network/if-down.d/ | ||
86 | install -m 755 ${WORKDIR}/wpa-supplicant.sh ${D}${sysconfdir}/network/if-pre-up.d/wpa-supplicant | ||
87 | cd ${D}${sysconfdir}/network/ && \ | ||
88 | ln -sf ../if-pre-up.d/wpa-supplicant if-post-down.d/wpa-supplicant | ||
89 | |||
90 | install -d ${D}/${datadir}/dbus-1/system-services | ||
91 | install -m 644 ${S}/wpa_supplicant/dbus/*.service ${D}/${datadir}/dbus-1/system-services | ||
92 | |||
93 | if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then | ||
94 | install -d ${D}/${sysconfdir}/dbus-1/system.d | ||
95 | install -m 644 ${S}/wpa_supplicant/dbus/dbus-wpa_supplicant.conf ${D}/${sysconfdir}/dbus-1/system.d | ||
96 | |||
97 | install -d ${D}/${systemd_unitdir}/system | ||
98 | install -m 644 ${S}/wpa_supplicant/systemd/*.service ${D}/${systemd_unitdir}/system | ||
99 | fi | ||
100 | |||
101 | install -d ${D}/etc/default/volatiles | ||
102 | install -m 0644 ${WORKDIR}/99_wpa_supplicant ${D}/etc/default/volatiles | ||
103 | } | ||
104 | |||
105 | pkg_postinst_wpa-supplicant () { | ||
106 | # If we're offline, we don't need to do this. | ||
107 | if [ "x$D" = "x" ]; then | ||
108 | killall -q -HUP dbus-daemon || true | ||
109 | fi | ||
110 | |||
111 | } | ||