diff options
author | Alexander Kanavin <alex.kanavin@gmail.com> | 2022-08-08 08:42:08 +0200 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2022-08-10 08:25:28 +0100 |
commit | 7e8177dfa173ec82b5279d9adc61ffece75d8735 (patch) | |
tree | aa6001ce4ccd9d6ac53e1c6482156b8eab12bbdb /meta/recipes-connectivity/bind/bind_9.18.5.bb | |
parent | f862d6873a66e98eb5296b697e206990a245295c (diff) | |
download | poky-7e8177dfa173ec82b5279d9adc61ffece75d8735.tar.gz |
bind: upgrade 9.18.4 -> 9.18.5
(From OE-Core rev: 0a419b730ca87daa4e07daf022a550fb4112b9b0)
Signed-off-by: Alexander Kanavin <alex@linutronix.de>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-connectivity/bind/bind_9.18.5.bb')
-rw-r--r-- | meta/recipes-connectivity/bind/bind_9.18.5.bb | 114 |
1 files changed, 114 insertions, 0 deletions
diff --git a/meta/recipes-connectivity/bind/bind_9.18.5.bb b/meta/recipes-connectivity/bind/bind_9.18.5.bb new file mode 100644 index 0000000000..6059ca6a33 --- /dev/null +++ b/meta/recipes-connectivity/bind/bind_9.18.5.bb | |||
@@ -0,0 +1,114 @@ | |||
1 | SUMMARY = "ISC Internet Domain Name Server" | ||
2 | HOMEPAGE = "https://www.isc.org/bind/" | ||
3 | DESCRIPTION = "BIND 9 provides a full-featured Domain Name Server system" | ||
4 | SECTION = "console/network" | ||
5 | |||
6 | LICENSE = "MPL-2.0" | ||
7 | LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=9a4a897f202c0710e07f2f2836bc2b62" | ||
8 | |||
9 | DEPENDS = "openssl libcap zlib libuv" | ||
10 | |||
11 | SRC_URI = "https://ftp.isc.org/isc/bind9/${PV}/${BPN}-${PV}.tar.xz \ | ||
12 | file://conf.patch \ | ||
13 | file://named.service \ | ||
14 | file://bind9 \ | ||
15 | file://generate-rndc-key.sh \ | ||
16 | file://make-etc-initd-bind-stop-work.patch \ | ||
17 | file://init.d-add-support-for-read-only-rootfs.patch \ | ||
18 | file://bind-ensure-searching-for-json-headers-searches-sysr.patch \ | ||
19 | file://0001-named-lwresd-V-and-start-log-hide-build-options.patch \ | ||
20 | file://0001-avoid-start-failure-with-bind-user.patch \ | ||
21 | " | ||
22 | |||
23 | SRC_URI[sha256sum] = "0cee078d74f0bdc4ec374435026b25de7892f26540a18b22a02ef728a11dcae7" | ||
24 | |||
25 | UPSTREAM_CHECK_URI = "https://ftp.isc.org/isc/bind9/" | ||
26 | # follow the ESV versions divisible by 2 | ||
27 | UPSTREAM_CHECK_REGEX = "(?P<pver>9.(\d*[02468])+(\.\d+)+(-P\d+)*)/" | ||
28 | |||
29 | # Issue only affects dhcpd with recent bind versions. We don't ship dhcpd anymore | ||
30 | # so the issue doesn't affect us. | ||
31 | CVE_CHECK_IGNORE += "CVE-2019-6470" | ||
32 | |||
33 | inherit autotools update-rc.d systemd useradd pkgconfig multilib_header update-alternatives | ||
34 | |||
35 | # PACKAGECONFIGs readline and libedit should NOT be set at same time | ||
36 | PACKAGECONFIG ?= "readline" | ||
37 | PACKAGECONFIG[httpstats] = "--with-libxml2=${STAGING_DIR_HOST}${prefix},--without-libxml2,libxml2" | ||
38 | PACKAGECONFIG[readline] = "--with-readline=readline,,readline" | ||
39 | PACKAGECONFIG[libedit] = "--with-readline=libedit,,libedit" | ||
40 | PACKAGECONFIG[dns-over-http] = "--enable-doh,--disable-doh,nghttp2" | ||
41 | |||
42 | EXTRA_OECONF = " --disable-devpoll --disable-auto-validation --enable-epoll \ | ||
43 | --with-gssapi=no --with-lmdb=no --with-zlib \ | ||
44 | --sysconfdir=${sysconfdir}/bind \ | ||
45 | --with-openssl=${STAGING_DIR_HOST}${prefix} \ | ||
46 | " | ||
47 | LDFLAGS:append = " -lz" | ||
48 | |||
49 | # dhcp needs .la so keep them | ||
50 | REMOVE_LIBTOOL_LA = "0" | ||
51 | |||
52 | USERADD_PACKAGES = "${PN}" | ||
53 | USERADD_PARAM:${PN} = "--system --home ${localstatedir}/cache/bind --no-create-home \ | ||
54 | --user-group bind" | ||
55 | |||
56 | INITSCRIPT_NAME = "bind" | ||
57 | INITSCRIPT_PARAMS = "defaults" | ||
58 | |||
59 | SYSTEMD_SERVICE:${PN} = "named.service" | ||
60 | |||
61 | do_install:append() { | ||
62 | |||
63 | install -d -o bind "${D}${localstatedir}/cache/bind" | ||
64 | install -d "${D}${sysconfdir}/bind" | ||
65 | install -d "${D}${sysconfdir}/init.d" | ||
66 | install -m 644 ${S}/conf/* "${D}${sysconfdir}/bind/" | ||
67 | install -m 755 "${S}/init.d" "${D}${sysconfdir}/init.d/bind" | ||
68 | |||
69 | # Install systemd related files | ||
70 | install -d ${D}${sbindir} | ||
71 | install -m 755 ${WORKDIR}/generate-rndc-key.sh ${D}${sbindir} | ||
72 | install -d ${D}${systemd_system_unitdir} | ||
73 | install -m 0644 ${WORKDIR}/named.service ${D}${systemd_system_unitdir} | ||
74 | sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \ | ||
75 | -e 's,@SBINDIR@,${sbindir},g' \ | ||
76 | ${D}${systemd_system_unitdir}/named.service | ||
77 | |||
78 | install -d ${D}${sysconfdir}/default | ||
79 | install -m 0644 ${WORKDIR}/bind9 ${D}${sysconfdir}/default | ||
80 | |||
81 | if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then | ||
82 | install -d ${D}${sysconfdir}/tmpfiles.d | ||
83 | echo "d /run/named 0755 bind bind - -" > ${D}${sysconfdir}/tmpfiles.d/bind.conf | ||
84 | fi | ||
85 | } | ||
86 | |||
87 | CONFFILES:${PN} = " \ | ||
88 | ${sysconfdir}/bind/named.conf \ | ||
89 | ${sysconfdir}/bind/named.conf.local \ | ||
90 | ${sysconfdir}/bind/named.conf.options \ | ||
91 | ${sysconfdir}/bind/db.0 \ | ||
92 | ${sysconfdir}/bind/db.127 \ | ||
93 | ${sysconfdir}/bind/db.empty \ | ||
94 | ${sysconfdir}/bind/db.local \ | ||
95 | ${sysconfdir}/bind/db.root \ | ||
96 | " | ||
97 | |||
98 | ALTERNATIVE:${PN}-utils = "nslookup" | ||
99 | ALTERNATIVE_LINK_NAME[nslookup] = "${bindir}/nslookup" | ||
100 | ALTERNATIVE_PRIORITY = "100" | ||
101 | |||
102 | PACKAGE_BEFORE_PN += "${PN}-utils" | ||
103 | FILES:${PN}-utils = "${bindir}/host ${bindir}/dig ${bindir}/mdig ${bindir}/nslookup ${bindir}/nsupdate" | ||
104 | FILES:${PN}-dev += "${bindir}/isc-config.h" | ||
105 | FILES:${PN} += "${sbindir}/generate-rndc-key.sh" | ||
106 | |||
107 | PACKAGE_BEFORE_PN += "${PN}-libs" | ||
108 | # special arrangement below due to | ||
109 | # https://github.com/isc-projects/bind9/commit/0e25af628cd776f98c04fc4cc59048f5448f6c88 | ||
110 | FILES_SOLIBSDEV = "${libdir}/*[!0-9].so ${libdir}/libbind9.so" | ||
111 | FILES:${PN}-libs = "${libdir}/named/*.so* ${libdir}/*-${PV}.so" | ||
112 | FILES:${PN}-staticdev += "${libdir}/*.la" | ||
113 | |||
114 | DEV_PKG_DEPENDENCY = "" | ||